npc_cartrevolution.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// [手推车攻击]学习任务
// 代码重写 by FPE(2006.7.16)
// Jathena++ 论坛：http://www.foxofice.net/bbs
//----------------------------------------------

alberta.gat,232,106,6	script	格尔思	57,{
	if(getskilllv(153)>0)
	{
		mes "[格尔思]";
		mes "你已经掌握了手推车攻击的技巧，别再来烦我了！";
		close;
		end;
	}

	if(Class == 5 && JobLevel<35)
	{
		mes "[格尔思]";
		mes "嘿！朋友，你的职业等级还不足以学习手推车攻击，等你有了35级的时候再来找我吧！";
		close;
		end;
	}

	if(Class!=5 && Class!=10 && Class!=18)
	{
		mes "[格尔思]";
		mes "我是一名商人，当然我也会传授一些关于手推车的使用技巧。手推车攻击目前只有商人才可以学习，依我看你还不是一名商人吧？";
		close;
		end;
	}

	if(countitem(533)>=2 && countitem(998)>=15 && countitem(938)>=30 && countitem(601)>=20 && countitem(962)>=5)
	{
		mes "[格尔思]";
		mes "喂！看来你已经完成了你的任务，看来应该祝贺你了！当然我也是个遵守诺言的人，你还想要学习^0033FF手推车攻击^000000这种技能吗？";
		next;
		if(select("是的","不了，谢谢")==2)
		{
			mes "[格尔思]";
			mes "真是可恶，别再来烦我了，自己保重吧！";
			close;
			end;
		}

		mes "[格尔思]";
		mes "很好，那我就开始传授你这个技能，请稍等。";
		next;
		delitem 533,2;
		delitem 998,15;
		delitem 938,30;
		delitem 601,20;
		delitem 962,5;
		skill 153,1,0;
		mes "[格尔思]";
		mes "恭喜，你已经掌握了手推车攻击的技能，祝你好运！";
		close;
		end;
	}

	mes "[格尔思]";
	mes "欢迎来到艾尔贝塔，我是这里的手推车训练员。在这里你可以学到^0033FF手推车攻击^000000的技巧，你想要学习这种技能吗？";
	next;
	if(select("是的，请给予帮助","不，只是随便看看")==2)
	{
		mes "[格尔思]";
		mes "你可真是小气，快走，别烦我！";
		close;
		end;
	}

	mes "[格尔思]";
	mes "天下可没有免费的午餐，你必须支付我一些报酬，否则请你离开这里。";
	next;
	if(select("是的，我愿意","不了，别理我")==2)
	{
		mes "[格尔思]";
		mes "你可真是小气，快走，别再来烦我了！";
		close;
		end;
	}

	mes "[格尔思]";
	mes "那好吧，你需要带这些物品来给我：";
	mes "";
	mes "30 个^FF0000粘稠液体^000000";
	mes "20 个^FF0000苍蝇翅膀^000000";
	mes "15 个^FF0000铁^000000";
	mes "5  个^FF0000触须^000000";
	mes "2  个^FF0000葡萄汁^000000";
	mes "";
	mes "当你找到了这些东西再回来找我吧，祝你好运！";
	close;
	end;
}