回转窑.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

/TITLE,THE ANALYSIS OF ROTARY KILN  
/FILNAME,ROTARYKILN 
*AFUN,DEG                           !   
!*  
*SET,BR,0.65                               !
*SET,R1,2.1                                !
*SET,R2,2.33                             !  
*SET,B1,0.78                             !  
*SET,B2,0.312                            !  
*SET,R1T,0.7                             !  
*SET,R2T,0.6
*SET,R3,0.455   
*SET,R4,0.325   
*SET,R5,0.2 
*SET,R6,0.06
*SET,R7,0.200184                         !  
*SET,Q,3615992                           !  
*SET,PI,3.1415926   
*SET,RC,2.215   
*SET,KVAL,0.876376                       !常数K   
*SET,BVAL,54                             !  
!*  
/PREP7                              !   
!====指定材料常数==== 
ET,1,SOLID95                        !   
ET,2,PLANE42
MP,EX,1,210E9                       !   
MP,NUXY,1,0.3   
MP,DENS,1,7800                      !   
!====创建托轮并网格划分====
CYL4,,,R2T,0,R1T,45/2,B1/2             !1/16
CYL4,,,R5,0,R4,45/2,B1/2               !1/16
CYL4,,,R4,0,R2T,45/3,B2/2   
CYL4,,,R4,45/3,R2T,45/2,B1/2
WPOFFS,R3                          !
CYL4,,,,,R6,360,B1  
VSBV,3,5
WPCSYS,-1,0                         !   
VGLUE,ALL                          !
!   
LESIZE,14,,,6                         ! 
LESIZE,4,,,6
LESIZE,56,,,2   
LESIZE,55,,,2   
LESIZE,71,,,4   
LESIZE,67,,,4   
LESIZE,15,,,3   
LESIZE,13,,,3   
LESIZE,25,,,6   
LESIZE,37,,,6   
LESIZE,3,,,2
LESIZE,1,,,2
LESIZE,75,,,2   
LESIZE,74,,,2   
LESIZE,52,,,7   
LESIZE,51,,,7   
!   
LSEL,S,LINE,,37 
LSEL,A,LINE,,67,71,4
LCCAT,ALL   
LSEL,S,LINE,,51,52  
LCCAT,ALL   
LSEL,S,LINE,,56,71,15   
LCCAT,ALL   
LSEL,S,LINE,,55,67,12   
LCCAT,ALL   
MSHKEY,1                          ! 
MSHAPE,0                          ! 
ASEL,S,LOC,Z,0  
TYPE,2  
AMESH,ALL   
ALLS
VSEL,U,VOLU,,8  
LESIZE,24,,,5                        !  
EXTOPT,ACLEAR,1                   ! 
TYPE,1  
VSWEEP,ALL  
VSEL,S,VOLU,,8  
EXTOPT,ACLEAR,1 
EXTOPT,ESIZE,2  
VSWEEP,ALL  
ALLSEL,ALL  
NUMMRG,ALL                       !  
NUMCMP,ALL                       !  
!   
LSEL,S,LCCAT
LDEL,ALL
!   
VSYMM,Y,ALL 
CSYS,1  
VGEN,8,ALL,,,,45
ALLSEL,ALL  
NUMMRG,ALL  
NUMCMP,ALL  
!====创建轴承并网格划分====
CYL4,,,,,R7,90,(2*B1)/3                  !1/4   
LSEL,S,LOC,Z,(2*B1)/3   
LSEL,R,LOC,X,R7 
LESIZE,ALL,,,6  
ASEL,S,LOC,Z,(2*B1)/3   
TYPE,2  
AMESH,ALL   
TYPE,1  
LSEL,S,LOC,X,0  
LESIZE,ALL,,,8  
VSEL,S,LOC,X,0,R7   
EXTOPT,ACLEAR,1 
VSWEEP,ALL  
CSYS,0  
VSYMM,Y,ALL 
VSYMM,X,ALL 
ALLS
NUMMRG,ALL  
NUMCMP,ALL  
!====创建滚圈并网格划分=====   
CSYS
WPOFFS,-(R2+R1T)*COS(60),(R2+R1T)*SIN(60)     ! 
CYL4,,,R1,-90,R2,90,BR/2                         !生成1/4 
CSWPLA,11,1                                   !在滚圈中心处建立11   
CSYS,11 
VSEL,S,LOC,X,0,R2                             ! 
WPROTA,,90  
WPROTA,,,-30
VSBW,ALL
WPROTA,,,66 
VSBW,ALL
!   
CSYS,11 
LSEL,S,LOC,X,,R1                              !-90度到-30 
LSEL,R,LOC,Y,-89,-31
LESIZE,ALL,,,20 
LSEL,S,LOC,X,0,R1                             !-30度到36  
LSEL,R,LOC,Y,-29,35 
LESIZE,ALL,,,20 
LSEL,S,LOC,X,0,R1                             !36度到90   
LSEL,R,LOC,Y,37,89  
LESIZE,ALL,,,10 
LSEL,S,LOC,X,R1+0.001,R2-0.001                 !
LSEL,R,LOC,Y,90 
LESIZE,ALL,,,3  
LSEL,S,LOC,Z,0.001,BR/2-0.001                  !
LSEL,R,LOC,Y,90 
LESIZE,ALL,,,5  
MSHKEY,1
MSHAPE,0
TYPE,2  
ASEL,S,LOC,X,0,R2   
ASEL,R,LOC,Z,0  
AMESH,ALL   
EXTOPT,ACLEAR,1 
TYPE,1  
VSWEEP,ALL  
ALLSEL,ALL  
!====接触单元生成===  
ET,3,170
ET,4,174
ET,5,174
MP,MU,2,0                              !
MP,MU,3,0.2                             !   
KEYOPT,4,9,2                               !
KEYOPT,5,5,1                               !
!   
TYPE,3  
R,3 
REAL,3  
MAT,2   
CSYS,1  
ASEL,S,LOC,X,R7 
NSLA,S,1
ESLN,S,0
ESURF   
!   
TYPE,4  
REAL,3  
MAT,2   
ASEL,S,LOC,X,R5 
NSLA,S,1
ESLN,S,0
ESURF   
ALLSEL  
!   
TYPE,3  
MAT,3   
R,4 
REAL,4  
CSYS,1  
ASEL,S,LOC,X,R1T
ASEL,R,LOC,Y,90,150 
NSLA,S,1
ESLN,S,0
ESURF   
!   
TYPE,5  
MAT,3   
REAL,4  
CSYS,11 
VSEL,S,LOC,X,0,R2   
ASLV,S  
ASEL,R,LOC,X,R2 
ASEL,R,LOC,Y,-89,-31
NSLA,S,1
ESLN,S,0
ESURF   
ALLSEL  
NUMCMP,NODE 
NUMCMP,ELEM 
!*  
FINI
/SOLU   
!   
CSYS,1  
ASEL,S,LOC,Z,0  
DA,ALL,SYMM 
ASEL,S,LOC,Z,(2*B1)/3   
DA,ALL,UX   
DA,ALL,UY   
WPCSYS,,11  
CSWPLA,12                    !创建12  
CSYS,12 
ASEL,S,LOC,X,0  
DA,ALL,SYMM 
ALLSEL,ALL  
!   
WPCSYS,,12  
WPROTA,-90  
CSWPLA,13   
!   
*SET,_FNCNAME,'PFUN'
*DIM,_FNC_C1,,1 
*DIM,_FNC_C2,,1 
*DIM,_FNC_C3,,1 
*SET,_FNC_C1(1),3615992 
*SET,_FNC_C2(1),0.876376
*SET,_FNC_C3(1),2.215   
*SET,_FNCCSYS,13
! /INPUT,PFUN.FUNC  
*DIM,%_FNCNAME%,TABLE,6,13,1,,,,%_FNCCSYS%  
!   
! BEGIN OF EQUATION: Q*(KVAL+{X}/SQRT({X}**2+{Y}**2))/(PI*RC)   
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0 
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), 0.0 
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 2, 0, 0, 2  
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 2, 17, -1
*SET,%_FNCNAME%(0,3,1),   0, -1, 0, 2, 0, 0, 3  
*SET,%_FNCNAME%(0,4,1), 0.0, -3, 0, 1, 3, 17, -1
*SET,%_FNCNAME%(0,5,1), 0.0, -1, 0, 1, -2, 1, -3
*SET,%_FNCNAME%(0,6,1), 0.0, -1, 16, 1, -1, 0, 0
*SET,%_FNCNAME%(0,7,1), 0.0, -2, 0, 1, 2, 4, -1 
*SET,%_FNCNAME%(0,8,1), 0.0, -1, 0, 1, 18, 1, -2
*SET,%_FNCNAME%(0,9,1), 0.0, -2, 0, 1, 17, 3, -1
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 3.14159265358979310, 0, 0, 19  
*SET,%_FNCNAME%(0,11,1), 0.0, -3, 0, 1, -1, 3, 19   
*SET,%_FNCNAME%(0,12,1), 0.0, -1, 0, 1, -2, 4, -3   
*SET,%_FNCNAME%(0,13,1), 0.0, 99, 0, 1, -1, 0, 0
! END OF EQUATION: Q*(KVAL+{X}/SQRT({X}**2+{Y}**2))/(PI*RC) 
ASEL,S,AREA,,386,396,10 
SFA,ALL,,PRESS,%PFUN%   
ANTYPE,STATIC   
ACEL,,9.8   
OUTRES,BASIC,ALL
AUTOTS,ON   
NROPT,FULL  
NSUBST,8,16 
ALLSEL,ALL  
/STATUS,SOLU
!*  
solve   
SAVE