npc_card_remover.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// Card removal NPC by TyrNemesis^ 日本語訳：胡蝶蘭
// 代码重写 by FPE (2006.6.26)
// Jathena++ 论坛：http://www.foxofice.net/bbs
//----------------------------------------------

prt_in.gat,28,73,4	script	神秘妇人	78,{
	mes "[神秘妇人]";
	mes "你好啊~~年轻人！";
	mes "想要卸除装载在装备上的卡片吗？";
	mes "我可以使用魔法来帮你这个忙！";
	mes "不过你必须支付一定的费用喔！";
	next;
	menu	"好啊！看来真不错。",A01,
		"你是如何收费的呀？",-,
		"不了，谢谢。",Exit;

	mes "[神秘妇人]";
	mes "嗯....卸除一件装备需要支付^4040FF200000z^000000Zeny。";
	mes "一张卡片加收^4040FF25000z^000000Zeny。";
	mes "另外，我需要一些^4040FF星星的角^000000和";
	mes "^4040FF黄色魔力矿石^000000来辅助我的魔法。";
	next;
	menu	"那帮我卸除吧",-,
		"想想还是算了",Exit;

A01:
	mes "[神秘妇人]";
	mes "HOO~你想我帮你卸除哪一件装备呢？";
	next;
	menu	"嗯..卸除..让我想想。",Exit,
		getequipname(1),SLOT1,
		getequipname(2),SLOT2,
		getequipname(3),SLOT3,
		getequipname(4),SLOT4,
		getequipname(5),SLOT5,
		getequipname(6),SLOT6,
		getequipname(7),SLOT7,
		getequipname(8),SLOT8,
		getequipname(9),SLOT9,
		getequipname(10),SLOT10;

SLOT1:
	set @part,1;
	goto CardNumCheck;
SLOT2:
	set @part,2;
	goto CardNumCheck;
SLOT3:
	set @part,3;
	goto CardNumCheck;
SLOT4:
	set @part,4;
	goto CardNumCheck;
SLOT5:
	set @part,5;
	goto CardNumCheck;
SLOT6:
	set @part,6;
	goto CardNumCheck;
SLOT7:
	set @part,7;
	goto CardNumCheck;
SLOT8:
	set @part,8;
	goto CardNumCheck;
SLOT9:
	set @part,9;
	goto CardNumCheck;
SLOT10:
	set @part,10;

CardNumCheck:
	if(getequipcardcnt(@part)==0)
	{
		emotion 5;
		mes "[神秘妇人]";
		mes "年轻人...这件装备上面并没有卡片呀~~~";
		close;
		end;
	}
	set @cardcount,getequipcardcnt(@part);
	mes "[神秘妇人]";
	mes "这件装备的插槽上已经插上了" + @cardcount + "张卡片。";
	mes "你必须支付^0000FF" + (200000+(@cardcount*25000)) + "金币和^000000一个^0000FF星星的角，^000000一个^0000FF黄色魔力矿石^000000。";
	next;
	menu	"这些我都带来了",-,
		"我还没有准备好。",Exit;

	mes "[神秘妇人]";
	mes "在开始之前我得先告诉你，使用这种魔法万一失败，可能会损坏了卡片或装备，也可能装备和卡片一起损坏了。";
	mes "万一损坏了，我可^FF4040不会赔偿^000000给你的喔~~所以，你必须考虑清楚，如果损坏的话，你想保留卡片还是装备。";
	next;
	menu	"想想还是算了。",Exit,
		"保留装备。",-,
		"保留卡片。",PriorityCard;

	set @failtype,1;
	goto RemoveCard;
PriorityCard:
	set @failtype,2;
RemoveCard:
	mes "[神秘妇人]";
	mes "很好！那我开始了~~。";
	next;
	if(zeny<(200000+(@cardcount*25000)) || countitem(1000)<1 || countitem(715)<1)
	{
		mes "[神秘妇人]";
		mes "你并没有把我需要的材料带来呀，还是把东西都带齐了再来找我吧！再说，我的付出也应该得要有所收获嘛！";
		close;
		end;
	}
	set zeny,zeny-(200000+(@cardcount*25000));
	delitem 1000,1;
	delitem 715,1;

	set @failchance,rand(100);
	if(@failchance<2)
	{
		emotion 4;
		mes "[神秘妇人]";
		mes "最担心的事情终于发生了...对不起，卡片坏掉了.....";
		failedremovecards @part,0;
		close;
		end;
	}
	if(@failchance<6 && @failtype==1)
	{
		emotion 4;
		mes "[神秘妇人]";
		mes "尽管我已经设法将卡片从装备的插槽中卸除，但它们还是被损坏了。幸好，装备还是好的。";
		failedremovecards @part,1;
		close;
		end;
	}
	if(@failchance<6 && @failtype==2)
	{
		emotion 4;
		mes "[神秘妇人]";
		mes "不幸的消息....卡片是卸除下来了，可是装备在卸除过程中被破坏了。";
		failedremovecards @part,2;
		close;
		end;
	}
	if(@failchance<10)
	{
		emotion 4;
		mes "[神秘妇人]";
		mes "不行不行，卸除失败了....幸好，卸除过程中卡片和装备还依然完好。";
		failedremovecards @part,3;
		close;
		end;
	}
	emotion 18;
	successremovecards @part;
	mes "[神秘妇人]";
	mes "大功告成啦！";
	mes "这是你的卡片和你的道具，再见！";
	close;
	end;

Exit:
	mes "[神秘妇人]";
	mes "很好，如果需要，我愿意随时为你服务。";
	close;
	end;
}