xttest0.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.3.4  29sep2000
program define xttest0, rclass sort
	version 4.0
	if "`e(cmd)'"!="xtreg" { error 301 }
	if "`e(model)'" != "re" {
		di in red "last estimates not xtreg, re"
		exit 301
	}
	if "`*'"!="" { error 198 }
	tempvar touse e sum Ti
	tempname cur Tn T ee LM
	tempname A1 M11

	qui gen byte `touse' = e(sample)

	_evlist
	local rhs "`s(varlist)'"
	sret clear
	local lhs "`e(depvar)'"
	local ivar "`e(ivar)'"

	estimate hold `cur'
	capture {
		regress `lhs' `rhs' if `touse'
		predict double `e' if `touse', resid
	}
	if _rc {
		estimate unhold `cur'
		error _rc
	}
	estimate unhold `cur'
	quietly {
		sort `e(ivar)'
		by `e(ivar)': gen long `Ti' = cond(_n==_N,sum(`touse'),.)
		gen double `sum' = sum(`Ti'^2)
		scalar `M11' = `sum'[_N]
		drop `sum'

		by `e(ivar)': gen double `sum' = cond(_n==_N,sum(`e')^2,.) 
		replace `sum' = sum(`sum')
		scalar `A1' = `sum'[_N]

		replace `sum' = sum(`e'^2)
		scalar `A1' = 1-`A1'/`sum'[_N]
	}
	scalar `LM'=scalar( ((e(N)^2)/2) * ( (`A1'^2)/(`M11'-e(N)) ) )

	#delimit ;
	di _n in gr 
	"Breusch and Pagan Lagrangian multiplier test for random effects:" ;
	di _n in gr _col(9) 
	   "`e(depvar)'[`e(ivar)',t] = Xb + u[`e(ivar)'] + e[`e(ivar)',t]" ;
	di in smcl _n in gr _col(9) "Estimated results:" _n
		_col(26) "{c |}"
		_col(34) "Var" _col(42) "sd = sqrt(Var)" _n 
		_col(17) "{hline 9}{c +}{hline 29}" ;
		
	qui summ `e(depvar)' if `touse' ;
	di in smcl _col(16) in gr %9s abbrev("`e(depvar)'",9) " {c |}  " in ye
		%9.0g r(Var) _skip(6) %9.0g sqrt(r(Var)) ;
	di in smcl _col(24) in gr "e {c |}  " in ye 
		%9.0g e(sigma_e)^2 _skip(6) %9.0g e(sigma_e) ;
	di in smcl _col(24) in gr "u {c |}  "  in ye 
		%9.0g e(sigma_u)^2 _skip(6) %9.0g e(sigma_u) ;

	di _n in gr _col(9) "Test:" _col(17) "Var(u) = 0" _n 
		_col(31) "chi2(1) = " in ye %8.2f `LM' _n in gr 
		_col(27) "Prob > chi2 = " _col(44) in ye %7.4f 
		chiprob(1,`LM') ;

#delimit cr
	ret scalar lm = `LM'
	ret scalar df = 1
	ret scalar p = chiprob(1,`LM')

	global S_1 = `LM'	/* double save */
end
exit

Breusch and Pagan Langrangian multiplier test for random effects
----------------------------------------------------------------

        lnC[firm,t] = Xb + u[firm] + e[firm,t]

	Estimated results:
                               Var       sd = sqrt(Var)
		---------+-----------------------------
----+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8
		longlong |  123456789      123456789
		       u |  123456789      123456789
		       e |  123456789      123456789

	Test:			sd(u) = 0
                              chi2(1) = xxxxx.xx
			  Prob > chi2 =    Xx.xxxx