intreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  intreg

*! VERSION 1.1.1  21feb2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header
HELP hlp1, view("help intreg")
RESET res1

DIALOG main, label("intreg - Interval regression")			/*
		*/ tabtitle("Model")
BEGIN
  TEXT     tx_dv1    _lft      _top      _iwd      .,			/*
		*/ label("Dependent variable 1:")			/*
		*/
  VARNAME  vn_dv1    @         _ss       _vnwd     .,			/*
		*/ label("Dependent variable 1")			/*
		*/

  TEXT     tx_dv2    _vlx      _top      _iwd      .,			/*
		*/ label("Dependent variable 2:")			/*
		*/
  VARNAME  vn_dv2    @         _ss       _vnwd     .,			/*
		*/ label("Dependent variable 2")			/*
		*/

  TEXT     tx_iv     _lft      _ls       _iwd      .,			/*
		*/ label("Independent variables:")			/*
		*/
  VARLIST  vl_iv     @         _ss       @         .,			/*
		*/ label("Independent variables")			/*
		*/ allowcat						/*
		*/
  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_output _lft      _ms      _iwd      _ht15h,		/*
		*/ label("Options")					/*
		*/
  CHECKBOX ck_het    _ilft     _ss       _ibwd     _ht2h,		/*
  		*/ groupbox						/*
		*/ label("Independent variables to model the variance")/*
		*/ clickon("script het_on")				/*
		*/ clickoff("script het_off")
  VARLIST  vl_het    _indent   _ms       _cwd2          .,		/*
		*/ label("Independent variables to model the variance")	/*
		*/ allowcat
  CHECKBOX ck_nocon  _ilft2    @         _cwd5              .,		/*
		*/ label("Suppress constant term")			/*
		*/ option(noconstant)

  TEXT     tx_offset _ilft     _xls      @         .,			/*
		*/ label("Offset variable:")				/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/
  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ms
  INCLUDE _constraints

END

SCRIPT het_on
BEGIN
	main.vl_het.enable
	main.ck_nocon.enable
END

SCRIPT het_off
BEGIN
	main.vl_het.disable
	main.ck_nocon.disable
END

INCLUDE byifin
INCLUDE weights_fpai
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END


DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y _top
  INCLUDE _sp_level
END

PROGRAM rpt_output
BEGIN
	optionarg /hidedefault rpt.sp_level
END

INCLUDE max_ml

PROGRAM subcommand
BEGIN
	require main.vl_het
	put main.vl_het
	beginoptions
		option main.ck_nocon
	endoptions
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "intreg "
	varlist main.vn_dv1
	varlist main.vn_dv2 [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		if main.ck_het {
			put "het("
			put /program subcommand
			put ")"
		}
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		put " " /program se_output
		put " " /program rpt_output
		put " " /program max_output
	endoptions
END