frmlogin.frm

VB数据库设计的代码。需要根据自己的数据库再作调整

VERSION 5.00
Begin VB.Form frmLogin 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "登录"
   ClientHeight    =   1545
   ClientLeft      =   2835
   ClientTop       =   3480
   ClientWidth     =   3750
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   912.837
   ScaleMode       =   0  'User
   ScaleWidth      =   3521.047
   ShowInTaskbar   =   0   'False
   StartUpPosition =   2  '屏幕中心
   Begin VB.TextBox txtUserName 
      Height          =   345
      Left            =   1290
      TabIndex        =   1
      Top             =   135
      Width           =   2325
   End
   Begin VB.CommandButton cmdOK 
      Caption         =   "确定"
      Default         =   -1  'True
      Height          =   390
      Left            =   495
      TabIndex        =   4
      Top             =   1020
      Width           =   1140
   End
   Begin VB.CommandButton cmdCancel 
      Cancel          =   -1  'True
      Caption         =   "取消"
      Height          =   390
      Left            =   2100
      TabIndex        =   5
      Top             =   1020
      Width           =   1140
   End
   Begin VB.TextBox txtPassword 
      Height          =   345
      IMEMode         =   3  'DISABLE
      Left            =   1290
      PasswordChar    =   "*"
      TabIndex        =   3
      Top             =   525
      Width           =   2325
   End
   Begin VB.Label lblLabels 
      Caption         =   "用户名称(&U):"
      Height          =   270
      Index           =   0
      Left            =   105
      TabIndex        =   0
      Top             =   150
      Width           =   1080
   End
   Begin VB.Label lblLabels 
      Caption         =   "密码(&P):"
      Height          =   270
      Index           =   1
      Left            =   105
      TabIndex        =   2
      Top             =   540
      Width           =   1080
   End
End
Attribute VB_Name = "frmLogin"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private LoginSucceeded As Boolean


'***********************************************************************
'* 过程名：cmdCancel_Click
'* 功  能：放弃按钮单击事件响应
'* 参  数：
'* 版  本：2006.01.01 颜志军 初版
'***********************************************************************
Private Sub cmdCancel_Click()
    '设置全局变量为 false
    '不提示失败的登录
    LoginSucceeded = False
    Me.Hide
End Sub

'***********************************************************************
'* 过程名：cmdOK_Click
'* 功  能：确定按钮单击事件响应
'* 参  数：
'* 版  本：2006.01.01 颜志军 初版
'***********************************************************************
Private Sub cmdOK_Click()
    Dim userName As String
    Dim userPwd As String
    
    userName = Trim(txtUserName)
    userPwd = Trim(txtPassword)
    
    '检查正确的密码
    If CheckUser(userName, userPwd) Then
        LoginSucceeded = True
        Me.Hide
    Else
        MsgBox "无效的密码，请重试!", , "登录"
        txtPassword.SetFocus
        SendKeys "{Home}+{End}"
    End If
End Sub

'***********************************************************************
'* 函数名：CheckUser
'* 功  能：检查用户合法性
'* 参  数：String                   用户名
'*       ：String                   密码
'*       ：Boolean                  True 合法 False 不合法
'* 版  本：2006.01.01 颜志军 初版
'***********************************************************************
Private Function CheckUser(ByVal userName As String, ByVal userPwd As String) As Boolean
    '变量定义
    Dim userInfo As clsOpuser
    
    '取得操作者信息
    Set userInfo = New clsOpuser
    If userInfo.LoadByUserName(userName) = DbOpRecNoExist Then
        CheckUser = False
    ElseIf userInfo.userPwd <> userPwd Then
        CheckUser = False
    Else
        CheckUser = True
    End If
End Function

'***********************************************************************
'* 函数名：ShowDlg
'* 功  能：显示登录框
'* 参  数：clsOpuser                用户信息
'*       ：Boolean                  True 合法 False 不合法
'* 版  本：2006.01.01 颜志军 初版
'***********************************************************************
Public Function ShowDlg(ByRef opUser As clsOpuser) As Boolean
    '变量定义
    Dim userName As String
    Me.Show vbModal
    If LoginSucceeded Then
        ShowDlg = True
        '取得用户名
        userName = Trim(txtUserName)
        opUser.LoadByUserName userName
    Else
        ShowDlg = False
    End If
    Unload Me
End Function