npc_magican.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// 魔法师转职任务
// 代码重写 & 修正 by FPE (2006.7.14)
// Jathena++ 论坛：http://www.foxofice.net/bbs
//----------------------------------------------

geffen_in.gat,164,124,4	script	魔法公会 服务人员	123,{
	mes "[魔法公会 服务人员]";
	if(Class!=0)
	{
		mes "欢迎你来到魔法公会！这是某个有名的家庭餐厅里听到的迎宾辞，我只是想说说看而已~嘿嘿~";
		close;
		end;
	}

	if(upper==1)
	{
		mes "你是来转职为魔法师的吧？好吧，让我看看你的条件。";
		next;
		mes "[魔法公会 服务人员]";
		if(Joblevel<10)
		{
			mes "你的基本技能等级不足，现在不能转职为魔法师。";
			close;
			end;
		}
		if(Skillpoint!=0)
		{
			mes "你的技能点数还没有用完，现在不能转职为魔法师。";
			close;
			end;
		}
		jobchange 2,Upper;
		mes "恭喜，你现在已经是进阶魔法师了，记得好好修炼哦。";
		close;
		end;
	}

	if(job_magician_q==0)
	{
		mes "你好，请问有什么事情吗？";
		next;
		switch(select("转职成为魔法师","询问有关转职成为魔法师所需要的条件","放弃"))
		{
		case 1:
			mes "[魔法公会 服务人员]";
			if(JobLevel<10)
			{
				mes "你的职业等级不够喔！等你的职业等级修行到 10 级以后再说吧。";
				close;
				end;
			}
			if(Skillpoint!=0)
			{
				mes "你的技能点数尚未分配完，请分配后再来进行转职。";
				close;
				end;
			}
			mes "你想转职成为魔法师？";
			next;
			mes "[魔法公会 服务人员]";
			if(Sex) mes "...仔细看起来，你还真可爱，不过不是我喜欢的类型...";
			else mes "...仔细看起来，姊姊，你真可爱，我最喜欢像姊姊这种类型的人了~";
			next;
			mes "[魔法公会 服务人员]";
			mes "说归说，你想转职成为魔法师吗？那么，麻烦你在魔法师转职申请书上签个名。";
			next;
			if(select("申请转职成为魔法师。","放弃。")==2)
			{
				mes "[魔法公会 服务人员]";
				mes "什么啊？你不是说过想当成魔法师？！";
				close;
				end;
			}

			mes "[魔法公会 服务人员]";
			mes "对..在那边签名.... 哇~写得真好看~ 好了，好了...";
			mes "名字叫..." + strcharinfo(0) + "。";
			next;
			mes "[魔法公会 服务人员]";
			mes "你的转职考试项目是...";
			set job_magician_q,rand(1,4);
			mes "做出魔法师转职考试要求的混合液 "+ job_magician_q +" 号。";
			next;
			getitem 1092,1;
			mes "[魔法公会 服务人员]";
			mes "做混合液所需的所有材料，公会里的书籍上都有写，请你自己去找，书插在你右边中央的书柜。";
			next;
			mes "[魔法公会服务人员]";
			mes "你看得到中央的那些机器吧？要调制混合液的话，请利用那些机器。";
			next;
			mes "[魔法公会服务人员]";
			mes "那，加油~";
			close;
			end;
			break;
		case 2:
			mes "[魔法公会 服务人员]";
			mes "你想成为魔法师？";
			if(Sex) mes "像你这样可爱的人加入我们魔法公会，我们当然很欢迎~";
			else mes "像你这样可爱的姊姊加入我们魔法公会，我们当然很欢迎~";
			next;
			mes "[魔法公会 服务人员]";
			mes "第一，基本技能等级要达到 9 级以上才可以。";
			mes "第二，必须要做出魔法师转职要求的混合液。";
			next;
			mes "[魔法公会 服务人员]";
			mes "你要做什么样的混合液，要等你填写完魔法师转职申请书后，我才能告诉你。";
			next;
			mes "[魔法公会 服务人员]";
			mes "等你认为自己已经符合这两项转职条件后，再来向我询问其他的事项吧！";
			close;
			end;
			break;
		case 3:
			mes "[魔法公会 服务人员]";
			mes "什么？";
			close;
			end;
			break;
		}
	}
	else
	{
		mes "嗯，让我看看"+ strcharinfo(0) +"的转职考试任务是";
		next;
		mes "[魔法公会 服务人员]";
		mes "做出魔法师转职考试要求的混合液 "+ job_magician_q +" 号。";
		next;
		mes "[魔法公会 服务人员]";
		mes "那么让我检查一下...";
		switch(job_magician_q)
		{
		case 1:
			if(countitem(1071)<1)
			{
				mes "不对呀，你身上并没有混合液 "+ job_magician_q +" 号呀。是不是搞错了？你再好好看看。";
				close;
				end;
			}
			delitem 1071,1;
			break;
		case 2:
			if(countitem(1085)<1)
			{
				mes "不对呀，你身上并没有混合液 "+ job_magician_q +" 号呀。是不是搞错了？你再好好看看。";
				close;
				end;
			}
			delitem 1085,1;
			break;
		case 3:
			if(countitem(1086)<1)
			{
				mes "不对呀，你身上并没有混合液 "+ job_magician_q +" 号呀。是不是搞错了？你再好好看看。";
				close;
				end;
			}
			delitem 1086,1;
			break;
		case 4:
			if(countitem(1087) < 1)
			{
				mes "不对呀，你身上并没有混合液 "+ job_magician_q +" 号呀。是不是搞错了？你再好好看看。";
				close;
				end;
			}
			delitem 1087,1;
			break;
		}
		next;
		mes "[魔法公会服务人员]";
		mes "嗯，相信你已经尽力了。虽然做的不是很完美，但是这个程度应该可以了。";
		next;
		mes "[魔法公会服务人员]";
		mes "很好！你已经通过魔法师转职考试，我就依你的意愿将你转职成为魔法师吧！";
		next;
		mes "[魔法公会服务人员]";
		mes "你成为了我们的兄弟姊妹~ 你就是魔法师！恭喜你成为我们魔法公会的一员！";
		next;
		jobchange 2,Upper;
		set ReClass,2;
		set job_magician_q,0;
		set Zeny,Zeny+50;
		mes "[魔法公会 服务人员]";
		mes "欢迎你来到魔法公会！";
		mes "这是某个有名的家庭餐厅里听到的迎宾辞，我只是想说说看而已~嘿嘿~";
		mes "总之，恭喜你成为我们魔法公会的一员，以后还请多多指教~";
		close;
		end;
	}
}

