npc_gvg_exe.txt

JA++的最新...很多ROSF都用这个 ] 是个不错的东西-3-

//=========================================================================
// 让出秘密基地·解散工会的公共函数
//	callfunc "AgitGiveUp","AgitCode";
//
// ■ 分配角色
//	"::OnFlagEmb_XY" 参考npc_gvg_flag.txt
//
// ■ function
//	如果是攻城战的话，function "AgitSummon" 会被调用（npc_gvg_monster）
// 汉化和修正 : FPE
// Jathena++ 论坛：http://www.foxofice.net/bbs
//-------------------------------------------------------------------------

function	script	AgitGiveUp	{
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);		//'@map$以外的都是虚设的
	killmonsterall '@map$;
	disablenpc "AgitKafra_"+getarg(0);
	for(set '@i,1; '@i<=17; set '@i,'@i+1) {
		setcastledata '@map$,'@i,('@i==2 || '@i==3)? 1: 0;
	}
	donpcevent "::OnFlagEmb_"+getarg(0);		//工会图标的改变
	maprespawnguildid '@map$,0,7;
	if(agitcheck(0))
		callfunc "AgitSummon",getarg(0);	//召唤怪物和华丽金属函数
	return;
}


//=========================================================================
// 攻城战实行部分
//	在这里进行全部处理！
//
// 　※ 根据strnpcinfo(2) 取得工会名字
//      使用duplicate，把每次NPC的MAP名字作为参数处理
//-------------------------------------------------------------------------

-	script	AgitExe	-1,{
OnAgitInit:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);		//'@map$以外的都是虚设的
	if('@map$ == "-")					//duplicate不做任何事情
		end;
	if(getcastledata('@map$,9) == 0)
		disablenpc "AgitKafra_"+strnpcinfo(2);
	for(set '@i,10; '@i<=17; set '@i,'@i+1) {	//召唤监护人
		if(getcastledata('@map$,'@i))
			callfunc "GuardianCall",strnpcinfo(2),'@i,0;
	}
	end;
OnAgitStart:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);
	if('@map$ == "-")
		end;
	maprespawnguildid '@map$,getcastledata('@map$,1),2;
	callfunc "AgitSummon",strnpcinfo(2);	//召唤华丽金属(npc_gvg_monster.txt)
	gvgon '@map$;
	end;
OnAgitBreak:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);
	if('@map$ == "-")
		end;
	killmonsterall '@map$;
	set '@gid,getcharid(2);		//取得破坏华金的工会ID
	if('@gid <= 0)
		end;
	setcastledata '@map$,1,'@gid;
	for(set '@i,2; '@i<=17; set '@i,'@i+1) {
		if('@i==2 || '@i==3) {
			set '@val,getcastledata('@map$,'@i)-5;
			setcastledata '@map$,'@i,('@val<1)? 1: '@val;
		}
		else
			setcastledata '@map$,'@i,0;
	}
	announce "华丽金属被破坏了",9,0x00ff00;
	sleep 800;
	announce "秘密基地 [" +getcastlename('@map$)+ "] 被 [" +getguildname('@gid)+ "] 工会占领了",0;
	donpcevent "::OnFlagEmb_"+strnpcinfo(2);	//工会图标的改变(npc_gvg_flag.txt)
	end;
OnAgitEliminate:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);
	if('@map$ == "-")
		end;
	maprespawnguildid '@map$,getcastledata('@map$,1),6;
	callfunc "AgitSummon",strnpcinfo(2);	//再次召唤华丽金属(npc_gvg_monster.txt)
	end;
OnGuildBreak:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);
	if('@map$ == "-")
		end;
	callfunc "AgitGiveUp",strnpcinfo(2);
	end;
OnAgitEnd:
	set '@dummy,getmapxy('@map$,'@dummy,'@dummy,1);
	if('@map$ == "-")
		end;
	maprespawnguildid '@map$,getcastledata('@map$,1),4;
	killmonster '@map$,strnpcinfo(0)+"::OnAgitBreak";	//华丽金属被破坏
	gvgoff '@map$;
	end;
}

//露依纳
aldeg_cas01.gat,0,0,0	duplicate(AgitExe)	AgitExe#L1	-1
aldeg_cas02.gat,0,0,0	duplicate(AgitExe)	AgitExe#L2	-1
aldeg_cas03.gat,0,0,0	duplicate(AgitExe)	AgitExe#L3	-1
aldeg_cas04.gat,0,0,0	duplicate(AgitExe)	AgitExe#L4	-1
aldeg_cas05.gat,0,0,0	duplicate(AgitExe)	AgitExe#L5	-1
//咘哩妥利亚
gefg_cas01.gat,0,0,0	duplicate(AgitExe)	AgitExe#B1	-1
gefg_cas02.gat,0,0,0	duplicate(AgitExe)	AgitExe#B2	-1
gefg_cas03.gat,0,0,0	duplicate(AgitExe)	AgitExe#B3	-1
gefg_cas04.gat,0,0,0	duplicate(AgitExe)	AgitExe#B4	-1
gefg_cas05.gat,0,0,0	duplicate(AgitExe)	AgitExe#B5	-1
//青林湖泊
payg_cas01.gat,0,0,0	duplicate(AgitExe)	AgitExe#C1	-1
payg_cas02.gat,0,0,0	duplicate(AgitExe)	AgitExe#C2	-1
payg_cas03.gat,0,0,0	duplicate(AgitExe)	AgitExe#C3	-1
payg_cas04.gat,0,0,0	duplicate(AgitExe)	AgitExe#C4	-1
payg_cas05.gat,0,0,0	duplicate(AgitExe)	AgitExe#C5	-1
//巴基力雷恩
prtg_cas01.gat,0,0,0	duplicate(AgitExe)	AgitExe#V1	-1
prtg_cas02.gat,0,0,0	duplicate(AgitExe)	AgitExe#V2	-1
prtg_cas03.gat,0,0,0	duplicate(AgitExe)	AgitExe#V3	-1
prtg_cas04.gat,0,0,0	duplicate(AgitExe)	AgitExe#V4	-1
prtg_cas05.gat,0,0,0	duplicate(AgitExe)	AgitExe#V5	-1