pier风激励.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

FINI
/CLE
/FILNAME,PIER
/TITLE,ANALYSIS OF A BRIDGE'S PIER 
!"PIER"宏文件应放在工作目录下。
PIER				!运行宏生成模型
!***********选择面并施加风载荷*********
!GUI定义函数边界条件wind,并加载，定义为wind表参数
ASEL,S,AREA,,51,54,3		!通过面号选择面51与54
ASEL,A,AREA,,105,107,2		!通过面号增选面105与107
ASEL,A,AREA,,58,110,52		!通过面号增选面58与110
ASEL,A,AREA,,65,115,50		!通过面号增选面65与115
SFA,ALL,,PRES,%wind%		!施加所选面的风载荷
SAVE				!保存
FINI				!退出一般后处理
!加载与求解
!*****************求解****************
/SOLU				!进入求解器
ANTYPE,4				!指定分析类型为瞬态动力学分析
TRNOPT,FULL			!瞬态动力学分析采用FULL法
TIMINT,OFF			!关闭时间积分效应
OUTRES,BASIC,ALL			!输出基本项，每一步都输出
KBC,1				!指定载荷
TIME,1E-10			!指定载荷步结束时间
NSUB,4,8				!指定载荷子步数为4，最大子步数为8
SSTIF,ON				!打开应力刚化效应
ACEL,0,9.8,0			!施加重力加速度
ALLS				!选中所有元素
SOLVE				!求解第一个载荷步
!在自重作用下，计算结构风激励下的响应
TIMINT,ON				!打开时间积分效应
OUTRES,BASIC,ALL			!输出基本项，每一步都输出
KBC,0				!指定载荷
AUTOTS,ON				!打开自动时间步
ALPHAD,ALPHA 			!设定质量阻尼为ALPHA
BETAD,BETA			!设定刚度阻尼为BETA
TIME,4*2*3.14/OMEGA		!指定载荷步结束时间
NSUB,40,60			!指定载荷子步数为40，最大子步数为60
ALLS				!选中所有元素
SOLVE				!求解
FINI				
!后处理
/POST1
SET,LAST			!从结果文件读入最后一个子步数据
PLNSOL, U,SUM, 0,1.0     	!显示合位移云图
PLNSOL, U,X, 0,1.0	     	!显示X方向位移云图
PLNSOL, U,Y, 0,1.0	     	!显示Y方向位移云图
PLNSOL, S,X, 0,1.0    	!显示X方向应力
PLNSOL, S,Y, 0,1.0    	!显示Y方向应力
PLNSOL, S,Z, 0,1.0    	!显示Z方向应力
PLNSOL, S,1, 0,1.0     	!显示第一主应力
PLNSOL, S,2, 0,1.0    	!显示第二主应力
PLNSOL, S,3, 0,1.0    	!显示第三主应力
PLNSOL, S,EQV, 0,1.0    	!显示等效应力
PLNSOL, EPTO,X, 0,1.0    	!显示X方向应变
PLNSOL, EPTO,Y, 0,1.0    	!显示Y方向应变
PLNSOL, EPTO,Z, 0,1.0    	!显示Z方向应变
PLNSOL, EPTO,1, 0,1.0		!显示第一主应变
PLNSOL, EPTO,2, 0,1.0		!显示第二主应变
PLNSOL, EPTO,3, 0,1.0		!显示第三主应变
PLNSOL, EPTO,EQV, 0,1.0    	!显示等效应变
PLESOL, EPTO,EQV, 0,1.0		!显示单元解等效应变
!-------------------
!--时间历程后处理---
!-------------------
ALLS
FINI
/POST26
NUMVAR,20			!指定允许的变量数
NSOL,2,394,U,X, UX_UP  	!取出墩顶点节点的X向位移数据
NSOL,3,394,U,Y, UY_UP  	!取出墩顶点节点的Y向位移数据
NSOL,4,394,U,Z, UZ_UP  	!取出墩顶点节点的Z向位移数据
NSOL,5,2757,U,X, UX_MID  	!取出墩中间节点的X向位移数据
NSOL,6,2757,U,Y, UY_MID  	!取出墩中间节点的Y向位移数据
NSOL,7,2757,U,Z, UZ_MID  	!取出墩中间节点的Z向位移数据
NSOL,8,3627,U,X, UX_LOW  	!取出墩下面节点的X向位移数据
NSOL,9,3627,U,Y, UY_LOW  	!取出墩下面节点的Y向位移数据
NSOL,10,3627,U,Z, UZ_LOW  	!取出墩下面节点的Z向位移数据
DERIV,11,2,1,,VX_UP		!对顶点节点的X向位移微分运算，得到X向速度
DERIV,12,3,1,,VY_UP		!对顶点节点的Y向位移微分运算，得到Y向速度
DERIV,13,4,1,,VZ_UP		!对顶点节点的Z向位移微分运算，得到Z向速度
DERIV,14,5,1,,VX_MID		!对墩中间节点的X向位移微分运算，得到X向速度
DERIV,15,6,1,,VY_MID		!对墩中间节点的Y向位移微分运算，得到Y向速度
DERIV,16,7,1,,VZ_MID		!对墩中间节点的Z向位移微分运算，得到Z向速度
DERIV,17,8,1,,VX_LOW		!对墩下面节点的X向位移微分运算，得到X向速度
DERIV,18,9,1,,VY_LOW		!对墩下面节点的Y向位移微分运算，得到Y向速度
DERIV,19,10,1,,VZ_LOW		!对墩下面节点的Z向位移微分运算，得到Z向速度

PLVAR,2,5,8			!显示上中下三节点的X向位移随时间变化曲线
PLVAR,3,6	,9		!显示上中下三节点的Y向位移随时间变化曲线
PLVAR,4,7	,10		!显示上中下三节点的Z向位移随时间变化曲线
PLVAR,11,14,17			!显示上中下三节点的X向速度随时间变化曲线
PLVAR,12,15,18			!显示上中下三节点的Y向速度随时间变化曲线
PLVAR,13,16,19			!显示上中下三节点的Z向速度随时间变化曲线
PLVAR,3			!显示上节点的Y向位移随时间变化曲线
PLVAR,12				!显示上节点的Y向速度随时间变化曲线