mdlsalemanage.bas

VB数据库设计的代码。需要根据自己的数据库再作调整

Attribute VB_Name = "MdlSaleManage"
Option Explicit

'***********************************************************************
'* 过程名：AppendNewDayReport
'* 功  能：锁售日报提交
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.05 颜志军 初版
'***********************************************************************
Public Sub AppendNewDayReport(ByRef lvListViewCtl As ListView)
    Dim appendDayReport As clsOpSubmitSalerecday
    Set appendDayReport = New clsOpSubmitSalerecday
    appendDayReport.AppendNewDayReport g_currentUser
    UpdateListViewInDayReport lvListViewCtl
End Sub

'***********************************************************************
'* 过程名：EditDayReport
'* 功  能：编辑日报
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.05 颜志军 初版
'***********************************************************************
Public Sub EditDayReport(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim currentSelDayReportId As String         '当前选择日报记录ID
    Dim currentSelDayReport As clsSalerecDay    '当前选择日报
    Dim opDayReport As clsOpSubmitSalerecday    '日报操作对象
    
    '取得当前选择
    If lvListViewCtl.SelectedItem Is Nothing Then
         MsgBox "请选择要编辑的日报条目！", vbExclamation Or vbOKOnly, "警告"
    Else
        currentSelDayReportId = Trim(lvListViewCtl.SelectedItem.Text)
        Set currentSelDayReport = New clsSalerecDay
        If currentSelDayReport.LoadById(CInt(currentSelDayReportId)) = DbOpRecExist Then
            Set opDayReport = New clsOpSubmitSalerecday
            opDayReport.EditDayReport currentSelDayReport, g_currentUser
            lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
            UpdateListViewInDayReport lvListViewCtl
        Else
            MsgBox "读取日报信息失败！", vbExclamation Or vbOKOnly, "警告"
        End If
    End If
End Sub

'***********************************************************************
'* 过程名：RemoveDayReport
'* 功  能：删除日报
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.05 颜志军 初版
'***********************************************************************
Public Sub RemoveDayReport(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim currentSelDayReportId As String         '当前选择日报记录ID
    Dim currentSelDayReport As clsSalerecDay    '当前选择日报
    Dim opDayReport As clsOpSubmitSalerecday    '日报操作对象
    
    If Not lvListViewCtl.SelectedItem Is Nothing Then
        currentSelDayReportId = lvListViewCtl.SelectedItem.Text
        If MsgBox("删除ID为[" & currentSelDayReportId & "]的日报条目吗？", vbQuestion Or _
                vbYesNo, "询问") = vbYes Then
            Set currentSelDayReport = New clsSalerecDay
            If currentSelDayReport.LoadById(CInt(currentSelDayReportId)) = DbOpRecExist Then
                Set opDayReport = New clsOpSubmitSalerecday
                If opDayReport.RemoveDayReport(currentSelDayReport, g_currentUser) Then
                    lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
                    Exit Sub
                End If
            End If
            MsgBox "删除日报条目失败！", vbExclamation Or vbOKOnly, "警告"
        End If
    Else
        MsgBox "请先选择要删除的日报条目！", vbExclamation Or vbOKOnly, "警告"
    End If
End Sub

'***********************************************************************
'* 过程名：IniListViewInDayReport
'* 功  能：以日报列表初始化ListView
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.05 颜志军 初版
'***********************************************************************
Public Sub IniListViewInDayReport(ByRef lvListViewCtl As ListView)
    If g_listViewState = DAYREPORTLIST Then
        UpdateListViewInDayReport lvListViewCtl
    Else
        '变量定义
        Dim dayReportSet As clsSalerecDaySet
        Dim dayReport As clsSalerecDay
        Dim curListItem As ListItem
        
        '取得日报集合
        Set dayReportSet = New clsSalerecDaySet
        If g_currentUser.shopId > 1 Then
            dayReportSet.LoadSetByShopId g_currentUser.shopId
        End If
        
        '清除现有显示
        lvListViewCtl.ColumnHeaders.Clear
        lvListViewCtl.ListItems.Clear
        
        '设定表头
        lvListViewCtl.ColumnHeaders.Add , "日报ID", "日报ID"
        lvListViewCtl.ColumnHeaders.Add , "店名", "店名"
        lvListViewCtl.ColumnHeaders.Add , "商品", "商品"
        lvListViewCtl.ColumnHeaders.Add , "日期", "日期"
        lvListViewCtl.ColumnHeaders.Add , "锁售数量", "锁售数量"
        
        '明细显示
        For Each dayReport In dayReportSet
            Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(dayReport.recid))
            curListItem.SubItems(1) = dayReport.shopName
            curListItem.SubItems(2) = dayReport.merchandiseName
            curListItem.SubItems(3) = CStr(dayReport.saledate)
            curListItem.SubItems(4) = CStr(dayReport.merchandiseCount)
        Next
    End If
    g_listViewState = DAYREPORTLIST
End Sub

'***********************************************************************
'* 过程名：UpdateListViewInDayReport
'* 功  能：更日报列表
'* 参  数：ListView                 列表控件
'* 版  本：2006.01.05 颜志军 初版
'***********************************************************************
Public Sub UpdateListViewInDayReport(ByRef lvListViewCtl As ListView)
    '变量定义
    Dim dayReportSet As clsSalerecDaySet
    Dim dayReport As clsSalerecDay
    Dim curListItem As ListItem
    Dim iLoop As Integer
    
    '取得日报集合
    Set dayReportSet = New clsSalerecDaySet
    If g_currentUser.shopId > 1 Then
        dayReportSet.LoadSetByShopId g_currentUser.shopId
    End If
    
    '明细更新
    For Each dayReport In dayReportSet
        For iLoop = 1 To lvListViewCtl.ListItems.Count
            If dayReport.recid = lvListViewCtl.ListItems.Item(iLoop).Text Then
                GoTo CHECKAGAIN
            End If
        Next
        
        Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(dayReport.recid))
        curListItem.SubItems(1) = dayReport.shopName
        curListItem.SubItems(2) = dayReport.merchandiseName
        curListItem.SubItems(3) = CStr(dayReport.saledate)
        curListItem.SubItems(4) = CStr(dayReport.merchandiseCount)
CHECKAGAIN:
    Next
End Sub