collapse.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	collapse

*!  VERSION 1.1.0  17nov2004

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE _ht200
INCLUDE header
HELP hlp1, view("help collapse")
RESET res1

DIALOG main, tabtitle("Main")	///
	label("collapse - Make dataset of summary statistics")
BEGIN
  TEXT     tx_clist  _lft      _top      _iwd      .,		///
	label("Collapse list:")
  VARLIST  vl_clist  @         _ss       @         .,		///
	label("Collapse list") allowts

  GROUPBOX gb_ex     @         +35       _cwd1     _ht8,	///
	label("Examples")
  DEFINE   holdy @y
  TEXT     tx_ex1    _indent   _vss      _cwd3     .,		///
	label("x y z")
  TEXT     tx_ex2    @         _vss      @         .,		///
	label("(mean) x y z")
  TEXT     tx_ex3    @         _vss      @         .,		///
	label("(median) x y z")
  TEXT     tx_ex4    @         _vss      @         .,		///
	label("(mean) x y (median) z")
  TEXT     tx_ex5    @         _vss      @         .,		///
	label("(min) x-z (max) a-c")

  GROUPBOX gb_stat   _lft2     holdy     _cwd1     _ht8,	///
	label("Statistics")

  TEXT     tx_stat1  _indent   _ss       _cwd4_5   .,		///
	label("mean")
  DEFINE   holdy @y
  TEXT     tx_stat2  @         _vss      @         .,		///
	label("sd")
  TEXT     tx_stat3  @         _vss      @         .,		///
	label("sum")
  TEXT     tx_stat4  @         _vss      @         .,		///
	label("rawsum")
  TEXT     tx_stat5  @         _vss      @         .,		///
	label("count")

  TEXT     tx_dummy  _lft4_4   holdy     0         .,

  TEXT     tx_stat6  _indent   @         _cwd4_5   .,		///
	label("max")

  TEXT     tx_stat7  @         _vss      @         .,		///
	label("min")
  TEXT     tx_stat8  @         _vss      @         .,		///
	label("median")
  TEXT     tx_stat9  @         _vss      @         .,		///
	label("p1 ... p99")
  TEXT     tx_stat10 @         _vss      @         .,		///
	label("iqr")
END

INCLUDE ifin
INCLUDE weights_fpai

DIALOG opt, tabtitle("Options")
BEGIN
  TEXT     tx_byvar  _lft      _top      _iwd      .,		///
	label("Grouping variables:")
  VARLIST  vl_byvar  @         _ss       @         .,		///
	option(by)						///
	label("Grouping variables")

  CHECKBOX ck_cw     @         _ls       @         .,		///
	option(cw)						///
	label("Casewise deletion instead of all possible observations")

/* -fast- is not included because it is an advanced programmer only option */
END

PROGRAM command
BEGIN
	put "collapse "
	varlist main.vl_clist
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if opt.vl_byvar {
			optionarg opt.vl_byvar
		}
		option opt.ck_cw
	endoptions
END