cesysgen.bat

wince底层驱动开发代码 ARM作为一种嵌入式系统处理器

if "%SYSGEN_DSHOW_MSRLE%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MPEGA%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MPEGV%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MPEGSPLITTER%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_WMP%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MSADPCM%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_IMAADPCM%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MSGSM610%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_MSG711%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_ACMWRAP%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_VIDREND%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_WMT_ASXV1%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_ASXV2%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_ASXV3%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_NSC%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_HTTP%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_MMS%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_LOCAL%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_MULTI%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_DRMOCX%"=="1" set SYSGEN_DSHOW_WMT_DRMV7=1
if "%SYSGEN_DSHOW_WMT_DRMV7%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT_PDDRM%"=="1" set SYSGEN_DSHOW_WMT=1
if "%SYSGEN_DSHOW_WMT%"=="1" set SYSGEN_DSHOW=1
if "%__SYSGEN_DSHOW_VRCTL%"=="1" set SYSGEN_DSHOW=1
if "%__SYSGEN_DSHOW_MPEG2SPLITTER%"=="1" set SYSGEN_DSHOW=1
if "%SYSGEN_DSHOW_OVMIXER%"=="1" set SYSGEN_DSHOW=1

if not "%SYSGEN_DSHOW%"=="1" goto No_DShow
    REM // Core quartz components needed in most cases
    set QUARTZ2_COMPONENTS=asyncrdr qtzbase %QUARTZ_EXTRA_COMPONENTS%
    set QUARTZ0_COMPONENTS=amutil fgctl filgraph
    set QUARTZ_COMPONENTS=quartz0 quartz1 quartz2

    REM // DShow extra error messages
    if "%SYSGEN_DSHOW_ERRORS%"=="1" set QUARTZ0_COMPONENTS=%QUARTZ0_COMPONENTS% errstr

    REM // DShow WaveOut audio renderer
    if "%SYSGEN_DSHOW_WAVEOUT%"=="1" set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% waveout

    REM // DShow DSound audio renderer
    if not "%SYSGEN_DSHOW_DSNDOUT%"=="1" goto No_DShow_DSoundRenderer
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% dsndout
        set SYSGEN_DSOUND=1
    :No_DShow_DSoundRenderer

    if "%SYSGEN_DSHOW_WAVEOUT%"=="1" goto DShow_Has_AudioRenderer
    if "%SYSGEN_DSHOW_DSNDOUT%"=="1" goto DShow_Has_AudioRenderer
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% waveout
    :DShow_Has_AudioRenderer

    REM WAV support
    REM =========================================================
    if not "%SYSGEN_DSHOW_WAV%"=="1" goto No_DShow_WAV
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% wavemsr
        set SYSGEN_URLMON=1
    :No_DShow_WAV

    REM MIDI support
    REM =========================================================
    if not "%SYSGEN_DSHOW_MIDI%"=="1" goto No_DShow_MIDI
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% mididm
        set __SYSGEN_DMUSIC=1
        set SYSGEN_URLMON=1
        set SYSGEN_DSHOW_WMA=1
    :No_DShow_MIDI

    REM AVI support
    REM =========================================================
    if not "%SYSGEN_DSHOW_AVI%"=="1" goto No_DShow_AVI
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% avimsr avidec
        set SYSGEN_DSHOW_MSRLE=1
        set SYSGEN_URLMON=1
    :No_DShow_AVI

    REM MPEG Audio support
    REM =========================================================
    if not "%SYSGEN_DSHOW_MPEGA%"=="1" goto No_DShow_MPEGA
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% mpgadec
        set SYSGEN_DSHOW_MPEGSPLITTER=1
    :No_DShow_MPEGA

    REM MPEG Video support
    REM =========================================================
    if not "%SYSGEN_DSHOW_MPEGV%"=="1" goto No_DShow_MPEGV
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% mpgvdec
        set SYSGEN_DSHOW_MPEGSPLITTER=1
        set SYSGEN_DSHOW_ICM=1
    :No_DShow_MPEGV

    REM MP3 Audio decompressor
    REM =========================================================
    if not "%SYSGEN_DSHOW_MP3%"=="1" goto No_DShow_MP3
        REM next two lines get you a MP3 DMO
        set DIRECTX_MODULES=%DIRECTX_MODULES% mp3dmod
        set SYSGEN_DSHOW_DMO=1
        REM next two lines get you a MP3 ACM
        REM set DIRECTX_MODULES=%DIRECTX_MODULES% l3codec
        REM set SYSGEN_DSHOW_ACMWRAP=1
        set SYSGEN_DSHOW_MPEGSPLITTER=1
    :No_DShow_MP3

    REM MPEG splitter/parser
    REM =========================================================
    if not "%SYSGEN_DSHOW_MPEGSPLITTER%"=="1" goto No_DShow_MPG
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% mpgsplit
        set SYSGEN_URLMON=1
    :No_DShow_MPG

    REM MPEG-2 splitter/parser
    REM =========================================================
    if not "%__SYSGEN_DSHOW_MPEG2SPLITTER%"=="1" goto No_DShow_MPG2
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% mpg2splt
        set SYSGEN_URLMON=1
    :No_DShow_MPG2

    REM Windows Media Video and MPEG-4 decompressor
    REM =========================================================
    if not "%SYSGEN_DSHOW_WMV%"=="1" goto No_WMV
        REM next two lines get you a WMV DMO
        set DIRECTX_MODULES=%DIRECTX_MODULES% wmvdmod
        set SYSGEN_DSHOW_DMO=1
        REM next line get you a WMV DShow filter
        REM set DIRECTX_MODULES=%DIRECTX_MODULES% mpg4ds32
        set __SYSGEN_DSHOW_WMT_ICM=1
        set SYSGEN_DSHOW_WMA=1
        set SYSGEN_DSHOW_VIDREND=1
    :No_WMV

    REM Windows Media Audio decompressor
    REM =========================================================
    if not "%SYSGEN_DSHOW_WMA%"=="1" goto No_WMA
        REM next two lines get you a WMA DMO
        set DIRECTX_MODULES=%DIRECTX_MODULES% wmadmod
        set SYSGEN_DSHOW_DMO=1
        set __SYSGEN_DSHOW_WMT_ACM=1
        if not "%SYSGEN_DSHOW_MIDI%"=="1" goto No_WMA
        REM next two lines get you a WMA ACM
        set __SYSGEN_ACM_WMA=1
        set SYSGEN_DSHOW_ACMWRAP=1
    :No_WMA

    REM Windows Media Audio Voice decompressor
    REM =========================================================
    if not "%SYSGEN_DSHOW_WMA_VOICE%"=="1" goto No_WMAVOICE
        REM next two lines get you a WMA Voice
        set DIRECTX_MODULES=%DIRECTX_MODULES% wmsdmod
        set SYSGEN_DSHOW_DMO=1
        set __SYSGEN_DSHOW_WMT_ACM=1
    :No_WMAVOICE

    REM Overlay Mixer (Broadcast Services or DVD Playback) and Video Renderer Control
    REM ===================================================================================
    if "%SYSGEN_DSHOW_OVMIXER%"=="1" set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% ovmixer2
    if "%__SYSGEN_DSHOW_VRCTL%"=="1" set DIRECTX_MODULES=%DIRECTX_MODULES% vrctl

    REM DirectShow components
    REM =========================================================
    set DIRECTX_MODULES=%DIRECTX_MODULES% quartz

    REM Windows Media Player component
    REM =========================================================
    if not "%SYSGEN_DSHOW_WMP%"=="1" goto No_WMP
        set MSDXM_COMPONENTS=toolbar statbar bkgndbmp
        set DIRECTX_MODULES=%DIRECTX_MODULES% msdxm
    :No_WMP

    REM DirectShow ACM codecs
    REM =========================================================
    if not "%SYSGEN_DSHOW_MSADPCM%"=="1" goto No_DShow_MSADPCM
        set __SYSGEN_ACM_MSADPCM=1
        set SYSGEN_DSHOW_ACMWRAP=1
    :No_DShow_MSADPCM

    if not "%SYSGEN_DSHOW_IMAADPCM%"=="1" goto No_DShow_IMAADPCM
        set __SYSGEN_ACM_IMAADPCM=1
        set SYSGEN_DSHOW_ACMWRAP=1
    :No_DShow_IMAADPCM

    if not "%SYSGEN_DSHOW_MSGSM610%"=="1" goto No_DShow_MSGSM610
        set __SYSGEN_ACM_MSGSM610=1
        set SYSGEN_DSHOW_ACMWRAP=1
    :No_DShow_MSGSM610

    if not "%SYSGEN_DSHOW_MSG711%"=="1" goto No_DShow_MSG711
        set __SYSGEN_ACM_MSG711=1
        set SYSGEN_DSHOW_ACMWRAP=1
    :No_DShow_MSG711

    REM // DirectShow ACM support
    if not "%SYSGEN_DSHOW_ACMWRAP%"=="1" goto No_DShow_ACM
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% acmwrap
        set __SYSGEN_DSHOW_MSACMCE=1
    :No_DShow_ACM

    if "%__SYSGEN_DSHOW_MSACMCE%"=="1" set DIRECTX_MODULES=%DIRECTX_MODULES% msacmce

    REM // allows DirectShow ACM audio codecs to be used as CE ACM drivers
    set __SYSGEN_ACMDWRAP=1

    REM // DirectShow ICM codecs

    REM DirectShow MS-RLE support
    REM ===============================================================
    if not "%SYSGEN_DSHOW_MSRLE%"=="1" goto No_DShow_MSRLE
        set DIRECTX_MODULES=%DIRECTX_MODULES% msrle32
        set SYSGEN_DSHOW_ICM=1
    :No_DShow_MSRLE

    REM DirectShow ICM support
    REM ===============================================================
    if not "%SYSGEN_DSHOW_ICM%"=="1" goto No_DShow_ICM
        set DIRECTX_MODULES=%DIRECTX_MODULES% icm
        set SYSGEN_DSHOW_VIDREND=1
    :No_DShow_ICM

    REM // DirectShow DirectX Media Objects
    if not "%SYSGEN_DSHOW_DMO%"=="1" goto No_DMO
        set DIRECTX_MODULES=%DIRECTX_MODULES% msdmo
        set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% dmowrap
    :No_DMO

    REM DirectShow Video Renderer
    REM ==============================================================================
    if "%SYSGEN_DSHOW_VIDREND%"=="1" set QUARTZ1_COMPONENTS=%QUARTZ1_COMPONENTS% image

    REM // DirectShow sample applications
    REM set DIRECTX_MODULES=%DIRECTX_MODULES% dshowsamples

    if not "%SYSGEN_DSHOW_WMT%"=="1" goto No_WMT
        REM =========WMT40 components=========
        REM acmobj        - Audio dispatcher
        REM icmobj        - Video dispatcher
        REM urlobj        - URL dispatcher
        REM urlgrab       - URL grabber
        REM httpstrm      - HTTP streaming
        REM msstrm        - MMS streaming
        REM filestrm      - File streaming
        REM msbstrm       - MS Broadcast and Multi Bit-Rate (MBR) streaming
        REM nscfileparser - .nsc support
        REM m3uplayl      - .m3u and .asx v1 support
        REM asxplayl      - .asx v2 support
        REM xmlplayl      - .asx v3 support
        REM errormsgs     - the error string-table resource
        REM drmv7         - full DRMv7 support

        if "%__SYSGEN_DSHOW_WMT_ACM%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% acmobj
        if "%__SYSGEN_DSHOW_WMT_ICM%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% icmobj
        if "%SYSGEN_DSHOW_WMT_ASXV1%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% m3uplayl
        if "%SYSGEN_DSHOW_WMT_ASXV2%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% asxplayl
        if "%SYSGEN_DSHOW_WMT_ASXV3%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% xmlplayl
        if "%SYSGEN_DSHOW_WMT_NSC%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% nscfileparser

        if "%SYSGEN_DSHOW_WMT_HTTP%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% httpstrm
        if "%SYSGEN_DSHOW_WMT_MMS%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% msstrm
        if "%SYSGEN_DSHOW_WMT_LOCAL%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% filestrm
        if "%SYSGEN_DSHOW_WMT_MULTI%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% msbstrm

        REM This is how we ensure we have at least one source for our WMT splitter
        if "%SYSGEN_DSHOW_WMT_HTTP%"=="1" goto WMT_Has_Source
        if "%SYSGEN_DSHOW_WMT_MMS%"=="1" goto WMT_Has_Source
        if "%SYSGEN_DSHOW_WMT_LOCAL%"=="1" goto WMT_Has_Source
        if "%SYSGEN_DSHOW_WMT_MULTI%"=="1" goto WMT_Has_Source
        set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% filestrm
:WMT_Has_Source

        set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% urlgrab urlobj qtzbase

	REM // If we pick the DRM-OCX, we need to bring in DRMv7 too
        if not "%SYSGEN_DSHOW_WMT_DRMOCX%"=="1" goto No_DRMOCX
            set SYSGEN_URLMON=1
            set SYSGEN_DSHOW_WMT_DRMV7=1
            set DIRECTX_MODULES=%DIRECTX_MODULES% cedrm2
:No_DRMOCX
        REM // If we take the full DRMv7 component, use drmv7.lib and WININET
        if not "%SYSGEN_DSHOW_WMT_DRMV7%"=="1" goto No_DRMFULL
            set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% drmv7
            set SYSGEN_WININET=1
            set SYSGEN_MLANG=1
:No_DRMFULL
        REM // If we take the lite PD-DRM component, use pddrm.lib
        if not "%SYSGEN_DSHOW_WMT_PDDRM%"=="1" goto No_DRMLITE
            set SYSGEN_URLMON=1
            if not "%SYSGEN_DSHOW_WMT_DRMV7%"=="1" set DXMASF_COMPONENTS=%DXMASF_COMPONENTS% pddrm
:No_DRMLITE

        REM // If we're supporting DRM and ActiveSync, bring in CeDrmUtil to allow transferring content
        if "%SYSGEN_DSHOW_WMT_PDDRM%"=="1" set DATASYNC_MODULES=%DATASYNC_MODULES% cedrmutil

        REM // Windows Media core
        set DIRECTX_MODULES=%DIRECTX_MODULES% dxmasf
        set QUARTZ2_COMPONENTS=%QUARTZ2_COMPONENTS% scmdout filerend
