rologit.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  rologit

*!  VERSION 1.1.3  21mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht320
INCLUDE header

HELP hlp1, view("help rologit")
RESET res1

DIALOG main, label("rologit - Rank-ordered logistic regression") tabtitle("Model")
BEGIN
  INCLUDE _dviv

  TEXT     tx_group  _lft      _ms       _iwd      .,			/*
		*/ label("Group variable:")				/*
		*/
  VARNAME  vn_group  _lft      _ss       _vnwd     .,			/*
		*/ label("Group variable")				/*
		*/ option("group")					/*
		*/

  GROUPBOX gb_option _lft      _ls       _iwd      _ht17h,		/*
  		*/ label("Options")
  TEXT     tx_offset _ilft     _ss       _inwd     .,			/*
		*/ label("Offset variable:")				/*
		*/
DEFINE y @y
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

  TEXT     tx_inc    _lft2     y          _cwd2     .,			/*
		*/ label("Code for unranked alternatives:")		/*
		*/
  EDIT     en_inc    @         _ss       _en7wd    ., numonly		/*
		*/ label("Code for unranked alternatives")		/*
		*/ option("incomplete")					/*
		*/ default("0")						/*
		*/
  TEXT     tx_inc2   _en7sep   @         _en7r2b   .,			/*
		*/ label("(default: 0)")				/*
		*/

  CHECKBOX ck_rev    _ilft     _ls       _cwd2     .,			/*
		*/ label("Reverse the preference order")		/*
		*/ option("reverse")					/*
		*/
  CHECKBOX ck_notest @         _ms       _ibwd     .,			/*
		*/ label("Keep RHS variables that do not vary within group") /*
		*/ option("notestrhs")					/*
		*/

  GROUPBOX gb_tied   _ilft     _ls       _ibwd     _ht4,		/*
		*/ label("Method to handle ties")			/*
		*/
  RADIO    rb_exactm _indent   _ss       _cwd3     .,			/*
		*/ label("Exact marginal likelihood")			/*
		*/ first						/*
		*/ option("ties(exactm)")				/*
		*/ onclickon(script exactm_on)
  DEFINE y @y
  RADIO    rb_efron  @         _ss       @         .,			/*
		*/ label("Efron")					/*
		*/ option("ties(efron)")				/*
		*/ onclickon(script efron_on)
  RADIO    rb_breslow _lft2    y         @         .,			/*
		*/ label("Breslow")					/*
		*/ option("ties(breslow)")				/*
		*/ onclickon(script breslow_on)
  RADIO    rb_none   @         _ss       @         .,			/*
		*/ label("None")					/*
		*/ option("ties(none)")					/*
		*/ onclickon(script none_on) last
END

SCRIPT exactm_on
BEGIN
	program enable_weights
	script se_setRobust_off
END

SCRIPT none_on
BEGIN
	program enable_weights
	script se_setClRobust_on
END

SCRIPT breslow_on
BEGIN
	program enable_weights
	script se_setClRobust_on
END

SCRIPT efron_on
BEGIN
	program disable_weights
	script se_setClRobust_on
END


INCLUDE byifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsInternalML
	script se_setJknifeBstrap_off
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y 20
  INCLUDE _sp_level
END

INCLUDE max_internal

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "rologit "
	varlist main.vn_dv
	varlist main.vl_iv
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		require main.vn_group
		optionarg main.vn_group
		optionarg main.vn_offset
		option main.ck_rev
		option main.ck_notest
		optionarg /hidedefault main.en_inc
		option radio(main rb_exactm rb_breslow rb_efron rb_none)
		optionarg /hidedefault rpt.sp_level
		put " " /program se_output
		put " " /program max_output
	endoptions
END