📄 ylrq.txt
字号:
FINISH
/CLEAR
/TITLE,YLRQ
/FILN,E653
!定义材料参数,单位为国际单位制
*AFUN,DEG ! 激活角度单位制
!模型参数
*SET,DI,3660E-3 ! 筒体内径
*SET,L,43000E-3 ! 鞍座间跨度
*SET,TN,26E-3 ! 筒体公称厚度
*SET,A,6860E-3 ! 鞍座中心至切线的距离
*SET,B,455E-3 ! 鞍座宽度
*SET,THETA,135 ! 鞍座包角
*SET,C,762E-3 ! 垫板宽度
*SET,TD,40E-3 ! 垫板厚度
*SET,H1,500E-3 ! 鞍座高H1
*SET,H2,1500E-3 ! 鞍座高H2
*SET,H3,1750E-3 ! 鞍座跨度
!材料参数
*SET,DENSITY,7850 ! 材料密度
*SET,EXX,2.01E11 ! 材料弹性模量
*SET,PRXY,0.3 ! 材料泊松比
*SET,P1,1E6 ! 均布内压
!************************
!*******前处理***********
!************************
/PREP7
!定义单元及材料属性
ET,1,SOLID95 ! 定义95号单元
MP,EX,1,EXX ! 定义弹性模量
MP,NUXY,1,PRXY ! 定义泊松比
MP,DENS,1,DENSITY ! 定义密度
!创建几何模型
CYLIND,DI/2,DI/2+TN,0,L/2,-90,90 ! 创建筒体
SPHERE,DI/2+TN,DI/2,-90,90, ! 创建封头
VSBW,ALL ! 采用工作平面切分体
VDELE,4, , ,1 ! 删除多余的体积，得到封头
CYLIND,DI/2+TN,DI/2+TN+TD,A-C/2,A+C/2,-90,-90+THETA/2 ! 创建垫板
WPOFF,0,0,A-B/2 ! 将工作平面平移至鞍座角点
BLC4,0,-DI/2-TN-TD-H1,H3,H2,B ! 创建鞍座
VPTN,ALL ! 体互分
ALLS ! 全选择
LGLUE,ALL ! 粘合各线
VDELE,5,,,1 ! 删除多余的体
CYLIND,0,DI/4,0,-DI*4,-90,90 ! 创建筒体
VPTN,ALL ! 体互分
VDELE,2,3,1,1 ! 删除多余体及其附属
!采用工作平面剖分体
WPROT,0,90,0 ! 旋转工作平面
VSEL,S,VOLU,,4,5,1, ! 选中封头
VSBW,ALL ! 采用工作平面切分封头
ALLSEL ! 全选择
WPROT,0,-90,0 ! 旋转工作平面
KWPAVE,20 ! 将工作平面定位于关键点20
VSBW,ALL ! 采用工作平面切分体
KWPAVE,22 ! 将工作平面定位于关键点22
VSBW,ALL ! 采用工作平面切分体
KWPAVE,27 ! 将工作平面定位于关键点27
VSBW,ALL ! 采用工作平面切分体
KWPAVE,31 ! 将工作平面定位于关键点31
VSBW,ALL ! 采用工作平面切分体
WPROT,0,0,90 ! 旋转工作平面
KWPAVE,43 ! 将工作平面定位于关键点43
VSBW,9 ! 采用工作平面切分支撑部
VGLUE,ALL ! 粘接体
!创建组件,方便选择
VSEL,S,VOLU,,14,17,3
VSEL,A,VOLU,,6,16,10
CM,INTANK,VOLU ! 创建连接处桶体内壁组件
VSEL,S,VOLU,,13,15,2
CM,BACKSTOP,VOLU ! 创建鞍座组件
VSEL,S,VOLU,,5,7,2
VSEL,A,VOLU,,10,12,2
CM,GASKET,VOLU ! 创建垫板组件
VSEL,S,VOLU,,1,2,1
VSEL,A,VOLU,,3,8,5
CM,CLOSE,VOLU ! 创建封头组件
VSEL,S,VOLU,,4,11,7
CM,TANK,VOLU ! 创建压力容器桶体组件
!划分网格
ALLSEL ! 全选择
CMSEL,S,INTANK ! 选中连接处桶体内壁组件
ESIZE,0.02 ! 设定单元大小
VSWEEP,ALL ! 映射网格划分
CMSEL,S,GASKET ! 选中垫板组件
ESIZE,0.02 ! 设定单元大小
VSWEEP,ALL ! 映射网格划分
CMSEL,S,BACKSTOP ! 选中鞍座组件
ESIZE,0.06 ! 设定单元大小
VSWEEP,ALL ! 映射网格划分
ESIZE,0.2 ! 设定单元大小
CMSEL,S,CLOSE ! 选中封头组件
VSWEEP,ALL ! 映射网格划分
CMSEL,S,TANK ! 选中压力容器桶体组件
ESIZE,0.4 ! 设定单元大小
VSWEEP,ALL ! 映射网格划分
ALLSEL ! 全选择
WPCSYS,-1,0 ! 转换到原始坐标系
LOCAL,11,0,0,0,L/2, ! 创建局部坐标系
CSYS,11 ! 激活局部坐标系
VSYMM,Z,ALL, , , ,0,0 ! 镜像
NUMMRG,ALL ! 合并
NUMCMP,ALL ! 压缩
FINISH
!************************
!*******加载与求解*******
!************************
/SOLU
ALLSEL
ACEL,0,9.8,0, ! 施加重力加速度
!*********注意，ANSYS中施加的重力为惯性力，其加速度方向与实际重力相反*************
NSEL,S,LOC,Z,0,L
NSEL,R,LOC,Y,-DI/2-TN-TD-H1 ! 选中前端鞍座底面
D,ALL,ALL ! 施加固定约束
ALLSEL
NSEL,S,LOC,Z,-L,0
NSEL,R,LOC,Y,-DI/2-TN-TD-H1 ! 选中后端鞍座底面
D,ALL,UY,0 ! 固定Y方向约束
ALLSEL
NSEL,S,LOC,X,0 ! 选中对称面上所有节点
DSYM,SYMM,X, ! 施加对称位移约束
CSYS,0 ! 激活笛卡尔坐标系
LSEL,S,LOC,Z,0,L ! 选中除封头之外的容器桶体及鞍座部分线段
CSYS,1 ! 激活极坐标系
LSEL,R,LOC,X,0,DI/2 ! 选中容器桶体内壁线段
ASLL,S,1 ! 选中筒体内壁面
ASEL,A,AREA,,10,11,1
ASEL,A,AREA,,28,29,1
ASEL,A,AREA,,92,118,26
ASEL,A,AREA,,83,86,3 ! 选中桶体内壁及封头内表面
NSLA,S,0 ! 选中依附于内表面的所有节点
SF,ALL,PRES,P1 ! 施加均布内压
SF,ALL,PRES,%P2% ! 施加静水压力
ALLSEL ! 全选择
SOLVE ! 求解
FINISH
!************************
!*******后处理***********
!************************
/POST1
!*************容器整体分析******************************
PLNSOL,S,EQV,0,1 ! 显示等效应力分布
PLNSOL,U,Y,2,1 ! 显示Y向位移
!*************容器局部分析******************************
RSYS,1 ! 激活结果坐标系为柱坐标系
ALLSEL ! 全选择
PLNSOL,S,SY,0,1 ! 显示周向应力分布
CMSEL,S,GASKET ! 选中垫板组件
CMSEL,A,BACKSTOP ! 选中鞍座组件
ESLV,S ! 选择附属于垫板+鞍座体积组件上的单元
PLNSOL,S,SY,0,1 ! 显示周向应力分布
!**************应力评定**********************************
CSYS,0 ! 激活笛卡儿坐标系
RSYS,0 ! 激活笛卡尔结果坐标系
ALLSEL ! 全选择
!****************路径1****************
NODE1=NODE(0,DI/2,0) ! 定义节点NODE1
NODE2=NODE(0,DI/2,L) ! 定义节点NODE2
PATH,PATH_1,2,30,40, ! 定义路径PATH_1
PPATH,1,NODE1 ! 通过节点位置定义路径关键点NODE1
PPATH,2,NODE2 ! 通过节点位置定义路径关键点NODE2
PDEF, ,S,EQV,AVG ! 将等效应力映射到路径
PDEF,SY,S,Y,AVG ! 将周向应力映射到路径
PDEF,SX,S,X,AVG ! 将径向应力映射到路径
PDEF,SZ,S,Z,AVG ! 将径向应力映射到路径
/AXLAB,X,DISTANCE ! 定义X轴显示距离
/AXLAB,Y,STRESS ! 定义Y轴显示应力
PLPATH,SEQV,SY,SX,SZ ! 显示路径上的应力分布
!****************路径2****************
NODE3=NODE(0,-DI/2,0) ! 定义节点NODE3
NODE4=NODE(0,-DI/2,L) ! 定义节点NODE4
PATH,PATH_2,2,30,40, ! 定义路径PATH_2
PPATH,1,NODE3 ! 通过节点位置定义路径关键点NODE3
PPATH,2,NODE4 ! 通过节点位置定义路径关键点NODE4
PDEF, ,S,EQV,AVG ! 将等效应力映射到路径
PDEF,SY,S,Y,AVG ! 将周向应力映射到路径
PDEF,SX,S,X,AVG ! 将径向应力映射到路径
PDEF,SZ,S,Z,AVG ! 将径向应力映射到路径
/AXLAB,X,DISTANCE ! 定义X轴显示距离
/AXLAB,Y,STRESS ! 定义Y轴显示应力
PLPATH,SEQV,SY,SX,SZ ! 显示路径上的应力分布
!****************路径3****************
TOP_NODE=NODE (0,DI/2,A) ! 定义节点TOP_NODE
BOT_NODE=NODE (0,-DI/2,A) ! 定义节点BOT_NODE
CSYS,1 ! 激活极坐标系
RSYS,1 ! 激活结果坐标系为柱坐标系
PATH,PATH_3,2,30,20, ! 定义路径PATH_3
PPATH,1,TOP_NODE ! 通过节点位置定义路径关键点1
PPATH,2,BOT_NODE ! 通过节点位置定义路径关键点2
PDEF,SY,S,Y,AVG ! 将周向应力映射到路径
PDEF,SX,S,X,AVG ! 将径向应力映射到路径
PDEF,SXY,S,XY,AVG ! 将剪应力映射到路径
/AXLAB,X,DISTANCE ! 定义X轴显示距离
/AXLAB,Y,STRESS ! 定义Y轴显示应力
PLPATH,SY,SX,SXY ! 显示路径上的应力分布
!****************路径4****************
CSYS,0 ! 激活笛卡儿坐标系
TOP_NODE2=NODE (0,DI/2,L-A) ! 定义节点TOP_NODE
BOT_NODE2=NODE (0,-DI/2,L-A) ! 定义节点BOT_NODE
CSYS,1 ! 激活极坐标系
RSYS,1 ! 激活结果坐标系为柱坐标系
PATH,PATH_4,2,30,20, ! 定义路径PATH_4
PPATH,1,TOP_NODE2 ! 通过节点位置定义路径关键点1
PPATH,2,BOT_NODE2 ! 通过节点位置定义路径关键点2
PDEF,SY,S,Y,AVG ! 将周向应力映射到路径
PDEF,SX,S,X,AVG ! 将径向应力映射到路径
PDEF,SXY,S,XY,AVG ! 将剪应力映射到路径
/AXLAB,X,DISTANCE ! 定义X轴显示距离
/AXLAB,Y,STRESS ! 定义Y轴显示应力
PLPATH,SY,SX,SXY ! 显示路径上的应力分布
!**************应力线性化评定路径1****
CSYS,0 ! 激活笛卡儿坐标系
NODE5=NODE(0,-DI/2,A) ! 定义节点NODE5
NODE6=NODE(0,-DI/2-TN,A) ! 定义节点NODE6
PATH,PATH_5,2,30,20, ! 定义路径PATH_5
PPATH,1,NODE5 ! 通过节点位置定义路径关键点NODE5
PPATH,2,NODE6 ! 通过节点位置定义路径关键点NODE6
PLSECT,S,X,-1,0 ! 应力线性化
!**************应力线性化评定路径2****
CSYS,0 ! 激活笛卡儿坐标系
NODE7=NODE(0,-DI/2,A/2) ! 定义节点NODE7
NODE8=NODE(0,-DI/2-TN,A/2) ! 定义节点NODE8
PATH,PATH_6,2,30,20, ! 定义路径PATH_6
PPATH,1,NODE7 ! 通过节点位置定义路径关键点NODE7
PPATH,2,NODE8 ! 通过节点位置定义路径关键点NODE8
PLSECT,S,X,-1,0 ! 应力线性化
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -