correlate.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 111 行

/*
	correlate

*!  VERSION 1.1.0  06nov2004

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE header
HELP hlp1, view("help correlate")
RESET res1

DIALOG	 main,	label("correlate - Correlations/covariances of variables") /*
		*/	tabtitle("Main")
BEGIN

  TEXT	   tx_var		_lft	_top	_iwd	 .,		/*
		*/	label("Variables:  (leave empty for all)")

  VARLIST  vl_var		@	_ss	@	 .,		/*
		*/	label("Variables")				/*
		*/	allowts

  TEXT	   tx_exp		@	_ms	_cwd1	 .,		/*
		*/	label("Examples:")

  TEXT	   tx_xy		_indent	_vss	_cwd4_2	 .,		/*
		*/	label("yr*")

  DEFINE holdx	@x

  TEXT	   tx_all		_lft4_2	@	_comb4_2 .,		/*
		*/	label(`"all variables starting with "yr""')

  TEXT	   tx_abc		holdx	_vss	_cwd4_2	 .,		/*
		*/	label("xyz-abc")

  TEXT	   tx_xab		_lft4_2 @	_comb4_2 .,		/*
		*/	label("all variables between xyz and abc")
END

INCLUDE byifin
INCLUDE weights_fa

DIALOG opt,	label("correlate - Correlations/Covariances of variables")/*
		*/	tabtitle("Options")
BEGIN

  GROUPBOX gb_opts		_lft	_top	_iwd	 _ht14,		/*
		*/	label("Options")

  RADIO	   rb_coff		_indent	_ss	_ibwd	 .,		/*
	*/ label("Display correlation/covariance matrix for variables") /*
		*/	first						/*
		*/ 	onclickon(script rb_coff_on)			/*
		*/	option(NONE)

  RADIO	   rb_cov		@	_ss	@	 .,		/*
	*/ label("Display correlation/covariance matrix of the coefficients") /*
		*/	last						/*
		*/ 	onclickon(script rb_cov_on)			/*
		*/	option(_coef)

  CHECKBOX ck_means		@	_ms	@	 .,		/*
	*/ label("Display means, std. dev., min, and max with matrix")/*
		*/ 	option(means)

  CHECKBOX ck_noformat		@	_ms	@	 .,		/*
	*/ label("Ignore display format associated with variables")     /*
		*/ 		option(noformat)

  CHECKBOX ck_covariance	@	_ms	@	 .,		/*
		*/	label("Display covariances")			/*
		*/ 	option(covariance)

  CHECKBOX ck_wrap		@	_ms	@	 .,		/*
		*/	label("Allow wide matrices to wrap")		/*
		*/	option(wrap)
END

SCRIPT rb_coff_on
BEGIN
  opt.ck_means.enable
  opt.ck_noformat.enable
END

SCRIPT rb_cov_on
BEGIN
  opt.ck_means.disable
  opt.ck_noformat.disable
END

PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "correlate "
	varlist [main.vl_var]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option radio(opt rb_coff rb_cov)
		option opt.ck_means
		option opt.ck_noformat
		option opt.ck_covariance
		option opt.ck_wrap
	endoptions

END