xtline_98s.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 127 行

/*
  xtline_98s
  ** Special version for Windows 95/98
  ** Extra small

*!  VERSION 1.1.0  10mar2005

*/

VERSION 9.0

INCLUDE graph_header
INCLUDE header
HELP hlp1, view("help xtline")
RESET res1

DIALOG main, label("xtline - Panel data line plots")  tabtitle("Main")
BEGIN
  RADIO    rb_by       _lft        _top      _gwd1       .,		///
  		label("Graph by panel") 				///
  		first							///
  		onclickon(script main_by_on)
  RADIO    rb_overlay _lft         _ss       @           .,		///
  		label("Overlay each panel on the same graph")		///
  		last							///
  		onclickon(script main_overlay_on)

  TEXT     tx_vars     _lft        _ls       _gwd1       .,		///
                label("Variables:")
  TEXT     tx_var      @           @         @           .,		///
  		label("Variable:")

  VARLIST  vn_vars     @           _ss       _gwd1       .,		///
                label("Variables")
  VARNAME  vn_var      @           @         _vnwd       .,		///
  		label("Variable")

  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_tsset

END

SCRIPT main_by_on
BEGIN
	main.tx_var.hide
	main.vn_var.hide
	script p1_opts_disable
	script p2_opts_disable

	main.tx_vars.show
	main.vn_vars.show
	script gby_enable
END

SCRIPT main_overlay_on
BEGIN
	main.tx_vars.hide
	main.vn_vars.hide
	script gby_disable

	main.tx_var.show
	main.vn_var.show
	script p1_opts_enable
	script p2_opts_enable
END

INCLUDE ifin
INCLUDE p1_opts
INCLUDE p2_opts

SCRIPT PREINIT
BEGIN
	script p1_opts_createAsNoRange
	script p1_opts_setDefaultLine
	script p2_opts_createAsNoRange
	script p2_opts_setDefaultLine
END

SCRIPT POSTINIT
BEGIN
	script gby_setViewByopts
	p1_opts.settabtitle "Plot 1"
	p2_opts.settabtitle "Plot 2"

	p1_opts_specialOutput.setstring "plopts1"
	p2_opts_specialOutput.setstring "plopts2"
END

INCLUDE gyaxis_98s
INCLUDE gtaxis_98s
INCLUDE gtitle_98s
INCLUDE glegend_98s
INCLUDE gregion_98s
INCLUDE gby_98s

PROGRAM command
BEGIN
	put "xtline "
	if main.rb_by {
		require main.vn_vars
		put main.vn_vars
	}
	if main.rb_overlay {
		require main.vn_var
		put main.vn_var
	}

	INCLUDE _ifin_pr
	beginoptions
		if main.rb_overlay {
			put "overlay "
			put " " /program p1_opts_special_output
			put " " /program p2_opts_special_output
		}

		put " " /program gyaxis_output
		put " " /program gtaxis_output
		put " " /program gtitle_output
		put " " /program glegend_output
		put " " /program gregion_output
		if main.rb_by {
			put " " /program gby_byopts_output
		}
	endoptions
END