npc_laba.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// 小喇叭广播 by FPE - 2007.9.12
// Jathena++ 论坛：http://www.foxofice.net/bbs
//----------------------------------------------

prontera.gat,164,171,4	script	小喇叭广播	703,{
	if(gettimetick(0)-Laba_WaitTime<180000)
	{
		mes "[小喇叭广播]";
		mes "你刚刚发过广播，请稍微等会再来。";
		close;
	}

	mes "[小喇叭广播]";
	mes "你好，我可以帮你广播一些信息。";
	mes "为了防止有人利用广播刷屏，规定每次广播间隔3分钟。";
	next;
	mes "[小喇叭广播]";
	mes "这是收费服务。";
	mes "根据每种信息档次，将会分别收取不同的信息费用。";
	mes "请选择你要发送信息的类型：";
	next; 
	switch(select(	"找MM/GG  (2W Zeny)",
			"找人组队 (2W Zeny)",
			"找人带我 (1W Zeny)",
			"公会收人 (10W Zeny)",
			"自定义彩色广播 (20W zeny)"
			)
		)
	{
	case 1:
		if(zeny<20000)
		{
			mes "[小喇叭广播]";
			mes "对不起，你的金额不足。";
			close;
		}
		set zeny,zeny-20000;
		if(sex) announce string_format("【小喇叭广播】漂亮MM们好，我是帅哥{0:S}，有MM愿意和我聊天吗？M我噢，嘿嘿^_^",strcharinfo(0)),15;
		else announce string_format("【小喇叭广播】帅GG们好，我是最最可爱的({0:S})美眉，有帅GG愿意陪我聊天吗？M偶喔，嘻嘻^o^",strcharinfo(0)),15;
		break;
	case 2:
		if(getcharid(1)==0)
		{
			mes "[小喇叭广播]";
			mes "你还没有组队哦！";
			mes "为了节约你的Zeny，请先建立队伍！";
			close;
		}
		if(zeny<20000)
		{
			mes "[小喇叭广播]";
			mes "对不起，你的金额不足。";
			close;
		}
		set zeny,zeny-20000;
		announce string_format("【小喇叭广播】大家好，我是({0:S})，有人愿意加入({1:S})队伍一起练级打宝吗？M我噢，吼吼-_-",strcharinfo(0),strcharinfo(1)),15;
		break;
	case 3:
		if(zeny<10000)
		{
			mes "[小喇叭广播]";
			mes "对不起，你的金额不足。";
			close;
		}
		set zeny,zeny-10000;
		announce string_format("【小喇叭广播】 GGJJ们好，我是新人({0:S})，有GG/JJ愿意带我练级吗？M偶喔，呜呜T_T",strcharinfo(0)),15;
		break;
	case 4:
		if(getcharid(2)==0)
		{
			mes "[小喇叭广播]";
			mes "你好像还没有加入任何公会嘛。";
			mes "为了节约你的Zeny，还是有了公会再发吧。";
			close;
		}
		if(zeny<100000)
		{
			mes "[小喇叭广播]";
			mes "对不起，你的金额不足。";
			close;
		}
		set zeny,zeny-100000;
		announce string_format("【小喇叭广播】({0:S})公会收人喽，入会的快M会长({1:S})！！",strcharinfo(2),getguildmaster(getcharid(2))),15; 
		break;
	case 5:
		if(zeny<200000)
		{
			mes "[小喇叭广播]";
			mes "对不起，你的金额不足。";
			close;
		}
		mes "[小喇叭广播]";
		mes "在输入信息之前请看^FF0000注意事项^000000";
		mes "^3355FF1、只限70个字符或35个汉字以内^000000";
		mes "^3355FF2、禁止发送任何含有暴力、色情、政治、人身攻击的文字^000000";
		next;
		mes "[小喇叭广播]";
		mes "如有玩家发现违反规定者请抓图在论坛上举报，任何违规者^FF0000冻结帐户1周^000000,再犯将^FF0000直接删除帐户^000000！";
		next;
		while(1)
		{
			mes "[小喇叭广播]";
			mes "请选择颜色：";
			switch(select("红色","橙色","黄色","绿色","青色","蓝色","紫色","自定义颜色"))
			{
			case 1:
				set '@color$,"ff0000";
				break;
			case 2:
				set '@color$,"ffa500";
				break;
			case 3:
				set '@color$,"ffff00";
				break;
			case 4:
				set '@color$,"008000";
				break;
			case 5:
				set '@color$,"008080";
				break;
			case 6:
				set '@color$,"0000ff";
				break;
			case 7:
				set '@color$,"800080";
				break;
			default:
				set '@r,-1;
				set '@g,-1;
				set '@b,-1;
				while('@r<0 || '@r>255)
				{
					next;
					mes "[小喇叭广播]";
					mes "请输入RGB(红绿蓝)中的R值(0-255)：";
					input '@r;
				}
				while('@g<0 || '@g>255)
				{
					next;
					mes "[小喇叭广播]";
					mes "请输入RGB(红绿蓝)中的G值(0-255)：";
					input '@g;
				}
				while('@b<0 || '@b>255)
				{
					next;
					mes "[小喇叭广播]";
					mes "请输入RGB(红绿蓝)中的B值(0-255)：";
					input '@b;
				}
				set '@color$,string_format("{0:X2}{1:X2}{2:X2}",'@r,'@g,'@b);
				break;
			}
			next;
			mes "[小喇叭广播]";
			mes "请输入公告内容：";
			input '@msg$;
			next;
			mes "[小喇叭广播]";
			mes "发送的公告如下：";
			mes "^"+'@color$+'@msg$;
			mes " ";
			mes "^000000需要修改内容或颜色吗？";
			next;
			if(select("我要修改","不用修改")==2)
			{
				set zeny,zeny-200000;
				announce string_format("【小喇叭广播】({0:S})说:{1:S}。",strcharinfo(0),'@msg$),0,"0x"+'@color$;
				break;
			}
		}
		break;
	}

	next;
	mes "[小喇叭广播]";
	mes "信息发送成功。";
	set Laba_WaitTime,gettimetick(0);
	close;
}