factor.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 06apr2005}{...}
{cmd:help factor} {right:dialogs:  {bf:{dialog factor}  {dialog factormat}}    }
{right:also see:  {help factor postestimation}}
{hline}

{title:Title}

{p 4 21 2}
{hi:[MV] factor} {hline 2} Factor analysis


{title:Syntax}

{pstd}
Factor analysis of data

{p 8 15 2}
{cmdab:fac:tor} {varlist} {ifin}  {weight}
[{cmd:,} {it:{help factor##method:method}}
{it:{help factor##options:options}} ]

{pstd}
Factor analysis of a correlation matrix

{p 8 18 2}
{cmd:factormat} {it:matname}{cmd:,} {opt n(#)}
[ {it:{help factor##method:method}}
{it:{help factor##options:options}}
{it:{help factor##matoptions:factormat_options}} ]

{synoptset 20 tabbed}{...}
{marker method}{...}
{synopthdr:method}
{synoptline}
{syntab:Model 2}
{synopt:{opt pf}}principal factor; the default{p_end}
{synopt:{opt pcf}}principal-components factor{p_end}
{synopt:{opt ip:f}}iterated principal factor{p_end}
{synopt:{opt ml}}maximum-likelihood factor{p_end}
{synoptline}

{marker options}{...}
{synopthdr}
{synoptline}
{syntab:Model 2}
{synopt:{opt fa:ctors(#)}}maximum number of factors to be retained{p_end}
{synopt:{opt mine:igen(#)}}minimum value of eigenvalues to be retained{p_end}
{synopt:{opt cit:erate(#)}}communality re-estimation iterations
	({cmd:ipf} only){p_end}

{syntab:Reporting}
{synopt:{opt bl:anks(#)}}display loadings as blanks when
	|loadings| < {it:#}{p_end}
{p2coldent:+ {opt norot:ated}}display unrotated solution, even if rotated
	results are available (replay only){p_end}
{synopt:{opt altdiv:isor}}use trace of correlation matrix as the divisor for
	reported proportions{p_end}

{syntab:Max options}
{synopt:{opt pr:otect(#)}}perform {it:#} optimizations and report the best
	solution ({cmd:ml} only){p_end}
{synopt:{opt r:andom}}use random starting values ({cmd:ml} only); seldom
	used{p_end}
{synopt:{opth "seed(generate:seed)"}}random-number seed ({cmd:ml} with
	{opt protect()} or {opt random} only){p_end}
{synopt:{help maximize:maximize_options}}control maximization process; seldom
	used ({cmd:ml} only){p_end}
{synoptline}
{p 4 6 2}
+ {opt norotated} is not available in the dialog.
{p_end}

{marker matoptions}{...}
{synopthdr:factormat_options}
{synoptline}
{syntab:Model}
{synopt:{cmdab:sh:ape(}{cmdab:f:ull}{cmd:)}}{it:matname} is a square symmetric
	matrix; the default{p_end}
{synopt:{cmdab:sh:ape(}{cmdab:l:ower}{cmd:)}}{it:matname} is a vector with the
	rowwise lower triangle (with diagonal){p_end}
{synopt:{cmdab:sh:ape(}{cmdab:u:pper}{cmd:)}}{it:matname} is a vector with the
	rowwise upper triangle (with diagonal){p_end}
{synopt:{opt nam:es(namelist)}}variable names; required if {it:matname} is
	triangular{p_end}
{p2coldent:* {opt n(#)}}number of observations; required{p_end}
{synopt:{opt sds(matname2)}}vector with standard deviations of variables{p_end}
{synopt:{opt means(matname3)}}vector with means of variables{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
* {opt n(#)} is required for {cmd:factormat}.
{p_end}

{p 4 6 2}
{cmd:bootstrap}, {cmd:by}, {cmd:jackknife}, {cmd:rolling}, and {cmd:statsby} 
are allowed with {cmd:factor}; see {help prefix}.
{p_end}
{p 4 6 2}
{cmd:aweight}s and {cmd:fweight}s are allowed with {cmd:factor}; 
see {help weight}.
{p_end}
{p 4 6 2}
See {help factor postestimation} for features available after estimation.
{p_end}


{title:Description}

{pstd}
{cmd:factor} and {cmd:factormat} perform a factor analysis of a correlation
matrix.  {cmd:factor} and {cmd:factormat} can produce principal factor,
iterated principal factor, principal-components factor, and maximum-likelihood
factor analyses.  {cmd:factor} and {cmd:factormat} display the eigenvalues of 
the correlation matrix, the factor loadings, and the uniqueness 
(= 1-communality) of the variables.

{pstd}
{cmd:factor} expects data in the form of variables, allows weights, and can be
run for subgroups (see {helpb by}).  {cmd:factormat} is for use with a
correlation or covariance matrix in the form of a square Stata matrix or a
vector containing the rowwise upper or lower triangle of the correlation or
covariance matrix.  This is explained in more detail below; see option
{opt shape()}.  If a covariance matrix is provided to {cmd:factormat}, it is
transformed into a correlation matrix for the factor analysis.  For replay of
estimation results, you may type {cmd:factor} or {cmd:factormat}; it does not
matter which.


{title:Options for factor and factormat}

{dlgtab:Model 2}

{phang}
{opt pcf}, {opt pf}, {opt ipf}, and {opt ml}
indicate the type of estimation to be performed.  The default is {opt pf}.

{phang2}
{opt pcf}
specifies that the principal-components factor method be used to analyze
the correlation matrix.  The communalities are assumed to be 1.

{phang2}
{opt pf}
specifies that the principal-factor method be used to analyze the correlation
matrix.  The factor loadings, sometimes called the factor patterns, are
computed using the squared multiple correlations as estimates of the
communality.  {opt pf} is the default.

{phang2}
{opt ipf}
specifies that the iterated principal-factor method be used to analyze the
correlation matrix.  This re-estimates the communalities iteratively.

{phang2}
{opt ml}
specifies the maximum-likelihood factor method assuming multivariate normal
observations.  This estimation method is equivalent to Rao's canonical-factor
method, and maximizes the determinant of the partial correlation matrix.
Hence this solution is also meaningful as a descriptive method for non-normal
data.  {opt ml} is not available for singular correlation matrices.  At least
3 variables must be specified with method {opt ml}.

{phang}
{opt factors(#)} and {opt mineigen(#)} 
specify the maximum number of factors to be retained.  {opt factors()}
specifies the number directly, and {opt mineigen()} specifies it indirectly,
keeping all factors with eigenvalues greater than the indicated value.  The
options can be specified individually, together, or not at all.

{phang2}
{opt factors(#)}
sets the maximum number of factors to be retained for subsequent use by the
postestimation commands.  {opt factor} always prints the full set of
eigenvalues but prints the corresponding eigenvectors only for retained
factors.  Specifying a number larger than the number of variables in the
{it:varlist} is equivalent to specifying the number of variables in the
{it:varlist}, and is the default.

{phang2}
{opt mineigen(#)}
sets the minimum value of eigenvalues to be retained.  The default for all all
methods except pcf is 0.000005 (effectively zero), meaning that factors
associated with negative eigenvalues will not be printed or retained.  The
default for {opt pcf} is 1.  Many sources recommend {cmd:mineigen(1)},
although the justification is complex and uncertain.  If {it:#} is less than
0.000005, it is reset to 0.000005.

{phang}
{opt citerate(#)}
is used only with {opt ipf} and sets the number of iterations for
re-estimating the communalities.  If {opt citerate()} is not specified,
iterations continue until the change in the communalities is small.  {opt ipf}
with {cmd:citerate(0)} produces the same results that {opt pf} does.

{dlgtab:Reporting}

{phang}
{opt blanks(#)}
specifies that factor loadings smaller than {it:#} (in absolute value) be
displayed as blanks.

{phang}
{opt norotated}
specifies that the unrotated factor solution be displayed, even if a rotated
factor solution is available.  {opt norotated} is for use only with replaying
results.

{phang}
{opt altdivisor}
specifies that reported proportions and cumulative proportions are to be
computed using the trace of the correlation matrix ({cmd:trace(e(C))}) as the
divisor.  The default is to use the sum of all eigenvalues as the divisor.

{dlgtab:Max options}

{phang}
{opt protect(#)} 
is used only with {opt ml} and requests that {it:#} optimizations with random
starting values be performed along with squared multiple-correlation
coefficient starting values and that the best of the solutions be reported.
The output also indicates whether all starting values converged to the same
solution.  When specified with a large number, such as {cmd:protect(50)}, this
provides reasonable assurance that the solution found is global and is not
just a local maximum.  If {opt trace} is also specified (see {help maximize}),
the parameters and likelihoods of each maximization will be printed.

{phang}
{opt random} 
is used only with {opt ml} and requests that random starting values be used.  
This option is rarely used and should only be used after {opt protect()} has 
shown the presence of multiple maxima.

{phang}
{opth "seed(generate:seed)"}
is used only with {opt ml} when the {opt random} or {opt protect()} options
are also specified.  {opt seed()} specifies the random-number seed; see 
{helpb set seed}.  If {opt seed()} is not specified, the random-number 
generator starts in whatever state it was last in.

{phang}
{it:maximize_options}:
{opt iter:ate(#)}, [{cmdab:no:}]{cmdab:lo:g}, {opt tr:ace},
{opt tol:erance(#)}, {opt ltol:erance(#)}, see {help maximize}.  These options
are seldom used.


{title:Options unique to factormat}

{dlgtab:Model}

{phang}
{opt shape(shape)}
specifies the shape (storage method) for the covariance or correlation matrix
{it:matname}.  The following shapes are supported:

{phang2}
{cmd:full}
specifies that the correlation or covariance structure of k variables is
stored as a symmetric k by k matrix.  This is the default.

{phang2}
{cmd:lower}
specifies that the correlation or covariance structure of k variables is
stored as a vector with k(k+1)/2 elements in rowwise lower-triangular order,

{p 16 20 2}
C(11) C(21) C(22) C(31) C(32) C(33) ... C(k1) C(k2) ... C(kk)

{phang2}
{cmd:upper}
specifies that the correlation or covariance structure of k variables is
stored as a vector with k(k+1)/2 elements in rowwise upper-triangular order,

{p 16 20 2}
C(11) C(12) C(13) ... C(1k) C(22) C(23) ... C(2k){...}
... {bind:C(k-1 k-1)} {bind:C(k-1 k)} C(kk)

{phang}
{opt names(namelist)}
specifies a list of k different names.  These names are used to document
output and label estimation results and as variable names by {cmd:predict}.
{opt names()} is required if the correlation or covariance matrix is in
vectorized storage mode (i.e, {cmd:shape(lower)} or {cmd:shape(upper)} are
specified).  By default, {cmd:factormat} verifies that the row and column
names of {it:matname} and the column or row names of {it:matname2} and
{it:matname3} from the {opt sds()} and {opt means()} options are in agreement.
Using the {opt names()} option turns off this check.

{phang}
{opt n(#)},
a required option, specifies the number of observations on which {it:matname}
is based.

{phang}
{opt sds(matname2)}
specifies a k by 1 or 1 by k matrix with the standard deviations of the
variables.  The row or column names should match the variable names
unless the {opt names()} option is specified.
{opt sds()} may only be specified if {it:matname} is a correlation matrix.
Specify {opt sds()} if you have variables in your dataset and want to use
{cmd:predict} after {cmd:factormat}.  {opt sds()} does not affect the
computations of {cmd:factormat}, it instead provides information so that
{cmd:predict} does not assume the standard deviations are one.

{phang}
{opt means(matname3)}
specifies a k by 1 or 1 by k matrix with the means of the variables.  The row
or column names should match the variable names unless the {opt names()}
option is specified.  Specify {opt means()} if you
have variables in your dataset and want to use {cmd:predict} after
{cmd:factormat}.  {opt means()} does not affect the computations of
{cmd:factormat}, it instead provides information so that {cmd:predict} does
not assume the means are zero.


{title:Examples of factor}

{p2colset 5 43 44 0}{...}
{p2col:{cmd:. factor cost1-cost5}}(principal factors){p_end}
{p2col:{cmd:. factor cost1-cost5, factors(2)}}(principal factors, keep 2
	factors){p_end}
{p2col:{cmd:. factor cost1-cost5, factors(2) pcf}}(principal-component
	factors, keep 2){p_end}
{p2col:{cmd:. factor cost1-cost5, factors(2) ipf}}(iterated principal factors,
	keep 2){p_end}
{p2col:{cmd:. factor cost1-cost5, factors(2) ml}}(max.-likelihood factors,
	keep 2){p_end}
{p2colreset}{...}


{title:Examples of factormat}

{pstd}
First enter the correlation matrix and set the row and column names.

	{cmd:. matrix C = ( 1.000, 0.943,  0.771  \ ///}
	{cmd:               0.943, 1.000,  0.605  \ ///}
	{cmd:               0.771, 0.605,  1.000  ) }

{pstd}
Note that elements within a row are separated by a comma, rows are separated
by a backslash {cmd:\}, and {cmd:///} continues lines.  Next invoke
{cmd:factormat}, with the number of observations in {cmd:n()},

{phang2}
{cmd:. factormat C, n(979) names(visual hearing taste) fac(1)}

{pstd}
Equivalently, one may just enter the upper triangle of the correlation matrix
{cmd:C} as a vector, i.e., a matrix with one row or column.

	{cmd:. matrix C = ( 1.000, 0.943, 0.771, ///}
	{cmd:                      1.000, 0.605, ///}
	{cmd:                             1.000 )}

{pstd}
Note that all elements are separated by a comma; indentation and the use of
three lines are just done for checking input.  One might just as well have
typed

{phang2}
{cmd:. matrix C = ( 1.000, 0.943, 0.771, 1.000, 0.605, 1.000)}

{pstd}
Next, we use {cmd:factormat}, specifying the storage {cmd:shape(upper)} and
the variable names with the option {cmd:names()}.

{phang2}
{cmd:. factormat C, n(979) shape(upper) fac(1) names(visual hearing taste)}


{title:Also see}

{psee}
Manual:  {bf:[MV] factor}

{psee}
Online:  {help factor postestimation};{break}  
{helpb alpha}, 
{helpb canon}, 
{helpb pca},
{helpb tetrachoric}
{p_end}