cf_getcookie.asp

支持多种播放器RealPlayer,MediaPlayer

<%
'乘风电影程序
'制作：乘　风
'QQ：178575
'E-Mail：[e-mail]
'开发网站：http://www.qqcf.com
'详细简介：http://www.qqcf.com/?action=list&list=cffilm
'上面有程序在线演示，安装演示，使用疑难解答，最新版本下载等内容
'因为这些内容可能时常更新，就没有放在程序里，请自己上网站上查看
'有完整版本的演示，包括如何实际整合Helix,Serv-u完全的实现在线播
'放和下载防盗链等
%>

<%
CFFilmUserCookie=Chkstr(Request.Cookies("CFFilmUserCookie"),1)

If Session("CFFilmUser")="" Then'Session不存在但cookie存在时，重新获得Session
 If CFFilmUserCookie<>"" Then
  Sql="Select UserName From CFFilm_User Where Cookies='"&CFFilmUserCookie&"'"
  Set Rs=Conn.Execute(Sql)
  If Not Rs.Eof Then
   Session("CFFilmUser")=Rs("UserName")
  Else
   Response.Cookies("CFFilmUserCookie")=""
   Response.Cookies("CFFilmUserCookie").Expires=Dateadd("n",-60,Now())
  End If
  Rs.Close()
 End If
End If

If Session("CFFilmUser")<>"" And CFFilmUserCookie="" Then'Session存在但cookie不存在时，重新写Cookie
  Sql="Select Cookies From CFFilm_User Where UserName='"&Session("CFFilmUser")&"'"
  Set Rs=Conn.Execute(Sql)
  If Not Rs.Eof Then
   Response.Cookies("CFFilmUserCookie")=Rs("Cookies")
   Response.Cookies("CFFilmUserCookie").expires=Dateadd("n",60,Now())
  Else
   Session("CFFilmUser")=""
  End If
  Rs.Close()
End If


CFFilmAdminCookie=Chkstr(Request.Cookies("CFFilmAdminCookie"),1)

If Session("CFFilmAdmin")="" Then 
 If CFFilmAdminCookie<>"" then   
  If RsSet("Cookies")=CFFilmAdminCookie Then Session("CFFilmAdmin")="ok"
 End If
End If


If Session("CFFilmAdmin")<>"" And CFFilmAdminCookie="" Then'Session存在但cookie不存在时，重新写Cookie
   Response.Cookies("CFFilmAdminCookie")=RsSet("Cookies")
   Response.Cookies("CFFilmAdminCookie").expires=Dateadd("n",60,Now())
End If
%>