mdlmerchandisekind.bas

VB数据库设计的代码。需要根据自己的数据库再作调整

Attribute VB_Name = "mdlMerchandiseKind"
Option Explicit

'***********************************************************************
'* 过程名：AppendMerchandiseKind
'* 功  能：追加新类别
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.03 颜志军 初版
'***********************************************************************
Public Sub AppendMerchandiseKind(ByRef lvListViewCtl As ListView)
    Dim opMerchandiseKind As clsOpMerchandisekind
    Set opMerchandiseKind = New clsOpMerchandisekind
    opMerchandiseKind.AppendNewMerchandisekind g_currentUser
    UpdateListViewInMerchandiseKind lvListViewCtl
End Sub

'***********************************************************************
'* 过程名：EditMerchandiseKind
'* 功  能：编辑商品类别信息
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.03 颜志军 初版
'***********************************************************************
Public Sub EditMerchandiseKind(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim currentSelMerchandiseKindString As String        '当前选择商品类别ID
    Dim currentSelMerchandiseKind As clsMerchandisekind  '当前选择商品类别
    Dim opMerchandiseKind As clsOpMerchandisekind        '商品类别操作对象
    
    '取得当前选择
    If lvListViewCtl.SelectedItem Is Nothing Then
         MsgBox "请选择要编辑的商品类别！", vbExclamation Or vbOKOnly, "警告"
    Else
        currentSelMerchandiseKindString = Trim(lvListViewCtl.SelectedItem.Text)
        Set currentSelMerchandiseKind = New clsMerchandisekind
        If currentSelMerchandiseKind.LoadByKindId(CInt(currentSelMerchandiseKindString)) = DbOpRecExist Then
            Set opMerchandiseKind = New clsOpMerchandisekind
            opMerchandiseKind.EditMerchandiseKind currentSelMerchandiseKind, g_currentUser
            lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.index
            UpdateListViewInMerchandiseKind lvListViewCtl
        Else
            MsgBox "读取商品类别信息失败！", vbExclamation Or vbOKOnly, "警告"
        End If
    End If
End Sub

'***********************************************************************
'* 过程名：RemoveMerchandiseKind
'* 功  能：删除商品种类
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.03 颜志军 初版
'***********************************************************************
Public Sub RemoveMerchandiseKind(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim currentSelMerchandiseKindString As String        '当前选择商品类别ID
    Dim currentSelMerchandiseKind As clsMerchandisekind  '当前选择商品类别
    Dim opMerchandiseKind As clsOpMerchandisekind        '商品类别操作对象
    Dim merchandiseSet As clsMerchandiseinfoSet          '商品集
    
    If Not lvListViewCtl.SelectedItem Is Nothing Then
        currentSelMerchandiseKindString = lvListViewCtl.SelectedItem.Text
        '检查该类下是否还有商品
        Set merchandiseSet = New clsMerchandiseinfoSet
        merchandiseSet.LoadSetByKindId currentSelMerchandiseKindString
        If merchandiseSet.Count > 0 Then
            MsgBox "该商品类别下还有商品，不能删除该类别！", vbExclamation Or vbOKOnly, "警告"
            Exit Sub
        End If
        
        '执行删除
        If MsgBox("删除ID为[" & currentSelMerchandiseKindString & "]的商品种类吗？", _
                vbQuestion Or vbYesNo, "询问") = vbYes Then
            Set currentSelMerchandiseKind = New clsMerchandisekind
            If currentSelMerchandiseKind.LoadByKindId(CInt(currentSelMerchandiseKindString)) = DbOpRecExist Then
                Set opMerchandiseKind = New clsOpMerchandisekind
                If opMerchandiseKind.RemoveMerchandiseKind(currentSelMerchandiseKind, g_currentUser) Then
                    lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.index
                    Exit Sub
                End If
            End If
            MsgBox "删除商品类别失败！", vbExclamation Or vbOKOnly, "警告"
        End If
    Else
        MsgBox "请先选择要删除的商品类别！", vbExclamation Or vbOKOnly, "警告"
    End If
End Sub

'***********************************************************************
'* 过程名：IniListViewInMerchandiseKind
'* 功  能：以商品种类列表初始化ListView
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.03 颜志军 初版
'***********************************************************************
Public Sub IniListViewInMerchandiseKind(ByRef lvListViewCtl As ListView)
    If g_listViewState = MERCHANDISEKINDLIST Then
        UpdateListViewInMerchandiseKind lvListViewCtl
    Else
        '变量定义
        Dim kindSet As clsMerchandisekindSet
        Dim merchandiseKind As clsMerchandisekind
        Dim curListItem As ListItem
        
        '取得商品类型集合
        Set kindSet = New clsMerchandisekindSet
        
        '清除现有显示
        lvListViewCtl.ColumnHeaders.Clear
        lvListViewCtl.ListItems.Clear
        
        '设定表头
        lvListViewCtl.ColumnHeaders.Add , "商品类别ID", "商品类别ID"
        lvListViewCtl.ColumnHeaders.Add , "商品类别名", "商品类别名"
        lvListViewCtl.ColumnHeaders.Add , "备注", "备注"
        
        '明细显示
        For Each merchandiseKind In kindSet
            Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(merchandiseKind.kindId))
            curListItem.SubItems(1) = merchandiseKind.kindName
            curListItem.SubItems(2) = merchandiseKind.remark
        Next
    End If
    g_listViewState = MERCHANDISEKINDLIST
End Sub

'***********************************************************************
'* 过程名：UpdateListViewInMerchandiseKind
'* 功  能：更新商品类别列表
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.03 颜志军 初版
'***********************************************************************
Public Sub UpdateListViewInMerchandiseKind(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim kindSet As clsMerchandisekindSet
    Dim merchandiseKind As clsMerchandisekind
    Dim curListItem As ListItem
    Dim iLoop As Integer
    
    '取得商品类型集合
    Set kindSet = New clsMerchandisekindSet
    
    '明细更新
    For Each merchandiseKind In kindSet
        For iLoop = 1 To lvListViewCtl.ListItems.Count
            If merchandiseKind.kindId = lvListViewCtl.ListItems.item(iLoop).Text Then
                GoTo CHECKAGAIN
            End If
        Next
        
        Set curListItem = lvListViewCtl.ListItems.Add(, , merchandiseKind.kindId)
        curListItem.SubItems(1) = merchandiseKind.kindName
        curListItem.SubItems(2) = merchandiseKind.remark
CHECKAGAIN:
    Next
End Sub