cluster_stop.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 90 行

/*
  cluster stop

*! VERSION 1.2.1  31mar2005

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE _ht310
INCLUDE header
HELP hlp1, view("help cluster_stop")
RESET res1

DIALOG main, label("cluster stop - Cluster analysis stopping rules") /*
		*/ tabtitle("Main")
BEGIN
  TEXT     tx_clname    _lft      _top      _cwd3_1   .,		/*
		*/ label("Cluster analysis:")
  LISTBOX  lb_clname    @         _ss       @         _ht23h,		/*
		*/ contents(char _dta[_cl])				/*
		*/ label("Cluster analysis")

  GROUPBOX gb_rule      _lft3_2   _top      _comb3_1  _ht4,		/*
		*/ label("Stopping rule")
  RADIO    rb_calinski  _indent   _ss       _inwd     ., first		/*
		*/ option("rule(calinski)")				/*
		*/ label("Calinski/Harabasz pseudo-F index")
  RADIO    rb_duda      @         _ss       @         ., last		/*
		*/ option("rule(duda)")					/*
		*/ label("Duda/Hart Je(2)/Je(1) index")

  GROUPBOX gb_options   _lft3_2   _xls      _comb3_1  _ht17h,		/*
		*/ label("Options")
  CHECKBOX ck_groups    _indent   _ss       _inwd     .,		/*
		*/ clickon("gaction main.sp_groups.enable")		/*
		*/ clickoff("gaction main.sp_groups.disable")		/*
		*/ label("Compute for groups up to:")
  DEFINE   holdx @x
  DEFINE   holdcx @cx
  TEXT     tx_groups    _indent2  _vss      _inwd     .,		/*
		*/ label("(hierarchical clustering only)")
  SPINNER  sp_groups    @         _ms       _spwd     .,		/*
		*/ min(2) max(100000) default(15)			/*
		*/ label("Compute for groups up to")
  TEXT     tx_matrix    holdx     _ls       holdcx    .,		/*
		*/ label("Save the results in matrix:")
  EDIT     ed_matrix    @         _ss       _vnwd     .,		/*
		*/ option(matrix)					/*
		*/ max(32)						/*
		*/ label("Save the results in matrix")
  CHECKBOX ck_variables @         _ls       holdcx    .,		/*
		*/ clickon("gaction main.vl_variables.enable")		/*
		*/ clickoff("gaction main.vl_variables.disable")	/*
		*/ label("Compute the stopping rule using")
  TEXT     tx_variables _indent2  _vss      _inwd     .,		/*
		*/ label("these variables:")
  VARLIST  vl_variables @         _ss       .         .,		/*
		*/ label("Compute the stopping rule using these variables") /*
		*/ option(variables)
END


PROGRAM command
BEGIN
	put "cluster stop " main.lb_clname
	beginoptions
		option radio(main rb_calinski rb_duda)
		if main.ck_groups {
			put "groups("
			if main.rb_calinski {
				put "2"
			}
			if main.rb_duda {
				put "1"
			}
			put "/" main.sp_groups ") "
		}
		optionarg main.ed_matrix
		if main.ck_variables {
			if !main.vl_variables {
				stopbox stop `""Compute the stopping rule using these variables" must be filled in"'
			}
			optionarg main.vl_variables
		}
	endoptions
END