xtrc.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 79 行

/*
  xtrc

*!  VERSION 1.1.3  28mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help xtrc")
RESET res1

DIALOG main, label("xtrc - Random coefficients regression") tabtitle("Model")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_panelset
  INCLUDE _dviv4set
  CHECKBOX ck_nocons	@	_ms	@	.,	///
	label("Suppress constant term")			///
	option(noconstant)

  TEXT     tx_offset	_lft	_ls	_cwd2	.,	///
	label("Offset variable: (optional)")
  VARNAME  vn_offset	@	_ss	_vnwd	.,	///
	label("Offset variable")			///
	option(offset)
END

INCLUDE byifin
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrap
END

SCRIPT POSTINIT
BEGIN
	script se_setCluster_off
	script se_setTitleSE
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y 20
  INCLUDE _sp_level

  CHECKBOX ck_betas	_lft	_ls	_iwd	.,	///
	option(betas)					///
	label("Display group-specific best linear predictors")
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "xtrc "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		optionarg main.vn_offset
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		option rpt.ck_betas
	endoptions
END