npc_merchant.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// 商人转职任务
// 代码重写 & 修正 by FPE (2006.7.14)
// Jathena++ 论坛：http://www.foxofice.net/bbs
//----------------------------------------------

alberta_in.gat,53,43,6	script	商人公会会员	86,{
	set @TEMP,0;
	mes "[会员 曼修]";
	if(Test_MER==2)
	{
		set Test_MER,0;
		set Test_MER2,0;
		set Test_MER3,0;
		mes "名字是"+ strcharinfo(0) +"....";
		mes "你的转职考试不合格，你已经知道吧？你的纪录会被消失。你愿意申请就再问问我吧。";
		close;
		end;
	}

	if((Test_MER==8 || Test_MER==7) && Test_MER!=0)
	{
		mes "啊，"+ strcharinfo(0) +"。那么快就回来了吗？看起来好像你还没有完成我交给你的任务吧？赶紧出发吧！";
		close;
		end;
	}

	if(Test_MER==10 || Test_MER==9) goto JobMerQE10o9;
	if(Test_MER<=6 && Test_MER!=0) goto JobMerQLE6aN0;

	mes "请问有什么事情吗？";
	next;
	menu	"转职成为商人。",M0,
		"询问有关商人的事项。",M1,
		"询问有关转职为商人的条件。",M2,
		"放弃。",MEnd;

M0:
	if(Class==5)
	{
		mes "[会员 曼修]";
		mes ".....? 你说什么啊？你已经是商人啦！你该不会是在跟我开玩笑吧？！";
		close;
		end;
	}

	if(Class!=0)
	{
		mes "[会员 曼修]";
		mes "我们商人公会最讨厌的就是那种脚踏两条船做兼职工作的人了。";
		mes "我指的就是那种白天身分是商人，晚上则变成盗贼做出偷窃的行为之类的。我最痛恨这样的人了~";
		next;
		mes "[会员 曼修]";
		mes "嗯，虽然我话多了点，但只是想让你知道，我们不需要已经有别的职业的人。";
		close;
		end;
	}

	if(upper==1)
	{
		mes "[会员 曼修]";
		mes "已经转生了啊，真是努力";
		mes "好了，你现在是商人";
		JobChange 5,Upper;
		close;
		end;
	}

	mes "[会员 曼修]";
	mes "你想成为商人吗？...";
	next;
	if(getskilllv(1)<9)
	{
		mes "[会员 曼修]";
		mes "但是，要成为商人的话，基本技能等级最少也要达到9级以上才行。";
		mes "虽然商人这个职业只跟钱有接触，但是最少还是得要有基本的技能不是吗？";
		close;
		end;
	}

	mes "[会员 曼修]";
	mes "很好，那么，请在这份申请书上签名，并且备妥加入商人公会的入会费用1000金币。";
	mes "啊~你要是现在手头上不方便的话，可以先缴交500金币保证金，余款部分等到转职考试考完后再交也可以。";
	mes "怎么样？你要现在加入吗？";
	next;
	if(select("加入。","不，我考虑看看…")==2)
	{
		mes "[会员 曼修]";
		mes "你现在没有钱是吗？等筹好钱再来吧！";
		close;
		end;
	}

	set Test_MER,0;
	set Test_MER2,0;
	set Test_MER3,0;
	mes "[会员 曼修]";
	mes "名字叫... " + strcharinfo(0) + " ...";
	mes "这份申请书必须和会费一起交出去，你想要怎么缴纳会费呢？";
	next;
	menu	"1000金币一次付清。",M000,
		"分期付款，先缴交500金币。",M001,
		"放弃。",M00End;

M000:
	mes "[会员 曼修]";
	if(Zeny>=1000)
	{
		set Zeny,Zeny-1000;
		set Test_MER,4;
		mes "看一看，是1000金币没错。";
		goto M00Cont;
	}
	mes "看你的表情好像有点困难，你也可以采用分期付款，先缴交500金币，你好好考虑一下吧！";
	close;
	end;

M001:
	mes "[会员 曼修]";
	if(Zeny>=500)
	{
		set Zeny,Zeny-500;
		set Test_MER,3;
		mes "看一看，是500金币没错。好吧！虽然分期付款并不是个好习惯...";
		goto M00Cont;
	}
	mes "...你不要摆出一副'我也不想一毛钱都没有'的表情嘛，快点去筹钱吧！";
	close;
	end;

M00End:
	mes "[会员 曼修]";
	mes "准备好后，欢迎你随时来找我！";
	close;
	end;

M00Cont:
	next;
	mes "[会员 曼修]";
	mes "很好，你已经填妥公会加入申请书，我会帮你送出去的，那么，现在就让我来为你说明转职考试的相关事项吧！对了，在那之前有一点我必须要提醒你。";
	mes "商人注重商誉，不要欺骗别人，知道吗？";
	next;
	set @TEMP,rand(1,4);
	mes "[会员 曼修]";
	switch(@TEMP)
	{
	case 0:
		break;
	case 1:
		goto R1;
		break;
	case 2:
		goto R2;
		break;
	case 3:
		goto R3;
		break;
	}

	mes "到仓库去取物品，然后将它送到普隆德拉的旧剑士公会去，交给卡普拉公司普隆德拉支部总负责人就可以了。";
	set @TEMP,rand(1,3);
	if(@TEMP!=0) goto R01;
	mes "物品统一编号：2485741.";
	set Test_MER2,1;
	next;
	goto M00Cont1;

R01:
	mes "物品统一编号：2328137.";
	set Test_MER2,2;
	next;
	goto M00Cont1;

R1:
	mes "到仓库去取物品，然后将它送到吉芬的魔法学校去，交给那里的服务员就可以了。";
	set @TEMP,rand(1,3);
	if(@TEMP!=0) goto R11;
	mes "物品统一编号：2989396.";
	set Test_MER2,3;
	next;
	goto M00Cont1;

R11:
	mes "物品统一编号：2191737.";
	set Test_MER2,4;
	next;
	goto M00Cont1;

R2:
	mes "到仓库去取物品，然后将它送到梦罗克的染料制造厂去，交给兹巴杜力师傅就可以了。";
	set @TEMP,rand(1,3);
	if(@TEMP!=0) goto R21;
	mes "物品统一编号：3012685.";
	set Test_MER2,5;
	next;
	goto M00Cont1;

R21:
	mes "物品统一编号：3487372.";
	set Test_MER2,6;
	next;
	goto M00Cont1;

R3:
	mes "到仓库去取物品，然后将它送到依斯鲁得岛去，交给卡普拉职员就可以了。";
	set @TEMP,rand(1,3);
	if(@TEMP!=0) goto R31;
	mes "物品统一编号：3318702.";
	set Test_MER2,7;
	next;
	goto M00R3;

R31:
	mes "物品统一编号：3543625.";
	set Test_MER2,8;
	next;

M00R3:
	next;
	mes "[会员 曼修]";
	mes "另外... (这是我私人的请求，当你将物品交给对方时，请把这封信也交给他。别忘记咯~麻烦你了~~)";
	getitem 1072,1;
	next;

M00Cont1:
	mes "[会员 曼修]";
	mes "记住这个编号，到仓库去告诉仓库管理员你的目的地和统一编号，他就会把东西拿出来给你，千万要记得喔！";
	mes "仓库是由我为中心，右手边那间房间就是了。";
	next;
	mes "[会员 曼修]";
	mes "事情办完后回到这里来，把收据交回拿物品的那个仓库去，然后再来找我就可以了。";
	mes "那么，路上小心！";
	close;
	next;

M1:
	mes "[会员 曼修]";
	mes "商人？简单的说就是藉由卖东西来赚钱的人。";
	mes "虽然既不太会打架，也没有特别的攻击或回复技能，但可以用低廉的价格买进并以高价卖出所拥有的商品。";
	next;
	mes "[会员 曼修]";
	mes "虽然商人有一招金钱攻击的技能，但是很浪费，所以请你考虑清楚再使用。除了剑、权杖或是双手剑等以外的武器才能使用，当然啦！买卖这些东西是没有问题的。";
	mes "嗯，简单来说，商人呢，就是个可以赚很多钱的职业，知道了吗？";
	close;
	end;
M2:
	mes "[会员 曼修]";
	mes "具备三个条件才可以成为商人。";
	next;
	mes "[会员 曼修]";
	mes "第一，虽然说商人就是藉由买卖物品赚钱的人，但是基本技能等级最少还是要达到9级以上才可以。";
	next;
	mes "[会员 曼修]";
	mes "第二，加入商人公会的入会费要1000金币，真想成为商人的话，这点小钱应该难不倒你吧！嗯~";
	next;
	mes "[会员 曼修]";
	mes "第三，你还必须通过基本体力与方向感的转职测验，我会要你到某个指定的村落去送东西给某个特定的人，到时候再看你的正确性来决定是否让你转职。";
	close;
	end;
MEnd:
	close;
	end;

JobMerQE10o9:
	if(sex) mes "啊！ " + strcharinfo(0) + " 先生。";
	else mes "啊！ " + strcharinfo(0) + " 小姐。";
	mes "有个好消息告诉你。";
	if(Test_MER==10)
	{
		mes "你的转职考试已经合格了，商人公会总会已经承认你的商人资格，并且让你正式加入商人公会。";
		goto JobMerQua;
	}

	mes "你的转职考试已经合格了，商人公会总会已经承认你的商人资格，并且让你正式加入商人公会。";
	mes "那么就只剩下有关会费余款的部分了，你应该已经准备好了吧？";
	next;
	if(select("付余款500金币。","放弃。")==1)
	{
		mes "[会员 曼修]";
		if(Zeny<500)
		{
			mes "都已经到了这个地步了，居然发生这种没钱付的问题，想当商人的人怎么可以这么不讲信用呢！你快点去想想办法吧！";
			mes "[会员 曼修]";
			mes "怎么了？有什么问题吗？";
			close;
			end;
		}
		set Zeny,Zeny-500;
		mes "嗯，500金币刚好！";
		goto JobMerQua;
	}
	mes "[会员 曼修]";
	mes "怎么了？有什么问题吗？";
	close;
	end;

JobMerQua:
	mes "按下一个钮看看吧！";
	next;
	mes "[会员 曼修]";
	mes "恭喜你成为商人！";
	JobChange 5,Upper;
	set ReClass,5;
	mes "再次真心的恭喜你成为我们商人公会的一员，希望你往后仍持续参与我们的活动！";
	next;
	if(Test_MER2==7 || Test_MER2==8 && Test_MER3==9)
	{
		mes "[会员 曼修]";
		mes "(虽然没多少钱，但这是我的心意，算是谢谢你送信来给我，下次还要麻烦你了~)";
		set Zeny,Zeny+100;
		goto JobMerQua1;
	}
	if(Test_MER2==7 || Test_MER2==8 && Test_MER3==8)
	{
		mes "[会员 曼修]";
		mes "(什么，你把信给忘了。好吧，那也没办法，辛苦你了。)";
	}

JobMerQua1:
	set Test_MER,0;
	set Test_MER2,0;
	set Test_MER3,0;
	next;
	mes "[会员 曼修]";
	mes "为了要达成占有全世界通货量20%的远大目标，我们需要像你这样热血的青年！";
	mes "话虽如此，重点还是想要多赚点钱啦！你也是知道的嘛！是不是~";
	close;
	end;

JobMerQLE6aN0:
	mes "哦？你忘记了你的路线和物品编号吗？那好吧，我再告诉你一次。";
	if(Test_MER2==1 || Test_MER2==2) goto JobMerQ2E1oE2;
	if(Test_MER2==3 || Test_MER2==4) goto JobMerQ2E3oE4;
	if(Test_MER2==5 || Test_MER2==6) goto JobMerQ2E5oE6;
	if(Test_MER2==7 || Test_MER2==8) goto JobMerQ2E7oE8;

JobMerQ2E1oE2:
	mes "到仓库去取物品，然后将它送到普隆德拉的旧剑士公会去，交给卡普拉公司普隆德拉支部总负责人就可以了。";
	if(Test_MER2==2)
	{
		mes "物品统一编号：2328137.";
		goto JobMerQ2Cont;
	}
	mes "物品统一编号：2485741.";
	goto JobMerQ2Cont;

JobMerQ2E3oE4:
	mes "到仓库去取物品，然后将它送到吉芬的魔法学校去，交给那里的服务员就可以了。";
	if(Test_MER2==4)
	{
		mes "物品统一编号：2191737.";
		goto JobMerQ2Cont;
	}
	mes "物品统一编号：2989396";
	goto JobMerQ2Cont;

JobMerQ2E5oE6:
	mes "到仓库去取物品，然后将它送到梦罗克的染料制造厂去，交给兹巴杜力师傅就可以了。";
	if(Test_MER2==6)
	{
		mes "物品统一编号：3487372.";
		goto JobMerQ2Cont;
	}
	mes "物品统一编号：3012685.";
	goto JobMerQ2Cont;

JobMerQ2E7oE8:
	mes "到仓库去取物品，然后将它送到依斯鲁得岛去，交给卡普拉职员就可以了。";
	if(Test_MER2==8)
	{
		mes "物品统一编号：3543625.";
		goto JobMerQ2Cont;
	}
	mes "物品统一编号：3318702.";

JobMerQ2Cont:
	mes "仓库是由我为中心，右手边那间房间就是了。";
	if(Test_MER2==7 || Test_MER2==8) mes "另外... (这封信也拜托你了~~)";
	next;
	mes "[会员 曼修]";
	mes "记住这个编号，到仓库去告诉仓库管理员你的目的地和统一编号，他就会把东西拿出来给你，千万要记得喔！";
	mes "事情办完后回到这里来，把收据交回拿物品的那个仓库去，然后再来找我就可以了。";
	mes "那么，路上小心。";
	close;
	end;
}