ca.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	ca

*!  VERSION 1.0.0  25feb2005

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header
HELP hlp1, view("help ca")
RESET res1


DIALOG main, tabtitle("Model") label("ca - Simple correspondence analysis")
BEGIN
  TEXT     tx_rowvar		_lft	_top	_cwd0	.,		///
	label("Row category variable:")
  VARNAME  vn_rowvar		@	_ss	_vnwd	.,		///
	label("Row category variable")
  TEXT     tx_colvar		@	_ls	_cwd0	.,		///
	label("Column category variable:")
  VARNAME  vn_colvar		@	_ss	_vnwd	.,		///
	label("Column category variable")
END

DIALOG model2, tabtitle("Model 2")
BEGIN
  CHECKBOX ck_dimensions	_lft	_top	_iwd	.,		///
  	onclickon(script ck_dimensions_on)				///
  	onclickoff(script ck_dimensions_off)				///
	label("The number of dimensions to be extracted:")

  SPINNER  sp_dimensions	_indent2	_ss	_spwd	.,	///
	label("Dimensions")						///
	min(1)								///
	max(1000)							///
	default(2)							///
	option(dimensions)
  TEXT     tx_dimensions	_spsep	@	_cksprb	.,		///
	label("Dimensions")

  GROUPBOX gb_normalize		_lft	_ls	_iwd	_ht6,		///
	label("Normalization method")
  RADIO	rb_default		_ilft	_ss	_cwd1	.,		///
	first label("Symmetric coordinates (default)") 			///
	option(NONE)
  DEFINE holdy @y
  RADIO	rb_row			@	_ss	@	., 		///
	label("Row principal coordinates")				///
	option(normalize(row))
  RADIO	rb_column		@	_ss	@	., 		///
	label("Column principal coordinates")				///
	option(normalize(column))

  RADIO	rb_principal		_lft2	holdy	_cwd2	., 		///
	label("Principal coordinates")					///
	option(normalize(principal))
  RADIO	rb_power		@	_ss	@ 	.,		///
	last label("Power 0<=#<=1 for row coordinates")			///
  	onclickon(script ck_power_on)					///
  	onclickoff(script ck_power_off)					///
	option(NONE)
  EDIT     ed_power	_indent2  _ss	_en7wd	.,			///
	option(normalize)						///
	label("Power #")
  TEXT     tx_power	_spsep	@	_ckwd	.,			///
	label("#")

  TEXT     tx_rowsupp		_lft	_xls	_cwd2	.,		///
	label("Matrix of suplementary rows:")
  DEFINE holdy @y
  COMBOBOX cb_rowsupp		@       _ss     _vnwd	.,		///
	label("Matrix of suplementary rows")				///
	dropdown option(rowsupp)					///
	contents(matrix)
  TEXT     tx_colsupp		_lft2	holdy	_cwd2	.,		///
	label("Matrix of suplementary columns:")
  COMBOBOX cb_colsupp		@       _ss     _vnwd	.,		///
	label("Matrix of suplementary columns")				///
	dropdown option(colsupp)					///
	contents(matrix)

  CHECKBOX ck_missing		_lft	_ls	_iwd	.,		///
	label("Treat missing values as ordinary values")		///
	option(missing)

END

INCLUDE byifin

INCLUDE weights_fai

DIALOG report, tabtitle("Reporting")
BEGIN
  CHECKBOX ck_norowpoints	_lft	_top	_iwd	.,		///
	label("Suppress table for row points")				///
	option(norowpoints)
  CHECKBOX ck_nocolpoints	@	_ms	@	.,		///
	label("Suppress table for column points")			///
	option(nocolpoints)
  CHECKBOX ck_compact		@	_ms	@	.,		///
	label("Display tables in a compact format")			///
	option(compact)

  GROUPBOX gb_plotopt		_lft	_ls	_iwd	_ht7,		///
	label("Plot options")
  CHECKBOX ck_plot		_ilft	_ss	_ibwd	.,		///
	label("Plot the row and column coordinates")			///
	onclickon(program ck_maxlength_on)				///
	onclickoff(program ck_maxlength_off)				///
	option(plot)
  CHECKBOX ck_maxlength		@	_ms	_ckwd	.,		///
	label("")							///
	onclickon(report.sp_maxlength.enable)				///
	onclickoff(report.sp_maxlength.disable)
  SPINNER  sp_maxlength		_cksep	@	_spwd	.,		///
	label("Number of characters")					///
	min(1)								///
	max(1000)							///
	default(12)							///
	option(maxlength)
  TEXT     tx_maxlength		_spsep	@	_cksprb	.,		///
	label("Number of plotted row/column label characters")
  TEXT     tx_note		_ilft	_ms	_ibwd	.,		///
	label("Note: Additional postestimation plot options available with -cabiplot-.")
END

SCRIPT ck_dimensions_on
BEGIN
	model2.sp_dimensions.enable
	model2.tx_dimensions.enable
END

SCRIPT ck_dimensions_off
BEGIN
	model2.sp_dimensions.disable
	model2.tx_dimensions.disable
END

SCRIPT ck_power_on
BEGIN
	model2.ed_power.enable
	model2.tx_power.enable
END

SCRIPT ck_power_off
BEGIN
	model2.ed_power.disable
	model2.tx_power.disable
END

PROGRAM ck_maxlength_on
BEGIN
	call gaction report.ck_maxlength.enable
	call gaction report.tx_maxlength.enable
	if report.ck_maxlength {
		call gaction report.sp_maxlength.enable
	}
END

PROGRAM ck_maxlength_off
BEGIN
	call gaction report.ck_maxlength.disable
	call gaction report.tx_maxlength.disable
	if report.ck_maxlength {
		call gaction report.sp_maxlength.disable
	}
END

PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "ca "
	require main.vn_rowvar main.vn_colvar
	put main.vn_rowvar " " main.vn_colvar
	INCLUDE _ifin_pr
 	INCLUDE _weights_pr
	beginoptions
		optionarg /hidedefault model2.sp_dimensions
		option radio(model2 rb_default rb_row rb_column rb_principal rb_power)
		if model2.rb_power {
			require model2.ed_power
			optionarg model2.ed_power
		}
		optionarg model2.cb_rowsupp
		optionarg model2.cb_colsupp
		option model2.ck_missing
		option report.ck_norowpoints
		option report.ck_nocolpoints
		option report.ck_compact
		option report.ck_plot
		if report.ck_maxlength {
			optionarg /hidedefault report.sp_maxlength
		}
        endoptions
END