fdause.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  fdause

*! VERSION 1.0.0 18aug2003

*/

VERSION 8.0

INCLUDE _std_medium
INCLUDE _ht280
INCLUDE header

HELP hlp1, view("help fdasave")
RESET res1

DIALOG main, label("fdause - Import FDA data (SAS XPORT)")		 ///
		tabtitle("Main")

BEGIN
  TEXT     tx_file     _lft        _top      _iwd        .,		///
		label("Filename:")
  FILE     fi_file     @           _ss       @           .,		///
		error("Filename")					///
		label("Browse...")					///
		filter(SAS XPORT (*.xpt)|*.xpt|All Files (*.*)|*.*)
		
  GROUPBOX gb_options  @           _xls      @           _ht13,		///
		label("Options")
		
  CHECKBOX ck_clear    _indent     _ms       _inwd       .,		///
  		label("Replace data in memory")				///  
		option(clear) 		
  CHECKBOX ck_novallab @           _ms       @           .,		///
  		label(`"Ignore accompanying " formats.xpf " file if it exists"') ///
  		option(novallabels)  		
  CHECKBOX ck_member   @           _ms       @           .,		///
  		label(`"" *.xpt " file has multiple members"')		///
  		onclickon(script member_on)				///
  		onclickoff(script member_off)
  TEXT     tx_member   @           _ms       _vnwd       .,		///
  		label("Member to use:")
  EDIT     ed_member   @           _ss       @           .,		///
  		label("Member to use")					///
  		option(member)
  		
  BUTTON   bu_describe _lft        _xxls     130         .,		///
  		label("Describe FDA data")				///
  		onpush(program fdadescribe)
END  	

SCRIPT member_on
BEGIN
	main.tx_member.enable
	main.ed_member.enable
END

SCRIPT member_off
BEGIN
	main.tx_member.disable
	main.ed_member.disable
END

PROGRAM fdadescribe
BEGIN
	if !main.fi_file {
		stopbox stop `""Filename" must be filled in"'
	}
	put "fdadescribe " main.fi_file
	if main.ck_member & main.ed_member {
		put ", member(" main.ed_member ")"
	}
	stata
END

PROGRAM command
BEGIN
	put "fdause "
	require main.fi_file
	put main.fi_file " "
	beginoptions
		option main.ck_clear
		option main.ck_novallab
		if main.ck_member {
			require main.ed_member
			optionarg main.ed_member
		}
	endoptions
END