门式刚架.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!生成山墙柱（自定义截面）BEAM44
*DO,I,601,901,100                                        !循环控制
*DO,J,1,2,1                                              !循环控制
L,(J-1)*2+I,J*2+I                                        !连线
LATT,2,,2,,,,200                                         !赋予属性
*ENDDO                                                   !循环结束
*ENDDO                                                   !循环结束
ALLSEL                                                   !选择所有元素
L,508,605                                                !生成线
L,509,705                                                !生成线
L,510,805                                                !生成线
L,511,905                                                !生成线
LATT,2,,2,,,,200                                         !赋予属性                                      
LSEL,ALL                                                 !选择所有线
LSEL,S,TYPE,,2                                           !利用单元号选择线
LSEL,R,SEC,,200                                          !利用截面号选择线
LESIZE,ALL,,,2                                           !指定划分数                                       
LMESH,ALL,,,1                                            !划分当前选择集中所有线
ALLSEL                                                   !选择所有元素

!生成支撑
*DO,I,7,407,100                                          !循环控制
L,I,I+94                                                 !连线                                          
LATT,3,11,3                                              !赋予属性
*ENDDO                                                   !循环结束                                                                                             
*DO,I,1,401,100                                          !循环控制
L,I,I+106                                                !连线  
LATT,3,11,3                                              !赋予属性
*ENDDO                                                   !循环结束 
ALLSEL                                                   !选择所有元素
L,8,107                                                  !生成线
L,107,208                                                !生成线
L,208,307                                                !生成线
L,307,408                                                !生成线
L,408,507                                                !生成线
L,408,509                                                !生成线
L,509,410                                                !生成线
L,410,511                                                !生成线
L,8,109                                                  !生成线
L,109,10                                                 !生成线
L,10,111                                                 !生成线
LATT,3,11,3                                              !赋予属性
LSEL,ALL                                                 !选择所有线
LSEL,S,TYPE,,3                                           !利用单元号选择线
LESIZE,ALL,,,1                                           !指定划分数
LMESH,ALL                                                !划分当前选择集中所有线

!镜像
ALLSEL                                                    !选择所有元素                                                 
LSYMM,X,ALL                                               !关于YZ面镜像
ALLSEL                                                    !选择所有元素     
LSYMM,Z,ALL                                               !关于XY面镜像
ALLSEL                                                    !选择所有元素 
NUMMRG,ALL                                                !压缩所有元素编号

SAVE,MSGJ,DB,,ALL                                         !保存为MSGJ.DB

!***************************边界条件***************************************
NSEL,S,LOC,Y,0                                            !选择Z坐标为0的点
D,ALL,UX                                                  !约束X方向平动位移
D,ALL,UY                                                  !约束Y方向平动位移
D,ALL,UZ                                                  !约束Z方向平动位移


!*************************静力分析*****************************************
/SOLU
ANTYPE,STATIC                                             !指定为静力分析
SSTIF,ON                                                  !打开预应力开关
ACEL,0,-9.8                                               !施加重力加速度
LSEL,S,TYPE,,1                                            !利用单元号选择线
LSEL,R,LOC,X,-B/2+0.01,0                                  !选择屋面上左半边刚性梁
ESLL,S                                                    !选择附着线选单元
SFBEAM,ALL,2,PRES,1500,1500                               !施加均布压力
LSEL,S,TYPE,,1                                            !利用单元号选择线
LSEL,R,LOC,X,B/2-0.01,0                                   !选择屋面上右半边刚性梁
ESLL,S                                                    !选择附着线选单元
SFBEAM,ALL,2,PRES,-1500,-1500                             !施加均布压力
ALLSEL                                                    !选择所有元素 
OUTPR,BASIC,ALL                                           !控制求解屏幕输出            
OUTRES,ALL,ALL                                            !输出所有项，每一步都输出
ALLSEL                                                    !选择所有元素 
SOLVE                                                     !求解
!**********************************静力分析后处理***********************************
/post1
PLDISP,0                                                  !变形图
PLNSOL,U,Y,0,1                                            !Y向位移云图
!梁柱弯矩图
ESEL,S,TYPE,,1                                            !利用单元号选
ETABLE,IMZ, SMISC, 6	                                  !建立元素结果表，元素 I 点Z力距
ETABLE,JMZ, SMISC, 12	                                  !建立元素结果表，元素 J 点Z力距
PLLS,IMZ,JMZ,-1                                           !绘弯矩图
!檩条弯矩
ESEL,S,TYPE,,2                                             !利用单元号选                                        
ESEL,R,SEC,,1                                              !利用截面号重选                                  
ETABLE,IMZ, SMISC, 3	                                   !建立元素结果表，元素 I 点X力距
ETABLE,JMZ, SMISC, 16	                                   !建立元素结果表，元素 J 点X力距
PLLS,IMZ,JMZ,-1                                            !绘弯矩图





