xtrc_p.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 69 行

/*
	predict (after xtrc)

*!  VERSION 1.1.2  28mar2005

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help xtrc postestimation")
RESET res1

DIALOG main, label("predict - Prediction after estimation") tabtitle("Main")
BEGIN
  INCLUDE  _p_gentype

  GROUPBOX gb_opts	_lft	_xls	_iwd	_ht8,	///
	label("Produce")
  RADIO    rb_xb	_indent	_ss	_inwd	., 	///
	first						///
	option(xb)					///
	label("Linear prediction")
  RADIO    rb_stdp	@	_ss	@	.,	///
	option(stdp)					///
	label("Standard error of the linear prediction")
  RADIO    rb_group	@	_ss	@	.,	///
	last						///
	onclickon(script main_group_on)			///
	onclickoff(script main_group_off)		///
	label("Best linear predictions based on group")
  SPINNER  sp_group	_indent2 _ss	_spwd	.,	///
  	option(group) default(1) min(1) max(10000)
  TEXT     tx_group	_spsep	@	150	.,	///
	label("Group number")
  INCLUDE  _p_nooffset
END

SCRIPT main_group_on
BEGIN
	main.sp_group.enable
	main.tx_group.enable
END

SCRIPT main_group_off
BEGIN
	main.sp_group.disable
	main.tx_group.disable
END

INCLUDE _p_gentype_sc
INCLUDE ifin
INCLUDE _type_list_fd

PROGRAM command
BEGIN
	put "predict "
	put " " /program _p_gentype_output
	INCLUDE _ifin_pr
	beginoptions
		option main.rb_xb
		option main.rb_stdp
		optionarg main.sp_group
	endoptions
	INCLUDE _p_nooffset_pr
END