16f84.asm

pic系列单片机得控制程序 主要进行温度采集和转换控制

	call	SHT11GetByte
	movf	SHT11Byte,W
	movwf	hi
	call	SendAck		;acknowledge the byte

	; get the least sig byte:

	call	SHT11GetByte
	movf	SHT11Byte,W
	movwf	lo
	call	SendAck		;acknowledge the byte

	call	SHT11GetByte	; gets the checksum (not needed)

	; Send the data as ASCII:
	call	SendAsciiNum

	; Send the terminating CR and LF:
	call	SendCRLF

SHT11TXRXDone
	return

;------end SHT11TXRX--------------------------------------------------

;------begin SHT11GetByte---------------------------------------------
;
; Gets a byte of data from the SHT11. Assumes that the data
; is ready to be sent by the SHT11. Also assumes that _SHT11_DAT has
; been set to input. Also assumes that _SHT11_SCK has been set to low.
; Returns the byte in SHT11Byte.

SHT11GetByte
	; clear SHT11Byte:

	clrf	SHT11Byte

	; set counter to get eight bits

	movlw	8
	movwf	counter

SHT11GetByteLoop
	bsf	PORTA,_SHT11_SCK	;set the clock high to get the next bit
	btfss	PORTA,_SHT11_DAT	;is the next bit a one?
	goto	SHT11GetZeroBit	;no--it's a zero
	bsf	SHT11Byte,0	;if it's a one, set the LSB in SHT11Byte
	goto	SHT11GotBit

SHT11GetZeroBit
	bcf	SHT11Byte,0	;set the LSB to zero in SHT11Byte

SHT11GotBit
	bcf	PORTA,_SHT11_SCK	;set the clock line low again.
	decfsz	counter,F
	goto	SHT11GetNextBit
	goto	SHT11GetByteDone

SHT11GetNextBit
	rlf	SHT11Byte,F	;move the bits over to get the next bit
	goto	SHT11GetByteLoop

SHT11GetByteDone

	return

;------end SHT11GetByte-----------------------------------------------

;------begin SendAck-------------------------------------------------
;
; send the ack. Set the data line as an output:

SendAck
	bsf	STATUS,RP0	;switch to bank 1
	bcf	TRISA,_SHT11_DAT	;make Port A data line an output
	bcf	STATUS,RP0	;switch back to bank 0

	; now send the ack. Take the data line low.

	bcf	PORTA,_SHT11_DAT
	bsf	PORTA,_SHT11_SCK
	bcf	PORTA,_SHT11_SCK

	; now make the data line an input again.

	bsf	STATUS,RP0	;switch to bank 1
	bsf	TRISA,_SHT11_DAT	;make Port A data line an input
	bcf	STATUS,RP0	;switch back to bank 0

	return

;------end SendAck---------------------------------------------------

;------begin SendErrorCode-------------------------------------------
;
; send error code back to PC. Error code is 'e' plus a digit. Load
; ASCII value of digit into 'digit' register before calling.

SendErrorCode
	movlw	'e'
	movwf	TXChar
	call	SendAChar
	movf	digit,W
	movwf	TXChar
	call	SendAChar
	call	SendCRLF
	return
	
;------end SendErrorCode---------------------------------------------

;------begin TellTemperature-----------------------------------------

;This subroutine is called when the 't' command is received. Calls
;SHT11TXRX.

TellTemperature

	movlw	3
	movwf	SHT11Byte
	call	SHT11TXRX

	goto	MainLoop

;------end TellTemperature-------------------------------------------

;------begin TellHumidity--------------------------------------------

;This subroutine is called when the 'h' command is received. Calls
;SHT11TXRX.

TellHumidity

	movlw	5
	movwf	SHT11Byte
	call	SHT11TXRX

	goto	MainLoop

;------end TellHumidity----------------------------------------------

;------begin SendCRLF------------------------------------------------
;
; Send the terminating CR and LF:

SendCRLF
	movlw	13
	movwf	TXChar
	call	SendAChar
	movlw	10
	movwf	TXChar
	call	SendAChar
	return

;------end SendCRLF--------------------------------------------------

;------begin SendAsciiNum--------------------------------------------
;
; load lo, hi with 16 bit unsigned num to send

SendAsciiNum
	dodigit	10000
	movf	digit,W
	movwf	TXChar
	call	SendAChar
	dodigit	1000
	movf	digit,W
	movwf	TXChar
	call	SendAChar
	dodigit	100
	movf	digit,W
	movwf	TXChar
	call	SendAChar
	dodigit	10
	movf	digit,W
	movwf	TXChar
	call	SendAChar
	movf	lo,w		; ls byte is already correct
	addlw	'0'		; convert to ascii
	movwf	TXChar
	call	SendAChar
	return			; done

; "dosub" is called by the "dodigit" macro defined above.
; Subtract the number in shi/slo from hi/lo until the result
; is negative, incrementing the ascii equivelent each time.

dosub	movlw	'0'-1
	movwf	digit
moresub	incf	digit,F		; increment ASCII character
	movf	slo,w		; subtract current power of 10
	subwf	lo,f
	movf	shi,w
	btfss	STATUS,C
	addlw	1
	subwf	hi,f
	btfsc	STATUS,C	; any carry?
	goto	moresub		; no, keep subtracting

	movf	slo,w		; reverse the last subtraction
	addwf	lo,f
	movf	shi,w
	btfsc	STATUS,C
	addlw	1
	addwf	hi,f
	return

;------end SendAsciiNum----------------------------------------------

;------begin GetWindSpeed-------------------------------------------
;
; Count the number of milliseconds between transitions and return.

GetWindSpeed

; First, zero out the counters:

	movlw	0
	movwf	lo
	movwf	hi

