hfs.nc

无线通信的主要编程软件,是无线通信工作人员的必备工具,关天相关教程我会在后续传上.

// $Id: HFS.nc,v 1.3 2003/10/07 21:44:50 idgay Exp $

/*									tab:4
 * "Copyright (c) 2000-2003 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2003 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */
/* High-frequency-sampling application. This is intended to show how to perform
   high-frequency-sampling, but is not (yet?) a standard OS service.

   During sampling, the radio is stopped (see ExternalShutdown interface
   on Sample)

   Leds usage:
   green: application ready for requests
   yellow: currently sampling
   red: error occured

   Main components:
   - HFSM: initiate sampling in response to outside message
   - HFSRead: report samples over UART in response to outside message
   - Sample: sample <n> samples at an <m> microsecond interval, logging
       the results over the LogData/fastAppend interface
   - MicroTimerM: microsecond granularity timing (doesn't interact nicely
     with LogicalTime. Makefile forces use of SimpleTime instead, this
     requires the local copy of TimerC.nc)
   - BufferedLog (system component): double-buffered fast logging
     (interpose in front of ByteEEPROMC)
   - ByteEEPROMC: portable eeprom component
*/
includes HFS;
configuration HFS { }
implementation {
  components Main, HFSM, HFSRead;
  components Sample, MicroTimerM;
  components BufferedLog, ByteEEPROM;
  components Accel as Sensor, GenericComm as Comm, LedsC;

  Main.StdControl -> HFSM;
  Main.StdControl -> ByteEEPROM;
  Main.StdControl -> Comm;
  Main.StdControl -> Sensor;

  HFSM.Sampling -> Sample;
  HFSM.ReceiveMsg -> Comm.ReceiveMsg[AM_SAMPLEREQUESTMSG];
  HFSM.SendMsg -> Comm.SendMsg[AM_SAMPLEDONEMSG];
  HFSM.AllocationReq -> ByteEEPROM.AllocationReq[HFS_EEPROM_ID];
  HFSM.Leds -> LedsC;

  Sample.LogData -> BufferedLog;
  Sample.fastAppend -> BufferedLog;
  Sample.ExternalShutdown -> Comm;
  Sample.MicroTimer -> MicroTimerM;
  Sample.ADC -> Sensor.AccelX;

  BufferedLog.Logger -> ByteEEPROM.LogData[HFS_EEPROM_ID];

  HFSRead.ReceiveMsg -> Comm.ReceiveMsg[AM_READREQUESTMSG];
  HFSRead.SendMsg -> Comm.SendMsg[AM_READDATAMSG];
  HFSRead.ReadData -> ByteEEPROM.ReadData[HFS_EEPROM_ID];
}