xtile.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
 xtile

 *!  VERSION 1.1.0  19nov2004

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help xtile")
RESET res1

DIALOG main,  tabtitle("Main")	///
	label("xtile - Create variable containing quantile categories")
BEGIN
  INCLUDE _exp_vareq
  GROUPBOX gb_opt          _lft      _xls      _iwd      _ht11,		///
	label("Options")
  RADIO    rb_nquant       _indent   _ms       _rbwd     .,		///
	first onclickon(script nquant_on)
  DEFINE _x @x
  SPINNER  sp_nquant       _cksep    @         _spwd     .,		///
	label("Number of quantiles")					///
	min(2) max(100) default(2) option(nquantiles)
  TEXT     tx_nquant       _spsep    @         _cksprb   .,		///
	label("Number of quantiles")
  RADIO    rb_cutp         _x        _ls       _ibwd     .,		///
	label("Use the values of this variable as cutpoints:")		///
	onclickon(script cutp_on) last
  VARNAME  vn_cutp         _indent2  _ss       _vnwd     .,		///
	label("Use the values of this variable as cutpoints") 		///
	option(cutpoints)
  CHECKBOX ck_altdef       _x        _ls       _ibwd     .,		///
	label("Alternative formula for calculating percentiles")	///
 	option(altdef) 							///
	onclickon(program disable_weights)				///
	onclickoff(program enable_weights)
END

INCLUDE ifin
INCLUDE weights_fpa

SCRIPT nquant_on
BEGIN
	main.sp_nquant.enable
	main.vn_cutp.disable
END

SCRIPT cutp_on
BEGIN
	main.sp_nquant.disable
	main.vn_cutp.enable
END

PROGRAM command
BEGIN
	put "xtile "
	INCLUDE _exp_vareq_pr
	INCLUDE  _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_nquant {
			optionarg /hidedefault main.sp_nquant
		}
		if main.rb_cutp {
			require main.vn_cutp
			optionarg main.vn_cutp
		}
		option main.ck_altdef
	endoptions
END