; Next, save the value of RB1 so we can detect when a transition
; occurs:

	movf	PORTB,W
	andlw	_WIND_IN_MASK
	movwf	RegSave

; Here is where we count pulses for a specified period of time (3 sec).
; Use nested loops again.

StartWindCount

	movlw	200
	movwf	counter

WindCountLoop
	movlw	15
	movwf	counter2

WindCountInnerLoop
	call	WaitMS
	call	CountWind
	decfsz	counter2,F
	goto	WindCountInnerLoop

	decfsz	counter,F
	goto	WindCountLoop

	return

;------end GetWindSpeed----------------------------------------------

;------begin CountWind-----------------------------------------------
;
; CountWind checks for a transition on the _WIND_IN line and 
; increments the 16-bit lo/hi counter for each transition. After a
; transition it saves the new state of the _WIND_IN line in RegSave
; for the next test.

CountWind

	;did a transition occur?

	movf	PORTB,W
	andlw	_WIND_IN_MASK
	subwf	RegSave,W
	btfsc	STATUS,Z
	return

	;yes. increment the counter

	incfsz	lo,F
	goto	SaveWindReg
	incf	hi,F

SaveWindReg

	;save the new state of the line

	movf	PORTB,W
	andlw	_WIND_IN_MASK
	movwf	RegSave

	return

;------end CountWind-------------------------------------------------

;------begin TellWindSpeed-------------------------------------------
;
; call GetWindSpeed and then send the result back to the PC.

TellWindSpeed
	call	GetWindSpeed
	call	SendAsciiNum
	call	SendCRLF
	goto	MainLoop

;------end TellWindSpeed---------------------------------------------

;------begin TellWindSpeedCW-----------------------------------------
;
; call GetWindSpeed and then send the result in CW via the LED.

TellWindSpeedCW

	; wait until button is released:

	btfss	PORTB,_PBUTTON
	goto	TellWindSpeedCW

	;get the wind speed and send it in CW via the LED.

	call	GetWindSpeed
	call	SendCWAsciiNum
	goto	MainLoop

;------end TellWindSpeedCW-------------------------------------------

;------begin ReportVersion-------------------------------------------

; send a string with the version in it. The string comes from EEPROM
; memory and is null-terminated. The null terminator is not sent. The
; protocol dictates that the string sent is terminated by a CR, which
; is sent. This subroutine is called when the 'v' command is received.

ReportVersion
	bcf	STATUS,RP0
	clrf	EEADR		;the string we want starts at the 
				;beginning of EEPROM memory.

GetNextVersionChar
	bsf	STATUS,RP0
	bsf	EECON1,RD
	bcf	STATUS,RP0
	movf	EEDATA,W
	btfsc	STATUS,Z	;if the character in W is null, don't
                                ;send any more.
	goto	MainLoop

	movwf	TXChar
	call	SendAChar
	incf	EEADR,F
	goto	GetNextVersionChar

;------end ReportVersion---------------------------------------------

;------begin Idle----------------------------------------------------
;
; Idle should be called whenever the chip is waiting for something
; to happen (waiting for a character to be sent or received, for
; example). Here, Idle checks to see if the button has been pressed.
; if so, it calls TellWindSpeedCW to get the wind speed and send it
; in CW via the LED.

Idle
	; is the pushbutton line low?
	btfss	PORTB,_PBUTTON
	goto	TellWindSpeedCW	;yes--tell the wind speed via CW to LED

	return

;------end Idle------------------------------------------------------

;------Main Program--------------------------------------------------

Main

; set up the ports as inputs and outputs as needed.

	bsf	STATUS,RP0	;switch to bank 1
	movlw	0xFF
	movwf	TRISB		;make Port B input
	movlw	0x00
	movwf	TRISA		;make Port A output
	bcf	STATUS,RP0

	clrf	PORTA

; set the _INVCW line high to turn off the LED.

	bsf	PORTA,_INVCW

; set default for the CW speed:

	movlw	0x50
	movwf	DitLen
	movlw	0x50
	movwf	DitWordLen

	call	SerSetup	;set up serial comm routines & int.

; this main program simply waits for characters to be received, then
; calls the handler for the command indicated by the received character.

MainLoop
	call	GetAChar	;wait for a character

	movf	RXBuff,W	;move the rx char into W
	sublw	't'		;compare with 't' character
	btfsc	STATUS,Z
	goto	TellTemperature	;if t, report the temperature

	movf	RXBuff,W	;move the rx char into W
	sublw	'h'		;compare with 'h' character
	btfsc	STATUS,Z
	goto	TellHumidity	;if h, report the humidity

	movf	RXBuff,W	;move the rx char into W
	sublw	'w'		;compare with 'w' character
	btfsc	STATUS,Z
	goto	TellWindSpeed	;if w, report the temperature

	movf	RXBuff,W	;move the rx char into W
	sublw	'v'		;compare with 'v' character
	btfsc	STATUS,Z
	goto	ReportVersion	;if v, report the version number

	goto	MainLoop

;------begin Table---------------------------------------------------
;
; This is a lookup table for use in getting the right bit pattern
; to send CW based on the ASCII value of the character to be sent.

	org	0x380		;begin the table on a page boundary
Table
	addwf	PCL,F		;compute the GOTO
	retlw	_Char_0
	retlw	_Char_1
	retlw	_Char_2
	retlw	_Char_3
	retlw	_Char_4
	retlw	_Char_5
	retlw	_Char_6
	retlw	_Char_7
	retlw	_Char_8
	retlw	_Char_9
	
;------end Table-----------------------------------------------------

;------Version EEPROM------------------------------------------------

	org	0x2100
	de	"WxPIC v0.5g (c) 2003 by NK0E",0x0D,0x0A,0x00	; Version 0.5g
	end