function2.asp

asp开发 asp开发 asp开发 asp开发

<%
'**********************************************
'函数文件二，专门存放各种函数
'**********************************************

'该函数可以将二进制字符串转换成文本字符串
Function BinaryToString(thedata) 
	'定义几个变量供使用,其中strNow表示正在处理的字符，strTemp用来保存已经处理完毕的字符串
	'flag是一个标志，False表示前一个字符不是中文，Ture表示前一个字符是中文
	Dim strNow,strTemp,flag,I
	flag=False 
	'利用循环依次转换每一个字符
	For I=1 To LenB(thedata)
		'因为一个中文字符包括两个字节，如果flag=True，表示前一个字符是中文，所以要跳过这个字符，不过要将中文标志flag=False。
		'如果flag=False，表示前一个字符不是中文，就需要将其转换
		If flag=True Then 
			flag=False 
		Else 
			'取出当前字符
			strNow=MidB(thedata,I,1)
			'如果AscB(strNow)>127，表示这是一个中文字符，<127，表示不是中文。
			If AscB(strNow) > 127 Then 
				'如果这是一个中文字符，首先需要把当前字节和下一个字节调换位置，然后用AscW返回该字符对应的ASCII码。
				'随之，用Chr函数返回该ASCII码对应的文本
				'最后，还要把中文标志设为True
				strTemp=strTemp & Chr(AscW(MidB(thedata,I+1,1) & strNow)) 
				flag=True 
			Else 
				'如果不是中文，直接用AscB返回该字符对应的ASCII码，然后用Chr函数返回该ASCII码对应的文本
				strTemp=strTemp & Chr(AscB(strNow)) 
			End If 
		End If 
	Next 
	BinaryToString=strTemp                   '返回函数值
End Function 

'该函数用来处理客户提交的文本
Function myReplace(myString)
	myString=Replace(myString,"&","&amp;")         '替换&为字符实体&amp;
	myString=Replace(myString,"<","&lt;")          '替换<
	myString=Replace(myString,">","&gt;")          '替换>
	myString=Replace(myString,chr(13),"<br>")      '替换回车符  
	myString=Replace(myString,chr(32),"&nbsp;")    '替换空格符
	myString=Replace(myString,chr(9)," &nbsp; &nbsp; &nbsp; &nbsp;")     '替换Tab缩进符
	myString=Replace(myString,chr(39),"&acute;")       '替换单引号
	myString=Replace(myString,chr(34),"&quot;")        '替换双引号
	myReplace=myString                             '返回函数值
End Function
%>