canon_estat.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 200 行

/*
	canon_estat

*!  VERSION 1.0.2  31mar2005

	***
	USE EXTREME CARE WHEN CHANGING CONTROL NAMES. The names used
	in this file have multiple external dependencies.
*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 340
INCLUDE header

HELP hlp1, view("help canon postestimation")
RESET res1

DIALOG main, label("estat - Postestimation tools for canon") tabtitle("Main")
BEGIN
  TEXT     tx_subcmd		_lft	_top	300	.,		///
  	label("Reports and statistics: (subcommand)")
  LISTBOX  lb_subcmd		@	_ss	@	70,		///
  	contents(main_subcommand_contents)				///
  	values(main_subcommand_values)					///
  	onselchangelist(main_subcommand_scripts)

  DEFINE holdy 110

  // Options for correlations and loadings
  CHECKBOX ck_format_1		_lft	holdy	_iwd	.,		///
  	label("Override display format") 				///
  	onclickon(script main_format_on)				///
  	onclickoff(script main_format_off)
  EDIT     ed_format_1	       _indent2	_ss	_en7wd	.,		///
  	default(%8.4f) option(format) label("Display format")
  BUTTON   bn_format_1	      _cken7sep	@      _cken7r2	.,		///
	label("Help format...")	onpush(view help format##|_new)

  // Summarize options
  GROUPBOX gb_eqlist            _lft    holdy	_iwd	_ht6,		///
  	label("Summarize")
  RADIO    rb_default		_ilft	_ss	_inwd	.,		///
  	first label("Use all variables involved in the estimation")	///
  	onclickon(main.vl_spec.disable)
  RADIO    rb_spec		@	_ss	@	.,		///
	onclickon(main.vl_spec.enable) last				///
	label("Use variables and optional equation names:")
  VARLIST  vl_spec	      _indent2	_ss	_inwd	.,		///
	label("Use variables and optional equation names")
  CHECKBOX ck_equation      	_lft	+45	_iwd	.,		///
	option(equation)						///
	label("Display summary by equation")
  CHECKBOX ck_labels		@	_ms	@	.,		///
  	label("Display variable labels")				///
  	option(labels)
  CHECKBOX ck_noheader		_lft	_ms	_iwd	.,		///
	option(noheader)						///
	label("Suppress the header")
  CHECKBOX ck_noweights		@	_ms	@	.,		///
	option(noweights)						///
	label("Ignore weights")

  INCLUDE estat_vce
END

INCLUDE estat_vce_pr

LIST main_subcommand_contents
BEGIN
	"Show correlation matrices (correlations)"
	"Show loaging matrices (loadings)"
	"Summarize estimation sample (summarize)"
	"Display covariance matrix estimates (vce)"
END

LIST main_subcommand_values
BEGIN
	correlations
	loadings
	summarize
	vce
END

LIST main_subcommand_scripts
BEGIN
	script sel_correlations
	script sel_loadings
	script sel_summarize
	script sel_vce
END

SCRIPT sel_correlations
BEGIN
	script main_hide_all
	main.ck_format_1.show
	main.ed_format_1.show
	main.bn_format_1.show
END

SCRIPT sel_loadings
BEGIN
	script main_hide_all
	main.ck_format_1.show
	main.ed_format_1.show
	main.bn_format_1.show
END

SCRIPT sel_summarize
BEGIN
	script main_hide_all
	script main_summ_on
END

SCRIPT sel_vce
BEGIN
	script main_hide_all
	program vce_on
END

SCRIPT main_summ_on
BEGIN
	main.ck_equation.show
	main.ck_labels.show
	main.ck_noheader.show
	main.ck_noweights.show
	main.gb_eqlist.show
	main.rb_default.show
	main.rb_spec.show
	main.vl_spec.show
END

SCRIPT main_summ_off
BEGIN
	main.ck_equation.hide
	main.ck_labels.hide
	main.ck_noheader.hide
	main.ck_noweights.hide
	main.gb_eqlist.hide
	main.rb_default.hide
	main.rb_spec.hide
	main.vl_spec.hide
END

SCRIPT main_hide_all
BEGIN
	program vce_off
	script main_summ_off
	main.ck_format_1.hide
	main.ed_format_1.hide
	main.bn_format_1.hide
END

SCRIPT main_format_on
BEGIN
	main.ed_format_1.enable
	main.bn_format_1.enable
END
SCRIPT main_format_off
BEGIN
	main.ed_format_1.disable
	main.bn_format_1.disable
END

PROGRAM vl_output
BEGIN
	put main.vl_spec
END

PROGRAM vl_eq_output
BEGIN
	put main.vl_eq
END

PROGRAM command
BEGIN
	put "estat "
	put main.lb_subcmd

	if main.rb_spec {
		require main.vl_spec
		put " " main.vl_spec
	}

	beginoptions
		// correlations and loadings options
		if main.ck_format_1 {
			require main.ed_format_1
			optionarg main.ed_format_1
		}
		// Summarize options
		option main.ck_equation
		option main.ck_labels
		option main.ck_noheader
		option main.ck_noweights
		put " " /program vce_output
	endoptions
END