email.asp

多用户管理分权限发布、管理软件信息； 自由选择系统默认为静态HTML或动态ASP； 无限制添加下载服务器

<%
Dim SendMail

Sub Jmail(email,topic,mailbody)
	on error resume next
	dim JMail
	Set JMail=Server.CreateObject("JMail.Message")
	'JMail.silent=true
	JMail.Logging=True
	JMail.Charset="gb2312"
	JMail.MailServerUserName = Newasp.setting(11) '您的邮件服务器登录名
	JMail.MailServerPassword = Newasp.setting(12) '登录密码
	JMail.ContentType = "text/html"
	JMail.Priority = 1
	JMail.From = Newasp.setting(8)  '邮件地址
	JMail.FromName = Newasp.setting(0)  '网站名称
	JMail.AddRecipient email
	JMail.Subject = topic
	JMail.Body = mailbody
	JMail.Send (Newasp.setting(9))   '发邮件服务器地址
	Set JMail=nothing
	SendMail="OK"
	If err then SendMail="False"
end sub
	
sub Cdonts(email,topic,mailbody)
	on error resume next
	dim  objCDOMail
	Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
	objCDOMail.From = Newasp.setting(8)  '邮件地址
	objCDOMail.To = email
	objCDOMail.Subject = topic
	objCDOMail.BodyFormat = 0 
	objCDOMail.MailFormat = 0 
	objCDOMail.Body = mailbody
	objCDOMail.Send
	Set objCDOMail = Nothing
	SendMail="OK"
	If err then SendMail="False"
end sub

sub aspemail(email,topic,mailbody)
	on error resume next
	dim Mailer
	Set Mailer=Server.CreateObject("Persits.MailSender") 
	Mailer.Charset = "gb2312"
	Mailer.IsHTML = True
	Mailer.username = Newasp.setting(11)	'服务器上有效的用户名
	Mailer.password = Newasp.setting(12)	'服务器上有效的密码
	Mailer.Priority = 1
	Mailer.Host = Newasp.setting(9)
	Mailer.Port = 25 ' 该项可选.端口25是默认值
	Mailer.From = Newasp.setting(8)   '邮件地址
	Mailer.FromName = Newasp.setting(0) ' 该项可选
	Mailer.AddAddress email,email
	Mailer.Subject = topic
	Mailer.Body = mailbody
	Mailer.Send
	SendMail="OK"
	If err then SendMail="False"
end sub
%>