notes_list.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	notes [list]

*! VERSION 1.1.0  06jan2004

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help notes")
RESET res1

DEFINE fromwd 50
DEFINE fromsep +55
DEFINE towd 35
DEFINE tosep +40

DIALOG main, label("notes - List notes") tabtitle("Main")
BEGIN
  CHECKBOX ck_dta    _lft      _top      _iwd      .,		/*
		*/ label("List notes for dataset")

  CHECKBOX ck_var    @         _ms       @         ., 		/*
		*/ clickon("gaction main.vl_var.enable")	/*
		*/ clickoff("gaction main.vl_var.disable")	/*
	*/ label("List notes for variables:  (leave empty for all variables)")

  VARLIST  vl_var    _indent2  _ss       _ibwd     .,	/*
		*/ label("Variables")

  CHECKBOX ck_ran    _lft      _ls       _iwd      _ht4,	/*
		*/ label("Restrict to range of notes")		/*
		*/ clickon("script ran_on")			/*
		*/ clickoff("script ran_off")			/*
		*/ groupbox

  TEXT     tx_from   _ilft     _ls       fromwd    .,		/*
		*/ right					/*
		*/ label("from:")

  SPINNER  sp_from   fromsep   @         _spwd     .,		/*
		*/ min(1)					/*
		*/ max(9999)					/*
		*/ default(1)

  CHECKBOX ck_to     _lft2     @         towd      .,		/*
		*/ clickon("gaction main.sp_to.enable")		/*
		*/ clickoff("gaction main.sp_to.disable")	/*
		*/ label("to:")

  SPINNER  sp_to     tosep     @         _spwd     .,		/*
		*/ min(1)					/*
		*/ max(9999)					/*
		*/ default(1)
END


SCRIPT ran_on
BEGIN
main.sp_from.enable
main.ck_to.enable
END

SCRIPT ran_off
BEGIN
main.sp_from.disable
main.ck_to.disable
END


PROGRAM command
BEGIN
	put "notes list "
	if main.ck_dta {
		put "_dta "
	}
	if main.ck_var {
		if (main.vl_var) {
			varlist [main.vl_var]
		}
		if !(main.vl_var) {
			put "* "
		}
	}
	if main.ck_ran {
		require main.sp_from
		put "in " main.sp_from
		if main.ck_to {
			require main.sp_to
			put "/" main.sp_to
		}
	}
END