create_sortingcls.asp

多用户管理分权限发布、管理软件信息； 自由选择系统默认为静态HTML或动态ASP； 无限制添加下载服务器

<%
Class Create_Sorting_Cls
	Private ErrMsg
	Private SucMsg
	Private Founderr
	Private NC_Admin, NewCloud_Ads
	Private softid, sortid, rootid, depth, SortName, ParentID, strParent, Child
	Private CurrentPage, maxperpage, totalnumber, bookmark, Pcount
	Private order_name, strOrder, ShowPageHtml, HtmlTemplate
	Private action, d
	Private Sub Class_Initialize()
		Founderr = False
		Response.Buffer = True
		Server.ScriptTimeout = 99999
		d = Timer()
		Newasp.LoadTemplates ("Sorting")
		Set NewCloud_Ads = New Adcolumn_Cls
		maxperpage = CInt(Newasp.TempSet(0)) '###每页显示数
	End Sub

	Private Sub Class_Terminate()
		If IsObject(Conn) Then
			Conn.Close
			Set Conn = Nothing
		End If
		Set NewCloud_Ads = Nothing
		Set Newasp = Nothing
	End Sub

	Public Sub Init_CreateHtml()
		Set NC_Admin = New Check
		NC_Admin.AdminChk = "31"
		NC_Admin.Check
		Newasp.admin_header
		If CInt(Newasp.Setting(5)) = 1 Then
			NC_Admin.Error_Msg ("对不起!你选择动态ASP程序,不能生成HTML文件,请在基本设置修改成静态HTML方能生成THML文件。")
			Exit Sub
		End If
		action = Trim(Request("action"))
		Select Case action
			Case "Create"
				Call CreateSortingHtml
			Case Else
				Call CreateMain
		End Select
		Newasp.admin_footer
	End Sub

	Public Sub SortingHtml()
		Dim SQL, Rs
		If CInt(Newasp.Setting(5)) = 0 Then Response.redirect (Newasp.SetupDir & Newasp.Setting(6))
		Set Rs = Server.CreateObject("adodb.recordset")
		If Not IsNumeric(Request("sortid")) And Request("sortid") <> "" Then
			Response.Write"错误的系统参数!ID必须是数字"
			Exit Sub
			Response.End
		Else
			sortid = CLng(Request("sortid"))
		End If
		If Not IsEmpty(Request("page")) Then
			CurrentPage = CInt(Request("page"))
		Else
			CurrentPage = 1
		End If
		If sortid <> "" Then
			SQL = "select sortid,sortname,rootid,depth,ParentID,strParent,Child from [NC_softsort] where sortid = " & CLng(Request("sortid"))
			Rs.Open SQL, Conn, 1, 1
			If Rs.bof And Rs.EOF Then
				Response.Write "Sorry！没有找到任何软件信息。或者您选择了错误的系统参数!"
				Response.End
			Else
				SortName = Rs("sortname")
				sortid = Rs("sortid")
				rootid = Rs("rootid")
				depth = Rs("depth")
				ParentID = Rs("ParentID")
				strParent = Rs("strParent")
				Child = Rs("Child")
			End If
			Rs.Close
		Else
			sortid = ""
			ParentID = ""
			strParent = 0
			Child = ""
			depth = ""
			rootid = ""
			SortName = "软件列表"
		End If
		order_name = Request("order")
		strOrder = Request("order")
		Select Case order_name
			Case "Name"
				order_name = "SoftName"
			Case "Indate"
				order_name = "SoftTime"
			Case "Size"
				order_name = "SoftSize"
			Case "Hits"
				order_name = "Hits"
			Case Else
				order_name = "SoftTime"
				strOrder = "Indate"
		End Select
		Dim temphtml, NowStats, HtmlTitle
		Dim TempTopStr, TempFootStr, Style_CSS
		If Len(sortid) = 0 Then
			NowStats = SortName
		Else
			NowStats = NowStation(sortid, SortName, ParentID, strParent)
		End If
		HtmlTitle = SortName
		If Len(Newasp.temphtml(0)) < 50 Then
			TempTopStr = Newasp.mainhtml(0) & Newasp.mainhtml(1) & Newasp.mainhtml(2) & Newasp.mainhtml(3)
		Else
			TempTopStr = Newasp.temphtml(0)
		End If
		If Len(Newasp.temphtml(4)) = 0 Then
			TempFootStr = Newasp.mainhtml(4)
		Else
			TempFootStr = Newasp.temphtml(4)
		End If
		Style_CSS = Replace(Replace(Newasp.Style_CSS, "{$SetupDir}", Newasp.SetupDir), "{$PicUrl}", Newasp.TempDir)
		temphtml = TempTopStr & Newasp.temphtml(1) & Newasp.temphtml(2) & Newasp.temphtml(3) & TempFootStr
		temphtml = Replace(temphtml, "{$NavMenu}", Newasp.SortingMenu)
		temphtml = Replace(temphtml, "{$Width}", Newasp.mainset(0))
		temphtml = Replace(temphtml, "{$Style_CSS}", Style_CSS)
		If CInt(Newasp.Setting(5)) = 0 Then
			temphtml = Replace(temphtml, "{$TopMeun}", Newasp.mainset(9))
		Else
			temphtml = Replace(temphtml, "{$TopMeun}", Newasp.mainset(10))
		End If
		temphtml = Replace(temphtml, "{$FootMeun}", Newasp.mainset(11))
		temphtml = Replace(temphtml, "{$NowStats}", NowStats)
		temphtml = Replace(temphtml, "{$Title}", HtmlTitle)
		temphtml = Replace(temphtml, "{$SortID}", sortid)
		temphtml = Replace(temphtml, "{$Sorting}", SoftSorting(sortid, ParentID, Child))
		temphtml = Replace(temphtml, "{$SortingList}", SoftSortingList(sortid, rootid, depth, SortName, order_name, maxperpage, CurrentPage, strOrder))

		temphtml = Replace(temphtml, "{$Adcolumn(0)}", NewCloud_Ads.RunScriptAds(2))
		temphtml = Replace(temphtml, "{$Adcolumn(1)}", NewCloud_Ads.BannerAds(2))
		temphtml = Replace(temphtml, "{$Adcolumn(2)}", NewCloud_Ads.AdsColumn(2, 2))
		temphtml = Replace(temphtml, "{$Adcolumn(3)}", NewCloud_Ads.AdsColumn(2, 3))
		temphtml = Replace(temphtml, "{$Adcolumn(6)}", NewCloud_Ads.AdsColumn(2, 7))
		temphtml = Replace(temphtml, "{$Adcolumn(4)}", NewCloud_Ads.ScriptFloatAds(2))
		temphtml = Replace(temphtml, "{$Adcolumn(5)}", NewCloud_Ads.ScriptFixedAds(2))
		Response.Write temphtml
	End Sub
	'*************************************************************
	'函数作用：软件列表
	'*************************************************************
	Private Function SoftSortingList(sortid, rootid, depth, SortName, order_name, maxperpage, CurrentPage, strOrder)
		Dim Rs, SQL, HtmlString, i, TopImg, isCommend, SoftImg
		Dim SoftName, SoftReadme, SoftTime, SoftSize
		Set Rs = Server.CreateObject("adodb.recordset")
		If Len(sortid) = 0 Then
			SQL = "select * from NC_softinfo where isLock=0  order by isTop Desc, SoftTime Desc, softid Desc"
		Else
			If depth = 0 Then
				SQL = "select * from NC_softinfo where isLock=0 and rootid = " & rootid & " order by isTop Desc, " & order_name & " Desc, softid Desc"
			Else
				Dim Rss, AllSortID, ParentStr
				Set Rss = Newasp.Execute("select * from NC_SoftSort where strParent like '%"& sortid &"%'")
				If Rss.EOF And Rss.bof Then
					AllSortID = sortid
				Else
					Do While Not Rss.EOF
						ParentStr = Split(Rss("strParent"), ",")
						For i = 0 To UBound(ParentStr)
							If CLng(ParentStr(i)) = sortid Then
								AllSortID = AllSortID & Rss("sortid") &","
								Exit For
							End If
						Next
						Rss.movenext
					Loop
					AllSortID = AllSortID & sortid
				End If
				Rss.Close
				Set Rss = Nothing
				SQL = "select * from NC_softinfo where isLock=0 and sortid in (" & AllSortID & ") order by isTop Desc, " & order_name & " Desc, softid Desc"
			End If
		End If
		Rs.Open SQL, Conn, 1, 1
		If CInt(Newasp.Setting(5)) = 0 Then
			HtmlString = Newasp.TempSet(8)
		Else
			HtmlString = Newasp.TempSet(9)
		End If
		HtmlString = Replace(HtmlString, "{$SortID}", sortid)
		If Rs.bof And Rs.EOF Then
			HtmlString = HtmlString & "<p align=center>还没有找到任何软件！</p>"
		Else
			totalnumber = Rs.recordcount
			If (totalnumber Mod maxperpage) = 0 Then
				Pcount = totalnumber \ maxperpage
			Else
				Pcount = totalnumber \ maxperpage + 1
			End If
			Rs.MoveFiRst
			If CurrentPage > Pcount Then CurrentPage = Pcount
			If CurrentPage < 1 Then CurrentPage = 1
			If CurrentPage = Empty Then CurrentPage = 1
			Rs.Move (CurrentPage - 1) * maxperpage
			bookmark = Rs.bookmark
			i = 0
			Do While Not Rs.EOF And i < CInt(maxperpage)
				HtmlString = HtmlString & Newasp.TempSet(10)
				If CInt(Rs("isTop")) = 1 Then
					TopImg = "<img src='" & Newasp.SetupDir & "images/isTop.gif' align='absmiddle'>"
				Else
					TopImg = "<img src='" & Newasp.SetupDir & "images/arrow.gif' align='absmiddle'>"
				End If
				If CInt(Rs("isCommend")) = 0 Then
					isCommend = ""
				Else
					isCommend = "<font color=red>推荐</font>"
				End If
				If CInt(Newasp.Setting(5)) = 0 Then
					SoftName = "" & TopImg & " <A HREF='" & Newasp.SetupDir & "Software/Catalog" & Rs("sortid") & "/" & Rs("softid") & ".html'>" & Trim(Rs("softname")) & " " & Trim(Rs("softver")) & "</a> " & isCommend & ""
				Else
					SoftName = "" & TopImg & " <A HREF='" & Newasp.SetupDir & "Software.asp?id=" & Rs("softid") & "'>" & Trim(Rs("softname")) & " " & Trim(Rs("softver")) & "</a> " & isCommend & ""
				End If
				If Rs("SoftTime") >= Date Then
					SoftTime = "<FONT color=red>" & FormatDateTime(Rs("SoftTime"), 2) & "</FONT >"
				Else
					SoftTime = FormatDateTime(Rs("SoftTime"), 2)
				End If
				If Rs("SoftSize") > 1024 Then
					SoftSize = Round(Rs("SoftSize") / 1024, 2) & " MB"
				Else
					SoftSize = Rs("SoftSize") & " KB"
				End If
				If Not IsNull(Trim(Rs("softimg"))) And Trim(Rs("softimg")) <> "" Then
					If CInt(Newasp.Setting(5)) = 0 Then
						SoftImg = "<A HREF='" & Newasp.SetupDir & "Software/Catalog" & Rs("sortid") & "/" & Rs("softid") & ".html'><img src='" & Rs("softimg") & "' width='" & Newasp.mainset(41) & "' height='" & Newasp.mainset(42) & "' border='0'></a> "
					Else
						SoftImg = "<A HREF='" & Newasp.SetupDir & "Software.asp?id=" & Rs("softid") & "'><img src='" & Rs("softimg") & "' width='" & Newasp.mainset(41) & "' height='" & Newasp.mainset(42) & "' border='0'></a> "
					End If
				Else
					SoftImg = "<img src=""" & Newasp.SetupDir & "images/NoPic.jpg"" width='" & Newasp.mainset(41) & "' height='" & Newasp.mainset(42) & "' border=0>"
				End If
				SoftReadme = Newasp.CutString(Rs("content"), CInt(Newasp.TempSet(7)))
				HtmlString = Replace(HtmlString, "{$SoftName}", SoftName)
				HtmlString = Replace(HtmlString, "{$SoftReadme}", SoftReadme)
				HtmlString = Replace(HtmlString, "{$SoftTime}", SoftTime)
				HtmlString = Replace(HtmlString, "{$SoftSize}", SoftSize)
				HtmlString = Replace(HtmlString, "{$Hits}", Rs("Hits"))
				HtmlString = Replace(HtmlString, "{$RunSystem}", Rs("RunSystem"))
				'HtmlString = Replace(HtmlString, "{$Impower}", Rs("impower"))
				HtmlString = Replace(HtmlString, "{$Grades}", Rs("Grades"))
				HtmlString = Replace(HtmlString, "{$SoftImg}", SoftImg)
				Rs.movenext
				i = i + 1
			Loop
		End If
		Rs.Close
		HtmlString = HtmlString & Newasp.TempSet(11)
		HtmlString = Replace(HtmlString, "{$ShowPage}", AspShowPage(SortName, maxperpage, CurrentPage, totalnumber))
		SoftSortingList = HtmlString
	End Function

	Private Sub CreateMain()
		Dim SQL, Rss, SoftTotal
		SQL = "select count(sortid) from [NC_SoftSort]"
		Rss = Newasp.Execute(SQL)
		SoftTotal = Rss(0)
		Response.Write "<table width=""98%"" border=""0"" align=""center"" cellpadding=""5"" cellspacing=""1"" class=""tableBorder"">" & vbCrLf
		Response.Write "    <tr>" & vbCrLf
		Response.Write "      <th colspan=""2"">批量生成软件分类列表的HTML页</th></tr>" & vbCrLf
		Response.Write "    <tr>" & vbCrLf
		Response.Write "      <td class=forumrow height=""32"" style=""LINE-HEIGHT: 150%; font-size: 10pt;"" colspan=""2"">" & vbCrLf
		If Request("type") = "ok" Then
			Response.Write "<b>操作完成:共生成软件列表<font color=""#FF0000"">" & Request("num") & "</font>个,共有分类<font color=""#FF0000"">" & SoftTotal & "</font>个,总费时<font color=""#FF0000"">" & FormatNumber((Timer() - Request("D")), 2) & "</font>秒,完成时间" & Now() & "</b>" & vbCrLf
		End If
		Response.Write "</td>" & vbCrLf
		Response.Write "    <tr>" & vbCrLf
		Response.Write "      <td class=forumrow height=""32"" style=""LINE-HEIGHT: 150%; font-size: 9pt;"" colspan=""2"">" & vbCrLf
		Response.Write "<font color=""#FF0000"">说明：</font><BR>" & vbCrLf