rename.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	rename

*!  VERSION 1.1.0  31mar2005

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help rename")
RESET res1

DIALOG main, label("rename - Rename variables") tabtitle("Main")
BEGIN
  GROUPBOX gb_rename	_lft	_top	_iwd	_ht4,		///
  	label("Rename one or more variables")
  RADIO    rb_rename	_ilft	_ss	_inwd	.,		///
	first 							///
	onclickon(script rename_on)				///
	label("Rename a single variable")
  RADIO    rb_renpfix	@	_ss	@	.,		///
  	last							///
  	onclickon(script renpfix_on) 				///
  	label("Rename multiple variables identified by a prefix")

  TEXT     tx_oldvar	_lft	+45	_cwd1	.,		///
	label("Existing variable name:")
  DEFINE   holdy @y
  VARNAME  vn_oldvar	@	_ss	_vnwd	., 		///
	label("Existing variable name")

  TEXT     tx_newvar	_lft2	holdy	_cwd1	.,		///
	label("New variable name:")
  EDIT     ed_newvar	@	_ss	_vnwd	., 		///
	label("New variable name")

  TEXT     tx_oldpfx	_lft	holdy	_cwd1	.,		///
	label("Prefix of variables to rename:")
  EDIT     ed_oldpfx	@	_ss	_vnwd	., 		///
	label("Prefix of variables to rename")

  TEXT     tx_newpfx	_lft2	holdy	_cwd1	.,		///
	label("Replacement prefix: (optional)")
  EDIT     ed_newpfx	@	_ss	_vnwd	.,		///
	label("Replacement prefix")
END

SCRIPT rename_on
BEGIN
	main.tx_oldpfx.hide
	main.ed_oldpfx.hide
	main.tx_newpfx.hide
	main.ed_newpfx.hide
	main.tx_newvar.show
	main.ed_newvar.show
	main.tx_oldvar.show
	main.vn_oldvar.show
END

SCRIPT renpfix_on
BEGIN
	main.tx_oldpfx.show
	main.ed_oldpfx.show
	main.tx_newpfx.show
	main.ed_newpfx.show
	main.tx_newvar.hide
	main.ed_newvar.hide
	main.tx_oldvar.hide
	main.vn_oldvar.hide
END

PROGRAM command
BEGIN
	if main.rb_rename {
		put "rename "
		varlist main.vn_oldvar
		varlist main.ed_newvar
	}
	if main.rb_renpfix {
		put "renpfix "
		varlist main.ed_oldpfx
		varlist [main.ed_newpfx]
	}
END