outsheet.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	outsheet

*! VERSION 1.1.0  29nov2004

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE _ht260
INCLUDE header

HELP hlp1, view("help outsheet")
RESET res1

DIALOG main, label("outsheet - Export spreadsheet-style dataset")	///
	tabtitle("Main")
BEGIN
  TEXT     tx_var            _lft      _top      _iwd      .,		///
	label("Variables:  (leave empty for all variables)")
  VARLIST  vl_var            @         _ss       @         .,		///
	label("Variables")

  TEXT     tx_using          @         _ls       @         .,		///
	label("Write to the file:")
  FILE     fi_using          @         _ss       @         .,		///
	error("Write to the file")					///
	label("Save As...")						///
	filter("Raw Files (*.raw)|*.raw|Text Files (*.txt)|*.txt|Comma Separated Values (*.csv)|*.csv|All (*.*)|*.*")	///
	defext(raw)							///
	save

  GROUPBOX gb_options        @         +35       @         _ht10,	///
	label("Options")
  CHECKBOX ck_comma          _ilft     _ss       _ibwd     .,		///
	option(comma)							///
	label("Comma-separated (instead of tab-separated) format")

  CHECKBOX ck_nonames        @         _ms       @         .,		///
	option(nonames)							///
	label("Do not write variable names on the first line")

  CHECKBOX ck_nolabel        @         _ms       @         .,		///
	option(nolabel)							///
	label("Output numeric values (not labels) of labeled variables")

  CHECKBOX ck_noquote        @         _ms       @         .,		///
	option(noquote) label("Do not enclose strings in double quotes")
END

INCLUDE ifin

PROGRAM command
BEGIN
	require main.fi_using
	put "outsheet "
	varlist [main.vl_var]
	repfile main.fi_using
	put " using " `"""' main.fi_using `"""' " "
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_comma
		option main.ck_nonames
		option main.ck_nolabel
		option main.ck_noquote
		put "replace"
	endoptions
END