xtmixed_estat.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	xtmixed_estat

*!  VERSION 1.0.1  31mar2005

*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 330
INCLUDE header

HELP hlp1, view("help xtmixed postestimation")
RESET res1

DIALOG main, label("estat -  Postestimation tools for xtmixed") tabtitle("Main")
BEGIN
  TEXT     tx_subcmd		_lft	_top	_cwd1	.,		///
  	label("Reports and statistics: (subcommand)")
  LISTBOX  lb_subcmd		@	_ss	_iwd	70,		///
  	contents(main_subcommand_contents)				///
  	values(main_subcommand_values)					///
  	onselchangelist(main_subcommand_scripts)

  DEFINE holdy 110
  // group
  TEXT     tx_gpnote		_lft	holdy	_iwd	.,		///
  	label("Click OK or Submit to summarize the composition of the nested groups")

  // recovariance options
  CHECKBOX ck_level		_lft	holdy	_iwd	.,		///
	onclickon(script level_on)					///
	onclickoff(script level_off)					///
	label("Specify level at which the random-effects covariance matrix is to be displayed")
  EDIT     ed_level	       _indent2	_ss	_vnwd	.,		///
	option(level) default("_all")					///
	label("Level at which the random-effects covariance matrix is to be displayed")
  TEXT     tx_level		_vnsep	@	200	.,		///
  	label("Level")

  // Information criteria
  TEXT     tx_icnote		_lft	holdy	_iwd	.,		///
  	label("Click OK or Submit to display the AIC and BIC information criteria")

  // Summarize options
  GROUPBOX gb_eqlist            _lft    holdy	_iwd	_ht6,		///
  	label("Summarize")
  RADIO    rb_default		_ilft	_ss	_inwd	.,		///
  	first label("Use all variables involved in the estimation")	///
  	onclickon(main.vl_spec.disable)
  RADIO    rb_spec		@	_ss	@	.,		///
	onclickon(main.vl_spec.enable) last				///
	label("Use variables and optional equation names:")
  VARLIST  vl_spec	      _indent2	_ss	_inwd	.,		///
	label("Use variables and optional equation names:")
  CHECKBOX ck_equation      	_lft	+45	_iwd	.,		///
	option(equation)						///
	label("Display summary by equation")
  CHECKBOX ck_labels		@	_ms	@	.,		///
  	label("Display variable labels")				///
  	option(labels)
  CHECKBOX ck_noheader		_lft	_ms	_iwd	.,		///
	option(noheader)						///
	label("Suppress the header")
  CHECKBOX ck_noweights		@	_ms	@	.,		///
	option(noweights)						///
	label("Ignore weights")

  INCLUDE estat_vce
END

INCLUDE estat_vce_pr

LIST main_subcommand_contents
BEGIN
  	 "Summarize the composition of the nested groups (group)"
  	 "Estimated random-effects covariance matrix (recovariance)"
 	 "Information criteria (ic)"
 	 "Summarize estimation sample (summarize)"
 	 "Covariance matrix estimates (vce)"
END

LIST main_subcommand_values
BEGIN
	group
	recovariance
	ic
	summarize
	vce
END

LIST main_subcommand_scripts
BEGIN
	script sel_group
	script sel_recovariance
	script sel_ic
	script sel_summarize
	script sel_vce
END

SCRIPT sel_group
BEGIN
	main.tx_icnote.hide
	script main_summ_off
	program vce_off
	script non_basic_opt_off
	main.tx_gpnote.show
END

SCRIPT sel_recovariance
BEGIN
	main.tx_icnote.hide
	script main_summ_off
	program vce_off
	script non_basic_opt_off
	script recovariance_on
END

SCRIPT sel_ic
BEGIN
	main.tx_icnote.show
	script main_summ_off
	program vce_off
	script non_basic_opt_off
END

SCRIPT sel_summarize
BEGIN
	main.tx_icnote.hide
	script main_summ_on
	program vce_off
	script non_basic_opt_off
END

SCRIPT sel_vce
BEGIN
	main.tx_icnote.hide
	program vce_on
	script main_summ_off
	script non_basic_opt_off
END

SCRIPT recovariance_on
BEGIN
	// controls located in estat_vce
	main.gb_matdisp.show
	main.rb_covariance.show
	main.rb_correlation.show

	main.ck_level.setposition . 170 . .
	main.ed_level.setposition . 190 . .
	main.tx_level.setposition . 190 . .
	main.ck_level.show
	main.ed_level.show
	main.tx_level.show
END

SCRIPT non_basic_opt_off
BEGIN
	main.tx_gpnote.hide
	main.ck_level.hide
	main.ed_level.hide
	main.tx_level.hide
END

SCRIPT main_summ_on
BEGIN
	main.ck_equation.show
	main.ck_labels.show
	main.ck_noheader.show
	main.ck_noweights.show
	main.gb_eqlist.show
	main.rb_default.show
	main.rb_spec.show
	main.vl_spec.show
END

SCRIPT main_summ_off
BEGIN
	main.ck_equation.hide
	main.ck_labels.hide
	main.ck_noheader.hide
	main.ck_noweights.hide
	main.gb_eqlist.hide
	main.rb_default.hide
	main.rb_spec.hide
	main.vl_spec.hide
END

SCRIPT level_on
BEGIN
	main.ed_level.enable
	main.tx_level.enable
END

SCRIPT level_off
BEGIN
	main.ed_level.disable
	main.tx_level.disable
END

PROGRAM vl_output
BEGIN
	put main.vl_spec
END

PROGRAM vl_eq_output
BEGIN
	put main.vl_eq
END

PROGRAM command
BEGIN
	put "estat "
	put main.lb_subcmd
	if main.rb_spec {
		require main.vl_spec
		put " " main.vl_spec
	}
	beginoptions
		// Summarize options
		option main.ck_equation
		option main.ck_labels
		option main.ck_noheader
		option main.ck_noweights

		put /program vce_output
		// other options
		if main.ck_level {
			require main.ed_level
			optionarg main.ed_level
		}
	endoptions
END