ereturn.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 29mar2005}{...}
{cmd:help ereturn} {right:dialog:  {bf:{dialog return_list:ereturn list}}}
{hline}

{title:Title}

{p2colset 5 20 22 2}{...}
{p2col :{hi:[P] ereturn} {hline 2}}Post the estimation results{p_end}
{p2colreset}{...}


{title:Syntax}

	{cmdab:eret:urn} {cmdab:loc:al} {it:name ...}{right:(see {helpb macro})  }

{p 8 16 2}{cmdab:eret:urn} {cmdab:sca:lar} {it:name} {cmd:=} {it:exp}

{p 8 16 2}{cmdab:eret:urn} {cmdab:mat:rix} {it:name} [{cmd:=}] {it:matname}
	[{cmd:,} {cmd:copy} ]

{p 8 16 2}{cmdab:eret:urn clear}

{p 8 16 2}{cmdab:eret:urn} {cmdab:li:st}


{p 8 16 2}{cmdab:eret:urn post} [{it:b} [{it:V} [{it:C}]]] [{cmd:,}
{cmdab:dep:name:(}{it:string}{cmd:)} {cmdab:o:bs:(}{it:#}{cmd:)}
{cmdab:d:of:(}{it:#}{cmd:)} {cmdab:e:sample:(}{it:varname}{cmd:)}
{cmdab:prop:erties:(}{it:string}{cmd:)} ]

{p 8 16 2}{cmdab:eret:urn repost} [{cmd:b =} {it:b}] [{cmd:V =} {it:V}]
[{cmd:,} {cmdab:e:sample:(}{it:varname}{cmd:)}
{cmdab:prop:erties:(}{it:string}{cmd:)} {cmdab:ren:ame} ]

{p 8 16 2}{cmdab:eret:urn} {cmdab:di:splay} [{cmd:,}
{cmdab:ef:orm:(}{it:string}{cmd:)} {cmdab:f:irst} {cmd:neq(}{it:#}{cmd:)}
{cmdab:pl:us} {cmdab:l:evel:(}{it:#}{cmd:)} ]

{pstd}
where {it:name} is the name of the macro, scalar, or matrix that will be
returned in {hi:e(}{it:name}{hi:)} by the estimation program, {it:matname} is
the name of an existing matrix, {it:b} is a 1 x p coefficient vector
(matrix), {it:V} is a p x p covariance matrix, and {it:C} is a c x (p+1)
constraint matrix.


{title:Description}

{pstd}
{cmd:ereturn local}, {cmd:ereturn scalar}, and {cmd:ereturn matrix} set
{hi:e()} macros, scalars, and matrices returned by estimation commands.  See
{helpb return} for more discussion on returning results.

{pstd}
{cmd:ereturn clear} clears the {hi:e()} saved results.

{pstd}
{cmd:ereturn list} lists the names and values of the {hi:e()} returned macros
and scalars and the names and sizes of the {hi:e()} returned matrices from the
last estimation command.

{pstd}
{cmd:ereturn post} saves the coefficient vector ({cmd:b}) and
variance-covariance ({cmd:V}) matrices in Stata's system areas, making
available all the postestimation features detailed in {helpb estimates} and
{help postest} available.  {cmd:V} and {cmd:b} are optional for
{cmd:ereturn repost}; some commands (such as {helpb factor}) do not have a
{cmd:b} or {cmd:V} but do set the estimation sample, {cmd:e(sample)}, and
properties, {cmd:e(properties)}.  {cmd:ereturn repost} changes the {cmd:b} or
{cmd:V} matrix (allowed only after estimation commands that posted their
results using {cmd:ereturn post}) or changes the declared estimation sample or
{cmd:e(properties)}.  The specified matrices cease to exist after {cmd:post}
or {cmd:repost}; they are literally moved into Stata's system areas.  The
resulting {cmd:b} and {cmd:V} matrices in Stata's system areas can be
retrieved by reference to {hi:e(b)} and {hi:e(V)}.  {cmd:ereturn post} and
{cmd:repost} deal with only the coefficient and variance-covariance matrices
while {cmd:ereturn matrix} is used to save other matrices associated with the
estimation command.

{pstd}
{cmd:ereturn display} displays or redisplays the coefficient table
corresponding to results that have been previously posted using
{cmd:ereturn post} or {cmd:repost}.

{pstd}
For a discussion of posting results with constraint matrices ({it:C} in the
syntax diagram above), see {helpb makecns}, but only after reading this
entry.


{title:Options}

{phang}
{cmd:copy} specified with {cmd:ereturn matrix} indicates that the matrix is
to be copied; that is, the original matrix should be left in place.

{phang}
{cmd:depname(}{it:string}{cmd:)} specified with {cmd:ereturn post}
supplies a name that should be that of the dependent variable but can be
anything; that name is saved and added to the appropriate place on the output
whenever {cmd:ereturn display} is executed.

{phang}
{cmd:obs(}{it:#}{cmd:)} specified with {cmd:ereturn post} supplies
the number of observations on which the estimation was performed; that number
is saved and stored in {hi:e(N)}.

{phang}
{cmd:dof(}{it:#}{cmd:)} specified with {cmd:ereturn post} supplies
the number of (denominator) degrees of freedom that is to be used with t and F
statistics and is saved and stored in {hi:e(df_r)}.  This number is used in
calculating significance levels and confidence intervals by
{cmd:ereturn display} and by subsequent {cmd:test} commands performed on the
posted results.  If the option is not specified, normal (Z) and chi-squared
statistics are used.

{phang}
{cmd:esample(}{it:varname}{cmd:)} specified with {cmd:ereturn post}
or {cmd:repost} gives the name of the 0/1 variable indicating the observations
involved in the estimation.  The variable is removed from the data but is
available for use as {hi:e(sample)}; see
{hi:[U] 20.5 Specifying the estimation subsample}.  If the {cmd:esample()}
option is not specified with {cmd:ereturn post}, it is set to all zeros
(meaning no estimation sample).  See {helpb marksample} for details of the
{cmd:marksample} command that can help create {it:varname}.

{phang}
{cmd:properties(}{it:string}{cmd:)} specified with {cmd:ereturn post} or
{cmd:repost} sets the {cmd:e(properties)} macro.  By default,
{cmd:e(properties)} is set to {cmd:b V} if {cmd:properties()} is not
specified.

{phang}
{cmd:rename} is allowed only with the {cmd:b =} {it:b} syntax of
{cmd:ereturn repost} and tells Stata to use the names obtained from the
specified {it:b} matrix as the labels for both the {cmd:b} and {cmd:V}
estimation matrices.  These labels are subsequently used in the output
produced by {cmd:ereturn display}.

{phang}
{cmd:eform(}{it:string}{cmd:)} specified with {cmd:ereturn display}
indicates that the exponentiated form of the coefficients is to be output and
reporting of the constant is to be suppressed.  {it:string} is used to label
the exponentiated coefficients; see {help maximize}.

{phang}
{cmd:first} requests that Stata display only the first equation and
make it appear as if only one equation were estimated.

{phang}
{cmd:neq(}{it:#}{cmd:)} requests that Stata display only the first
{it:#} equations and make it appear as if only {it:#} equations were
estimated.

{phang}
{cmd:plus} changes the bottom separation line produced by
{cmd:estimates display} to have a {hi:+} symbol at the position of the
dividing line between variable names and results.  This is useful if you plan
on adding more output to the table.

{phang}
{cmd:level(}{it:#}{cmd:)}, an option of {cmd:ereturn display},
supplies the significance level for the confidence intervals of the
coefficients; see {helpb level}.


{title:Examples}

{pstd}
See {hi:[P] ereturn} for the general outline of
an estimation command program and for examples of {cmd:ereturn post},
{cmd:repost}, and {cmd:display}.  Within such a program you could save
{hi:e()} results using something like

{tab}{it:...}
{phang2}{cmd:ereturn local depvar "`depname'"}{p_end}
{phang2}{cmd:ereturn scalar N = `nobs'}{p_end}
{phang2}{cmd:ereturn matrix lambda lam}{p_end}
{phang2}{cmd:ereturn local cmd "myestcmd"}{p_end}
{tab}{it:...}

{pstd}The user of an estimation command would type

{phang2}{cmd:. ereturn list}

{pstd}to see what was returned from an estimation command.


{title:Also see}

{psee}
Manual:  {bf:[P] ereturn}

{psee}
Online:  {help estcom},
{helpb estimates},
{helpb mark},
{helpb matrix},
{helpb matrix makecns},
{helpb matrix rownames},
{helpb ml},
{help postest},
{helpb return}
{p_end}