pier模态分析.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

/FILNAME,PIER
/TITLE,ANALYSIS OF A BRIDGE'S PIER 
*CREATE,PIER,MAC	!创建宏文件PIER
/UNITS,SI		!使用国际单位制
*AFUN,DEG		!使用角度制
*SET,H,78		!墩高
*SET,D,12.6		!实心底面直径
*SET,DD,10.44		!空心底面直径
*SET,DT,11		!墩帽直径
*SET,HT,2.5		!墩帽高
*SET,TT,3		!实心部分高
*SET,KO,45		!外母线斜率
*SET,KI,50		!内母线斜率
*SET,EE,29E9		!桥墩弹性模量
*SET,NU,0.3		!桥墩泊松比
*SET,DEN,2500		!桥墩密度
*SET,ALPHA,0.05		!设定质量阻尼ALPHA为0.05
*SET,BETA,0.01		!设定刚度阻尼BETA为0.01
*SET,OMEGA,2		!设定激励角频率2

!进入前处理
/PREP7
ET,1,MESH200
KEYOPT,1,1,6		!不带中间节点四边形单元
ET,2,SOLID45
MP,EX,1,EE
MP,NUXY,1,NU
MP,DENS,1,DEN
!建立几何模型
!建立关键点
K,1
K,2,DD/2+TT/KI
K,3,D/2
K,4,,TT
K,5,DD/2,TT
K,6,D/2-TT/KO,TT
K,7,,H-TT
K,8,DD/2-(H-2*TT)/KI,H-TT
K,9,D/2-(H-TT)/KO,H-TT
K,10,,H
K,11,DD/2-(H-TT)/KI,H
K,12,D/2-H/KO,H
K,13,DT/2,H
K,14,,H+HT
K,15,DD/2-(H-TT+HT)/KI,H+HT
K,16,D/2-(H+HT)/KO,H+HT
K,17,DT/2,H+HT
!建立用于旋转的面
A,2,3,6,5
A,5,6,9,8
A,8,9,12,11
A,11,12,16,15
A,12,13,17,16
!建立用于延伸的面
WPROT,,-90			!绕X轴旋转-90度
WPOFFS,,,TT			!移动工作平面到空心底部
CYL4,,,,,DD/2			!建立实心圆面
WPOFFS,,,H-TT			!移动工作平面到墩帽底部
CYL4,,,,,DD/2-(H-TT)/KI		!建立实心圆面
WPCSYS,				!工作平面回到笛卡儿坐标系
ASEL,S,AREA,,6,7,1		!选择面
ASBW,ALL,,DELETE		!用工作平面切分面
WPROT,,,90			!绕Y轴旋转90度
ASEL,S,AREA,,8,11,1		!选择面
ASBW,ALL,,DELETE		!用工作平面切分面
ALLS				!选择所有的元素
/PNUM,LINE,1			!打开线编号开关
/PNUM,AREA,1			!打开面编号开关
!建立有限元模型
!划分空心部分桥墩的面网格
MAT,1
TYPE,1
CSYS,
LSEL,S,LINE,,1,1,1
LSEL,A,LINE,,3,12,3
LSEL,A,LINE,,14,16,2
LESIZE,ALL,,,2			!网格划分数2
LSEL,S,LINE,,2,4,2
LSEL,A,LINE,,8,10,2
LSEL,A,LINE,,11,15,2
LESIZE,ALL,,,2			!网格划分数2
LSEL,S,LINE,,5,7,2
LESIZE,ALL,,,40
ASEL,S,AREA,,1,5,1
AMESH,ALL
!划分实心部分的面网格
ALLS
WPCSYS,				!工作平面回到笛卡儿坐标系
WPROT,,-90			!绕X轴旋转-90度
LSEL,S,LINE,,17,24,1		!选择要划分网格的线
LESIZE,ALL,,,6			!网格划分数6
LSEL,S,LINE,,27,34,1		!选择要划分网格的线
LESIZE,ALL,,,6			!网格划分数6
ASEL,S,AREA,,6,7,1
ASEL,A,AREA,,12,17,1
AMESH,ALL
!由面网格延伸成体网格
!墩帽中部网格
TYPE,2
ASEL,S,AREA,,14,17,1
EXTOPT,ESIZE,2			!设置延伸份数2
EXTOPT,ACLEAR,0			!设置延伸后保留面网格
VEXT,ALL,,,,HT,,1-HT/(DD*KI/2-H+TT),,1-HT/(DD*KI/2-H+TT)	
!设置X,Y,Z方向延伸长度0,-TT,0
!顶部实心网格
ASEL,S,AREA,,14,17,1
EXTOPT,ESIZE,2			!设置延伸份数2
EXTOPT,ACLEAR,1			!设置延伸后去掉面网格
VEXT,ALL,,,,-TT,,1+TT/(DD*KI/2-H+TT),,1+TT/(DD*KI/2-H+TT)	
!设置X,Y,Z方向延伸长度0,-TT,0
!底部实心网格
ASEL,S,AREA,,6,7,1
ASEL,A,AREA,,12,13,1
EXTOPT,ESIZE,2			!设置延伸份数2
EXTOPT,ACLEAR,1			!设置延伸后去掉面网格
VEXT,ALL,,,,-TT,,1+2*TT/(DD*KI),,1+2*TT/(DD*KI)			
!设置X,Y,Z方向延伸长度0,-TT,0
!由面网格旋转成体网格
ASEL,S,AREA,,1,5,1
EXTOPT,ESIZE,6			!设置延伸份数6
EXTOPT,ACLEAR,1			!设置延伸后去掉面网格
VROTA,ALL,,,,,,1,14		!旋转面生成体网格,关键点1与14定义旋转轴
NUMMRG,ALL			!合并所有重合元素
NUMCMP,ALL			!压缩所有元素的编号
!施加约束
NSEL,S,LOC,Y,			!选择塔底部节点
D,ALL,UX				!约束所选节点X方向自由度
D,ALL,UY				!约束所选节点Y方向自由度
D,ALL,UZ				!约束所选节点Z方向自由度
ALLS				!选中所有的元素
EPLOT				!显示单元
/VIEW,1,1,1,1			!正等轴视图
SAVE				!保存模型
*END				!结束宏文件
PIER				!运行宏生成模型
FINI				!退出前处理器
!加载与求解
/SOLU
ANTYPE,2				!设置分析类型为模态分析
MODOPT,SUBSP,10			!设置模态分析方法为subspace法
MXPAND,10,,,1			!设置模态分析扩展10阶
LUMPM,ON				!打开近似集中质量
ACEL,0,9.8,0			!设置重力加速度
ALLS				!选中所有的元素
SOLVE				!求解
SAVE				!保存
FINI				!退出SOLU求解器
!***************后处理****************
/POST1
FILE,'PIER','rst'			!读入结果文件
SET,LIST				!列出各阶频率
SET,1,1				!读取第1阶振型
PLNSOL,S,EQV,0,1.0		!显示等效应力
ANMODE,10,0.5,,0			!制作第1阶动画
SET,1,3				!读取第2阶振型
PLDI				!显示第2阶变形
ANMODE,10,0.5,,0			!制作第2阶动画
SET,1,5				!读取第3阶振型
PLNSOL,U,Y,0,1.0		!显示Y向位移
ANMODE,10,0.5,,0			!制作第3阶动画
SET,1,6				!读取第4阶振型
PLNSOL,S,Y,0,1.0    		!显示Y方向应力
ANMODE,10,0.5,,0			!制作第4阶动画