regress.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  regress

*!  VERSION 1.1.4  21mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help regress")
RESET res1

DIALOG main, label("regress - Linear regression") tabtitle("Model")
BEGIN
  INCLUDE _dviv_ts

  GROUPBOX gb_cons   _lft      _xls      _iwd      _ht8,		/*
  		*/ label("Treatment of constant")
  CHECKBOX ck_nocons _ilft     _ms       _cwd1     .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/
  CHECKBOX ck_hascon @         _ms       @         .,			/*
		*/ label("Has user-supplied constant")			/*
		*/ option("hascons")					/*
		*/
  CHECKBOX ck_tsscon @         _ms       @         .,			/*
		*/ label("Total SS with constant (advanced)")		/*
		*/ option("tsscons")					/*
		*/
END

INCLUDE byifin
INCLUDE weights_fpai
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsOLS
	script se_setBias_on
END

PROGRAM beta_on
BEGIN
  if robust.ck_robust {
    call gaction robust.vn_clust.disable
  }
END

PROGRAM beta_off
BEGIN
  if robust.ck_robust {
    call gaction robust.vn_clust.enable
  }
END


PROGRAM robon
BEGIN
  call gaction robust.gb_bias.enable
  call gaction robust.rb_hc1.enable
  call gaction robust.rb_hc2.enable
  call gaction robust.rb_hc3.enable
  call gaction robust.tx_hc1.enable
  call gaction robust.tx_hc2.enable
  call gaction robust.tx_hc3.enable
  call gaction robust.tx_clust.enable
  if !rpt.ck_beta {
    call gaction robust.vn_clust.enable
  }
END

SCRIPT roboff
BEGIN
  robust.gb_bias.disable
  robust.rb_hc1.disable
  robust.rb_hc2.disable
  robust.rb_hc3.disable
  robust.tx_hc1.disable
  robust.tx_hc2.disable
  robust.tx_hc3.disable
  robust.tx_clust.disable
  robust.vn_clust.disable
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y _top
  INCLUDE _sp_level

  CHECKBOX ck_beta   _lft2      @        _cwd2     .,			/*
		*/ label("Standardized beta coefficients")		/*
		*/ option("beta")					/*
		*/ clickon("program beta_on")                           /*
                */ clickoff("program beta_off")

  RADIO    rb_default _lft     +35       _iwd       .,			/*
  		*/ label("Report coefficients (default)") first		/*
  		*/ onclickon(rpt.ed_eform.disable)
  RADIO    rb_eform   @        _ss       @         .,			/*
  		*/ label("Report exponentiated coefficients and label as:")/*
  		*/ last       						/*
  		*/ onclickon(rpt.ed_eform.enable)
  EDIT     ed_eform   _indent2 _ss       _vnwd     .,			/*
		*/ label("Report exponentiated coefficients and label as")/*
		*/ default("exp(Coef.)")				/*
		*/ option("eform")					/*
		*/

  GROUPBOX gb_output _lft      _xls      _iwd      _ht4h,		/*
		*/ label("Advanced table options")			/*
		*/
  CHECKBOX ck_nohead _ilft     _ss       _cwd2     .,			/*
		*/ label("No table header")				/*
		*/ option("noheader")					/*
		*/
DEFINE y @y
  CHECKBOX ck_plus   @         _ms       @         .,			/*
		*/ label("Make table extendable")			/*
		*/ option("plus")					/*
		*/

  TEXT     tx_depn   _lft2     y         @         .,			/*
		*/ label("Substitute dependent variable name:")		/*
		*/
  EDIT     ed_depn   @         _ss       @         .,			/*
		*/ label("Substitute dependent variable name")		/*
		*/ option("depname")					/*
		*/

END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "regress "
	varlist main.vn_dv [main.vl_iv]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		option main.ck_hascon
		option main.ck_tsscon
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		option rpt.ck_beta
		option rpt.ck_nohead
		option rpt.ck_plus
		optionarg rpt.ed_depn
		if rpt.rb_eform {
			require rpt.ed_eform
		}
		optionarg rpt.ed_eform
	endoptions
END