!*****************************模态分析************************************
/SOLU                                                     !进入求解器
ANTYPE,MODAL                                              !指定为模态分析 
MODOPT,LANB,20,0,0,,OFF                                   !选择模态分析方法
MXPAND,20, , ,YES                                         !扩展振形
OUTPR,BASIC,ALL                                           !控制求解屏幕输出            
OUTRES,ALL,ALL                                            !输出所有项，每一步都输出
ALLSEL                                                    !选择所有元素 
SOLVE                                                     !求解
!********************************模态分析后处理*********************************************
/POST1
SET,LIST                                                  !结果列表
SET,1,1                                                   !读入第一个载荷子步的结果
PLDISP,0                                                  !显示一阶振型
SET,1,2                                                   !读入第二个载荷子步的结果
PLDISP,0                                                  !显示二阶振型
SET,1,3                                                   !读入第三个载荷子步的结果
PLDISP,0                                                  !显示三阶振型
SET,1,4                                                   !读入第四个载荷子步的结果
PLDISP,0                                                  !显示四阶振型



!************************地震时程分析*******************
!*********************设置CONFIG
FINI
/CONFIG,NRES,20000 
/CONFIG,STATU
/SOLU

ALLSEL
ANTYPE,TRANS   


!指定为时程分析 
!DAMPRATIO=0.0005                                          !结构的阻尼比
!FREQ1=3.0215

!通过模态求解得出频率
!ALPHAD,2*DAMPRATIO*FREQ1*2*3.1415926                      !质量阻尼
!BETAD,2*DAMPRATIO/(FREQ1*2*3.1415926)                     !刚度阻尼
TRNOPT,FULL                                               !指定为完全瞬态分析 
TIMINT,OFF                                                !关闭时间积分开关
NLGEOM,OFF                                                !关闭大变形开关
TIME,1E-8                                                 !设置一个十分小的时间步
ACEL,0,-9.8                                               !施加重力加速度
SOLVE                                                     !求解
TIMINT,ON                                                 !打开时间积分开关
!定义和读入时程曲线 
NT=1000                                                    !时程曲线有NT个点 
DT=0.01                                                    !时间步长
*DIM,AC,,NT 
!读入数据,这个数据文件可以用EXCEL等软件来写 
/INPUT,TIANJIN,TXT                                         !天津波东西向共10秒 
!-------------------------------------------------- 
NSUBST,1, , ,1                                             !设一个子步
OUTRES,ALL,ALL                                             !输出每个子步的结果 
*DO,I,1,NT                                                 !循环控制
ACEL,0,AC(I),0                                             !施加重力加速度 
TIME,I*DT                                                  !时间步计数
SOLVE                                                      !求解
*ENDDO                                                     !循环结束 

/POST26 
NSOL,2,30,U,y,                                             !提出节点位移解
PLVAR,2,3, , , , , , , , ,                                 !做位移响应