geffen_in.gat,164,112,4	script	物品 调和机	111,{
	set @mixitem1_1,0;
	set @mixitem1_2,0;
	set @mixitem1_3,0;
	set @mixitem2,0;
	set @mixitem3,0;
	set @select_mixitem1,0;
	set @magic_powder,0;
	mes "[物品 调和机]";
	mes "魔法师转职考试专用物品调合机，本器材是由吉芬魔法协会提供的。";
	next;
	if(select("使用物品调配机机器","放弃")==2)
	{
		mes "[物品 调和机]";
		mes "自动关闭，谢谢您的使用";
		close;
		end;
	}

	mes "[物品 调和机]";
	mes "请选择要调和的水溶液。";
	next;
	menu	"裴扬水溶液",-,
		"梦罗克水溶液",L_MENU_1,
		"跳过",L_MENU_2;
	if(countitem(1089)<1)
	{
		mes "[物品 调和机]";
		mes "没有发现裴扬水溶液，请检查试管。调和机作业终了，感谢你的使用。";
		close;
		end;
	}
	set @mixitem2,1;
	goto L_MENU_2;

L_MENU_1:
	if(countitem(1088)<1)
	{
		mes "[物品 调和机]";
		mes "没有发现梦罗克水溶液，请检查试管。调和机作业终了，感谢你的使用。";
		close;
		end;
	}
	set @mixitem2,2;
	next;

L_MENU_2:
	mes "[物品 调和机]";
	mes "请选择要调和的物品。";
	menu	"杰勒比结晶",L_MIXITEM1_SELECT_1,
		"毛",L_MIXITEM1_SELECT_2,
		"牛奶",L_MIXITEM1_SELECT_3,
		"查看所设定的物品明细",L_MIXITEM_CHECK,
		"设定完成",L_MIXITEM_STEP_OK;

L_MIXITEM1_SELECT_1:
	mes "请输入数量";
	next;
	input @mixitem_num;
	if(@mixitem_num<0 || @mixitem_num>10000)
	{
		mes "[物品 调和机]";
		mes "物品数量输入超出范围，请重新输入";
		next;
		goto L_MENU_2;
	}
	set @mixitem1_1,@mixitem_num;
	goto L_MENU_2;

L_MIXITEM1_SELECT_2:
	mes "请输入数量";
	next;
	input @mixitem_num;
	if(@mixitem_num<0 || @mixitem_num>10000)
	{
		mes "[物品 调和机]";
		mes "物品数量输入超出范围，请重新输入";
		goto L_MENU_2;
	}
	set @mixitem1_2,@mixitem_num;
	goto L_MENU_2;

L_MIXITEM1_SELECT_3:
	mes "请输入数量";
	next;
	input @mixitem_num;
	if(@mixitem_num<0 || @mixitem_num>10000)
	{
		mes "[物品 调和机]";
		mes "物品数量输入超出范围，请重新输入";
		goto L_MENU_2;
	}
	set @mixitem1_3,@mixitem_num;
	goto L_MENU_2;

L_MIXITEM_CHECK:
	next;
	mes "[物品 调和机]";
	if(@mixitem1_1==0 && @mixitem1_2==0 && @mixitem1_3==0 && @mixitem2==0)
	mes "里面没有任何东西";
	if(@mixitem1_1>0) mes "杰勒比结晶: " + @mixitem1_1 + " 块";
	if(@mixitem1_2>0) mes "毛: " + @mixitem1_2 + " 团";
	if(@mixitem1_3>0) mes "牛奶: " + @mixitem1_3 + " 瓶";
	if(@mixitem2==0) mes "溶剂: 无";
	if(@mixitem2==1) mes "溶剂: 裴扬水溶液";
	if(@mixitem2==2) mes "溶剂: 梦罗克水溶液";
	next;