nbreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  nbreg

*! VERSION 1.1.1  21feb2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header

HELP hlp1, view("help nbreg")
RESET res1

DIALOG main, label("nbreg - Negative binomial regression")		/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv
  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/
  GROUPBOX gb_disper _lft      _ls       _iwd      _ht2,		/*
		*/ label("Parameterization of dispersion")		/*
		*/
  RADIO    rb_mean   _ilft     _ss       _cwd2     .,			/*
		*/ label("A function of the expected mean")		/*
		*/ first						/*
		*/ option("dispersion(mean)")				/*
		*/
  RADIO    rb_cons   _lft2     @         @         .,			/*
		*/ label("A constant")					/*
		*/ last							/*
		*/ option("dispersion(constant)")			/*
		*/

  GROUPBOX gb_opt    _lft      _xls      _iwd      _ht10,		/*
		*/ label("Options")					/*
		*/

  RADIO    rb_expose _ilft     _ss       _cwd3_2   .,			/*
		*/ label("Exposure variable:")				/*
		*/ first						/*
		*/ clickon("script expose")				/*
		*/
  RADIO    rb_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable:")				/*
		*/ last							/*
		*/ clickon("script offset")				/*
		*/

  VARNAME  vn_expose _ilft     _ss       @         .,			/*
		*/ label("Exposure variable")				/*
		*/ option("exposure")					/*
		*/
  VARNAME  vn_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints

END

SCRIPT expose
BEGIN
  main.vn_expose.enable
  main.vn_offset.disable
END

SCRIPT offset
BEGIN
  main.vn_expose.disable
  main.vn_offset.enable
END

INCLUDE byifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y _top
  INCLUDE _sp_level

  CHECKBOX ck_nolrtest _lft         _ls       _cwd1      .,		/*
		*/ label("Suppress likelihood-ratio test")		/*
		*/ option("nolrtest")					/*
		*/
  RADIO    rb_default  @            _ls       _cwd1      .,		/*
  		*/ label("Report coefficients (default)") first
  RADIO    rb_irr      @           _ss       @         .,		/*
  		*/ label("Report incidence-rate ratios")		/*
  		*/ option(irr) last

END

PROGRAM rpt_output
BEGIN
	optionarg /hidedefault rpt.sp_level
	option rpt.ck_nolrtest
	option rpt.rb_irr
END

INCLUDE max_ml

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "nbreg "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		option radio(main rb_mean rb_cons)
		optionarg main.vn_expose
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		put " " /program se_output
		put " " /program rpt_output
		put " " /program max_output
	endoptions
END