:No_WMT

    set SYSGEN_AUDIO=1
:No_DShow

if not "%SYSGEN_DDRAW%"=="1" goto No_DDraw
    REM // DirectDraw components
    set DIRECTX_MODULES=%DIRECTX_MODULES% directdraw ddhel

    REM // DirectDraw sample applications
    set DIRECTX_MODULES=%DIRECTX_MODULES% ddsamples
:No_DDraw

if not "%__SYSGEN_DMUSIC%"=="1" goto No_DMusic
    REM // core DirectMusic engine
    set DIRECTX_MODULES=%DIRECTX_MODULES% dmusic
    REM // DirectMusic software synth
    set DIRECTX_MODULES=%DIRECTX_MODULES% dmsynth
    REM // DirectMusic wave samples
    set DIRECTX_MODULES=%DIRECTX_MODULES% msdls
    REM // Windows Media ACM Audio decompressor used by DirectMusic
    set __SYSGEN_ACM_WMA=1
    REM // DirectMusic requires DirectSound for actual playback of PCM data
    set SYSGEN_DSOUND=1
    set __SYSGEN_COM_STG=1
:No_DMusic

if not "%SYSGEN_DSOUND%"=="1" goto No_DSound
    REM // DirectSound core components
    set DIRECTX_MODULES=%DIRECTX_MODULES% directsound
    REM // DirectSound sample application
    REM set DIRECTX_MODULES=%DIRECTX_MODULES% dsplay
    REM // Sample capture application
    REM set DIRECTX_MODULES=%DIRECTX_MODULES% CaptureEcho

    set SYSGEN_AUDIO=1
:No_DSound

REM ==============================================================================================
REM
REM Optional components from WCEAppsFE
REM
REM ==============================================================================================

REM pWord
if "%SYSGEN_PWORD%"=="1"    set WCEAPPSFE_MODULES=%WCEAPPSFE_MODULES% pword pwd_res pwwiff

REM minimal fonts for pword are Times and Symbol
if "%SYSGEN_PWORD%"=="1"    set SYSGEN_FONTS_SYMBOL=1
if "%SYSGEN_PWORD%"=="1"    set SYSGEN_FONTS_TIMES_1_30=1


REM pWord and pInbox require some common components
if "%SYSGEN_PMAIL%"=="1"    set __SYSGEN_APPS_CMN=1
if "%SYSGEN_PWORD%"=="1"    set __SYSGEN_APPS_CMN=1
if "%__SYSGEN_APPS_CMN%"=="1" set WCEAPPSFE_MODULES=%WCEAPPSFE_MODULES% office