fracgen.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  fracgen

*! VERSION 1.0.1  19aug2003

*/

VERSION 8.0

INCLUDE _std_large
INCLUDE header
HELP hlp1, view("help fracgen")
RESET res1

DIALOG main, /*
*/label("fracgen - Generate fractional polynomial powers of a variable")/*
		*/ tabtitle("Main")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/ 
  TEXT     tx_var    _lft      _top      _iwd      .,			/*
		*/ label("Variable:")					/*
		*/
  VARNAME  vn_var    @         _ss       _vnwd     .,			/*
		*/ label("Variable")					/*
		*/

  TEXT     tx_pow    @         _ls       _iwd      .,			/*
	*/ label("Fractional powers to generate from above variable:")	/*
		*/
  EDIT     ed_pow    @         _ss       @         .,			/*
	*/ label("Fractional powers to generate from above variable")	/*
		*/

  GROUPBOX gb_opts   @         _ls       @         _ht10,		/*
		*/ label("Options")					/*
		*/
  GROUPBOX gb_adjust _indent   _ss       _cwd2     _ht7,		/*
		*/ label("Adjustments for variable")			/*
		*/
  DEFINE y @y
  RADIO    rb_no     _indent   _ss       _inwd     .,			/*
		*/ label("Do not make adjustments")			/*
		*/ clickon("gaction main.en_value.disable")		/*
		*/ first						/*
		*/ option(NONE)						/*
		*/
  RADIO    rb_mean   @         _ms       @         .,			/*
		*/ label("Adjust to the mean")				/*
		*/ clickon("gaction main.en_value.disable")		/*
		*/ option("adjust(mean)")				/*
		*/
  RADIO    rb_value  @         _ms       _rbwd     .,			/*
		*/ label("")						/*
		*/ clickon("gaction main.en_value.enable")		/*
		*/ last							/*
		*/ option(NONE)						/*
		*/
  EDIT     en_value  _rbsep    @         _en7wd    .,			/*
		*/ label("User-supplied value")				/*
		*/ numonly						/*
		*/ option("adjust")					/*
		*/
  TEXT     tx_value  _en7sep   @         _rben7r2bb .,			/*
		*/ label("User-supplied value")				/*
		*/
  CHECKBOX ck_noscal _lft2     y         _cwd2     .,			/*
		*/ label("Suppress scaling of variable")		/*
		*/ option("noscaling")					/*
		*/
  CHECKBOX ck_replac @         _ms       @         .,			/*
		*/ label("Replace variables if they exist")		/*
		*/ option("replace") nomem				/*
		*/

END

INCLUDE ifin
PROGRAM command
BEGIN
	put "fracgen "
	varlist main.vn_var
	require main.ed_pow
	put main.ed_pow
	INCLUDE _ifin_pr
	beginoptions
		option radio(main rb_no rb_mean rb_value)
		if main.rb_value {
			require main.en_value
			optionarg main.en_value
		}
		option main.ck_noscal
		option main.ck_replac
	endoptions
END