xtmixed_p.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 135 行

/*
	predict (after xtmixed)

*!  VERSION 1.0.0  18mar2005

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht250
INCLUDE header

HELP hlp1, view("help xtmixed postestimation")
RESET res1

DIALOG main, label("predict - Prediction after estimation") tabtitle("Main")
BEGIN
  TEXT     tx_vars           _lft      _top      _vlwd     .,		/*
		*/ label("New variable names or variable stub* :")
  EDIT     ed_vars           @         _ss       @         .,		/*
		*/ label("New variable names or variable stub*")
  TEXT     tx_var            _lft      _top      @         .,		/*
		*/ label("New variable name:")
  EDIT     ed_var            @         _ss       _vnwd     .,		/*
		*/ label("New variable name") max(32)

  TEXT     tx_type           _vlsep    _top      _vlr      .,		/*
		*/ label("New variable type:")
  COMBOBOX cb_type           @         _ss       @         .,		/*
		*/ dropdownlist						/*
		*/ contents(type) default(c(type))			/*
		*/ label("Type")
  GROUPBOX gb_opts           _lft      _ls       _iwd      _ht15,	/*
		*/ label("Produce:")
  RADIO    rb_blups          _ilft     _ss       _ibwd     .,		///
  		option(blups) first onclickon(script blups)		///
		label("Calculate linear unbiased predictions (BLUPs)")
  RADIO    rb_xb             @         _ss       @         .,		///
  		option(xb) clickon(script xb)				///
label("Calculate linear prediction for the fixed portion of the model (xb)")
  RADIO    rb_stdp           @         _ss       @         .,		///
  		option(stdp) clickon(script xb)				///
	label("Standard error of the linear prediction")
  RADIO    rb_fitted         @         _ss       @         .,		///
  		option(fitted) clickon(script mostothers)			///
		label("Fitted values")
  RADIO    rb_residuals      @         _ss       @         .,		///
  		option(residuals) clickon(script mostothers)		///
		label("Residuals, response minus fitted values")
  RADIO    rb_rstandard      @         _ss       @         .,		///
  		option(rstandard) clickon(script mostothers) last	///
		label("Standardized residuals")
  EDIT     ed_level          @         _ls       _vnwd     .,		///
label("Random effects level for predictions") option(level)
  TEXT     tx_level          _vnsep    @         _vnrb     .,		///
label("Random effects level for predictions")

END

INCLUDE ifin
INCLUDE _type_list_fd

SCRIPT xb
BEGIN
	script onevar
	main.ed_level.disable
	main.tx_level.disable
END

SCRIPT blups
BEGIN
	main.tx_level.enable
	main.ed_level.enable
	script manyvars
END

SCRIPT mostothers
BEGIN
	main.tx_level.enable
	main.ed_level.enable
	script onevar
END

SCRIPT manyvars
BEGIN
	main.tx_vars.show
	main.ed_vars.show
	main.tx_var.hide
	main.ed_var.hide
END

SCRIPT onevar
BEGIN
	main.tx_vars.hide
	main.ed_vars.hide
	main.tx_var.show
	main.ed_var.show
	main.tx_level.enable
	main.ed_level.enable
END

PROGRAM command
BEGIN
	put "predict "
	if main.cb_type.isdefault() {
		if main.rb_blups {
			require main.ed_vars
			put main.ed_vars " "
		}
		if !main.rb_blups {
			require main.ed_var
			put main.ed_var " "
		}
	}
	if ! main.cb_type.isdefault() {
		put main.cb_type " " "("
		if main.rb_blups {
			require main.ed_vars
			put main.ed_vars
		}
		if !main.rb_blups {
			require main.ed_var
			put main.ed_var
		}
		put ") "
	}
	INCLUDE _ifin_pr
	beginoptions
		option radio(main rb_blups rb_xb rb_stdp /*
			*/ rb_fitted rb_residuals rb_rstandard)
		optionarg main.ed_level
	endoptions
END