npc_gvg_config.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//=========================================================================
// 攻城战的开始·结束计时
//	从const.txt取得设定时间
//	（GvGWeekDay, GvGTimeST, GvGTimeST, GvGTime*ST, GvGTime*ED）
//
//　■MAP服务器启动后的60秒之后判断是否开始
// 汉化和修正 : FPE
// Jathena++ 论坛：http://www.foxofice.net/bbs
//-------------------------------------------------------------------------

-	script	#AgitConfig	-1,{
	end;
OnInit:
	if(GvGWeekDay == 0)
		end;
	//如果有开启工会战，那么对应的位元为1
	for(set '@i,0; '@i<7; set '@i,'@i+1) {
		set 'open['@i],(GvGWeekDay &(1<<'@i))? 1: 0;
	}
	//设定每周工会战起始时间
	if(GvGTimeST == GvGTimeED) {
		setarray 'dbt,GvGTime0ST,GvGTime1ST,GvGTime2ST,GvGTime3ST,GvGTime4ST,GvGTime5ST,GvGTime6ST;
		setarray 'fin,GvGTime0ED,GvGTime1ED,GvGTime2ED,GvGTime3ED,GvGTime4ED,GvGTime5ED,GvGTime6ED;
	}
	//每天都是相同的时间
	else {
		cleararray 'dbt,GvGTimeST,7;
		cleararray 'fin,GvGTimeED,7;
	}
	sleep 60000;
	set '@day,gettime(4);
	set '@min,gettime(3)*100+gettime(2);
	//当前时间为工会战时间
	if('open['@day] && '@min>='dbt['@day] && '@min<'fin['@day]) {
		debugmes "攻城战开始 [ " +gettimestr("%H:%M",6)+ " ]";
		agitstart;
	}
	sleep (60-gettime(1))*1000;	//待机时间设定

OnTimer60000:
	initnpctimer;
	set '@day,gettime(4);
	set '@min,gettime(3)*100+gettime(2);

	//24点结束时的例外处理
	if('@min == 0) {
		set '@prev,('@day>0)? '@day-1: 6;
		if('open['@prev] && 'fin['@prev]==2400) {
			if('open['@day]==0 || 'dbt['@day]>0) {
				debugmes "攻城战结束 [ " +gettimestr("%H:%M",6)+ " ]";
				agitend;
			}
			end;
		}
	}
	if('open['@day]==0)
		end;
	if('@min == 'dbt['@day]) {
		debugmes "攻城战开始 [ " +gettimestr("%H:%M",6)+ " ]";
		agitstart;
	}
	else if('@min == 'fin['@day]) {
		debugmes "攻城战结束 [ " +gettimestr("%H:%M",6)+ " ]";
		agitend;
	}
	end;
}


//-----GM专用的调试程序-----
//===========================================================
//prontera.gat,152,208,0	script	GvG-Control	111,{
//	if(getgmlevel()==0)
//		end;
//	mes "[GvG-Control^ff0000(GM专用)^000000]";
//	mes "攻城战模式设定";
//	next;
//	switch (select("开始","停止","调试","取消")) {
//	case 1:
//		announce "攻城战开始",0;
//		agitstart;
//		break;
//	case 2:
//		announce "攻城战结束",0;
//		agitend;
//		break;
//	case 3:
//		setarray '@chr$,"日","一","二","三","四","五","六";
//		for(set '@i,0; '@i<7; set '@i,'@i+1)
//			mes '@chr$['@i]+ "星期 ： " +(getelementofarray( getvariableofnpc('open,"#AgitConfig"),'@i ))? "○": "×";
//		next;
//		if(GvGTimeST != GvGTimeED) {
//			mes "每天时间　" +GvGTimeST+ " ～ " +GvGTimeED;
//			break;
//		}
//		for(set '@i,0; '@i<7; set '@i,'@i+1) {
//			mes '@chr$['@i]+ "星期 ： " +getelementofarray( getvariableofnpc('dbt,"#AgitConfig"),'@i )+
//						" ～ " +getelementofarray( getvariableofnpc('fin,"#AgitConfig"),'@i );
//		}
//		break;
//	}
//	close;
//}
//===========================================================