耐久度修补员.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//==============================================
// 耐久度修补员
// Made by FPE(2006.9.15)
// Jathena++ BBS: http://www.foxofice.net/bbs
//----------------------------------------------

prt_in.gat,61,54,2	script	耐久度修补员	63,{
	mes "[耐久度修补员]";
	mes "我是专门为客人修理装备耐久度/最大耐久度的，但是要收取一定的费用哦~";
	next;
	mes "[耐久度修补员]";
	mes "装备耐久度会在战斗过程中损耗。";
	mes "在人物死亡的时候，是损耗所有装备的耐久度为最大耐久度的5%。";
	mes "一旦耐久度损耗完毕，装备就会变为损坏状态，并且会损耗^0000ff最大耐久度^000000。";
	next;
	mes "[耐久度修补员]";
	mes "损坏了的装备可以通过修复继续使用。";
	mes "但是如果不修复耐久度和最大耐久度的话，装备很快就会再次损坏，所以修复耐久度和最大耐久度是很有必要的。";
	mes "装备最大的耐久度，可以恢复至^0000ff这种物品^000000的最大耐久度";
	next;
	mes "[耐久度修补员]";
	mes "你要修复耐久度/最大耐久度吗？";
	next;
	if(select("修复装备耐久度","修复装备最大耐久度")==1)
	{
		//判断是否没有任何装备
		for(set @i,1; @i<11; set @i,@i+1)
		{
			if(getequipid(@i)>0) break;
			if(@i==10)
			{
				mes "[耐久度修补员]";
				mes "你身上没有任何装备。";
				close;
				end;
			}
		}

		switch(select(	(getequipid(1)>0)?(itemid2name(getequipid(1)) + "(" + geteqdure(1) + "->" + geteqmaxdure(1) + ")"):"",
				(getequipid(2)>0)?(itemid2name(getequipid(2)) + "(" + geteqdure(2) + "->" + geteqmaxdure(2) + ")"):"",
				(getequipid(3)>0)?(itemid2name(getequipid(3)) + "(" + geteqdure(3) + "->" + geteqmaxdure(3) + ")"):"",
				(getequipid(4)>0)?(itemid2name(getequipid(4)) + "(" + geteqdure(4) + "->" + geteqmaxdure(4) + ")"):"",
				(getequipid(5)>0)?(itemid2name(getequipid(5)) + "(" + geteqdure(5) + "->" + geteqmaxdure(5) + ")"):"",
				(getequipid(6)>0)?(itemid2name(getequipid(6)) + "(" + geteqdure(6) + "->" + geteqmaxdure(6) + ")"):"",
				(getequipid(7)>0)?(itemid2name(getequipid(7)) + "(" + geteqdure(7) + "->" + geteqmaxdure(7) + ")"):"",
				(getequipid(8)>0)?(itemid2name(getequipid(8)) + "(" + geteqdure(8) + "->" + geteqmaxdure(8) + ")"):"",
				(getequipid(9)>0)?(itemid2name(getequipid(9)) + "(" + geteqdure(9) + "->" + geteqmaxdure(9) + ")"):"",
				(getequipid(10)>0)?(itemid2name(getequipid(10)) + "(" + geteqdure(10) + "->" + geteqmaxdure(10) + ")"):"",
				"^ff0000耐久度全修复^000000"
				))
		{
		case 11:
			set @pay,0;
			for(set @i,1; @i<11; set @i,@i+1)
			{
				if(@i==4 && getequipid(4))
				{
					if(getequipid(@i) && getiteminfo(getequipid(@i),13)==34) continue;
				}

				if(getequipid(@i)) set @pay,@pay + ( (geteqmaxdure(@i)-geteqdure(@i))*12/10 );
			}
			mes "[耐久度修补员]";
			if(@pay<=0)
			{
				mes "装备不需要修复";
				close;
				end;
			}
			mes "修复所有耐久度需要" + @pay + "zeny";
			if(zeny < @pay)
			{
				mes "等你有足够金钱的时候再来找我吧";
				close;
				end;
			}
			mes "你要马上修复吗？";
			next;
			if(select("马上修复","不要修复")==2)
			{
				close;
				end;
			}

			mes "[耐久度修补员]";
			set zeny,zeny-@pay;
			for(set @i,1; @i<11; set @i,@i+1)
			{
				if(getequipid(@i)) seteqdure @i,geteqmaxdure(@i);
			}
			mes "修理完毕！";
			emotion 18;
			close;
			end;
			break;
		default:
			set @i,@menu;
			set @pay,( (geteqmaxdure(@i)-geteqdure(@i))*12/10 );
			mes "[耐久度修补员]";
			if(@pay<=0)
			{
				mes "这件装备不需要修复";
				close;
				end;
			}

			mes "修复这个需要" + @pay + "zeny";
			if(zeny < @pay)
			{
				mes "等你有足够金钱的时候再来找我吧";
				close;
				end;
			}

			mes "你要马上修复吗？";
			next;
			if(select("马上修复","不要修复")==2)
			{
				close;
				end;
			}

			mes "[耐久度修补员]";
			set zeny,zeny-@pay;
			seteqdure @i,geteqmaxdure(@i);
			mes "修理完毕！";
			emotion 18;
			close;
			end;
			break;
		}
	}

	//判断是否没有任何装备
	for(set @i,1; @i<11; set @i,@i+1)
	{
		if(getequipid(@i)>0) break;
		if(@i==10)
		{
			mes "[耐久度修补员]";
			mes "你身上没有任何装备。";
			close;
			end;
		}
	}

	switch(select(	(getequipid(1)>0)?(itemid2name(getequipid(1)) + "(" + geteqmaxdure(1) + "->" + getitemmaxdure(getequipid(1),geteqlv(1)) + ")"):"",
			(getequipid(2)>0)?(itemid2name(getequipid(2)) + "(" + geteqmaxdure(2) + "->" + getitemmaxdure(getequipid(2),geteqlv(2)) + ")"):"",
			(getequipid(3)>0)?(itemid2name(getequipid(3)) + "(" + geteqmaxdure(3) + "->" + getitemmaxdure(getequipid(3),geteqlv(3)) + ")"):"",
			(getequipid(4)>0)?(itemid2name(getequipid(4)) + "(" + geteqmaxdure(4) + "->" + getitemmaxdure(getequipid(4),geteqlv(4)) + ")"):"",
			(getequipid(5)>0)?(itemid2name(getequipid(5)) + "(" + geteqmaxdure(5) + "->" + getitemmaxdure(getequipid(5),geteqlv(5)) + ")"):"",
			(getequipid(6)>0)?(itemid2name(getequipid(6)) + "(" + geteqmaxdure(6) + "->" + getitemmaxdure(getequipid(6),geteqlv(6)) + ")"):"",
			(getequipid(7)>0)?(itemid2name(getequipid(7)) + "(" + geteqmaxdure(7) + "->" + getitemmaxdure(getequipid(7),geteqlv(7)) + ")"):"",
			(getequipid(8)>0)?(itemid2name(getequipid(8)) + "(" + geteqmaxdure(8) + "->" + getitemmaxdure(getequipid(8),geteqlv(8)) + ")"):"",
			(getequipid(9)>0)?(itemid2name(getequipid(9)) + "(" + geteqmaxdure(9) + "->" + getitemmaxdure(getequipid(9),geteqlv(9)) + ")"):"",
			(getequipid(10)>0)?(itemid2name(getequipid(10)) + "(" + geteqmaxdure(10) + "->" + getitemmaxdure(getequipid(10),geteqlv(10)) + ")"):""
			))
	{
		set @i,@menu;
		set @pay,( (getitemmaxdure(getequipid(@i),geteqlv(@i))-geteqmaxdure(@i)) *4 );
		mes "[耐久度修补员]";
		if(@pay<=0)
		{
			mes "这件装备不需要修复";
			close;
			end;
		}

		mes "修复这个需要" + @pay + "zeny";
		if(zeny < @pay)
		{
			mes "等你有足够金钱的时候再来找我吧";
			close;
			end;
		}

		mes "你要马上修复吗？";
		next;
		if(select("马上修复","不要修复")==2)
		{
			close;
			end;
		}

		mes "[耐久度修补员]";
		set zeny,zeny-@pay;
		seteqmaxdure @i,getitemmaxdure(getequipid(@i),geteqlv(@i));
		mes "修理完毕！";
		emotion 18;
		close;
		end;
	}
}