📄 lmd.mac
字号:
FINI
/CLE
/FILNAME,EX
/TITLE,THE ANALYSIS OF THE LMD
!*******************************参数区**********************************************
!整体尺寸(到中轴线）
*SET,B,40 !宽度
*SET,H,15 !高度
*SET,L,120 !跨度
!*************************************局部尺寸****************************************
!伸臂部分
*SET,L_S,20 !伸臂长度
*SET,L_S_1,10 !伸臂等截面段长
*SET,H_S_1,4 !伸臂等截面段高
*SET,B_S_1,2 !伸臂等截面段宽
*SET,L_S_2,10 !伸臂变截面段长
*SET,H_S_2,2 !伸臂变截面段高
*SET,B_S_2,2 !伸臂变截面段宽
!横梁
*SET,L_H,40
*SET,B_H,2
*SET,H_H,2
!跨中部分
*SET,L_KZ,80 !跨中长度
*SET,H_KZ,4 !跨中高度
*SET,B_KZ,2 !跨中宽度
!支撑部分
*SET,L_ZC,15 !支撑长度
*SET,HS_ZC,4 !支撑高度上截面高
*SET,B_ZC,2 !支撑宽度
!框架脚
*SET,L_KJ,40 !框架脚 长度
*SET,H_KJ,4 !框架脚 高度
*SET,B_KJ,2 !框架脚 宽度
*SET,T,0.5 !箱形板厚度均为0.5
/PREP7
ET,1,63
MP,EX,1,2.1E10
MP,PRXY,1,0.3
MP,DENS,1,7850
R,1,T,T,T,T
!***********************载荷************************
F=0.25*(45E4*1.02+60E4*1.2)
!建立四分之一模型
!生成跨中关键点
K,1,0,H+H_KZ/2,-B/2+B_KZ/2
K,2,0,H+H_KZ/2,-B/2-B_KZ/2
K,3,0,H-H_KZ/2,-B/2-B_KZ/2
K,4,0,H-H_KZ/2,-B/2+B_KZ/2
KGEN,2,1,4,1,L_KZ/2,,,100 !跨中部分
KGEN,2,103,104,1,-B_ZC/2 !定位支撑位置
KGEN,2,103,104,1,B_ZC/2
KGEN,2,1,4,1,L_KZ/2+L_S_1,,,200 !伸臂等截面段
!生成伸臂端面关键点
K,301,L/2+B_H/2,H+H_KZ/2,-B/2+B_KZ/2
K,302,L/2+B_H/2,H+H_KZ/2,-B/2-B_KZ/2
K,303,L/2+B_H/2,H+H_KZ/2-H_H,-B/2-B_KZ/2
K,304,L/2+B_H/2,H+H_KZ/2-H_H,-B/2+B_KZ/2
!支撑
KGEN,2,5,8,1,,-L_ZC,
!横梁
KGEN,2,302,303,1,B_H
KGEN,2,13,14,1,,,L_H/2+B_KZ
KGEN,2,15,16,1,-B_H
!框架脚
KGEN,2,9,11,2,,-H_KJ
KGEN,2,19,20,1,,,L_H/2+B_KZ
KGEN,2,21,22,1,,H_KJ
A,1,2,302,301,1
A,2,202,203,3,2
A,202,302,303,203,202
A,201,301,304,204,201
A,201,204,4,1,201
A,6,10,12,8,6
A,8,12,11,7,8
A,7,11,9 ,5,7
A,6,10,9,5,6
A,3,4,6,5,3
A,203,204,304,303,203
A,302,303,14,13,302
A,201,204,304,301,201
A,13,15,16,14,13
A,302,17,15,13,302
A,301,17,18,304,301
A,303,18,16,14,303
A,9,19,20,11,9
A,11,24,22,20,11
A,20,22,21,19,20
A,21,19,9,23,21
A,10,23,24,12,10
ARSYM,X,ALL
ARSYM,Z,ALL
ALLSEL
NUMMRG,KP
ESIZE,1
AMESH,ALL
ALLSEL
NUMMRG,ALL
SAVE,LMD,DB,,ALL !保存为LMD.DB
ASEL,S,AREA,,1,5,4
ASEL,A,AREA,,22,26,4
ASEL,A,AREA,,43,47,4
ASEL,A,AREA,,64,68,4
ASEL,A,AREA,,30,72,42
ASEL,A,AREA,,41,83,42
ASEL,A,AREA,,20,62,42
ASEL,A,AREA,,9,51,42
ASEL,A,AREA,,36,78,42
ASEL,A,AREA,,15,57,42
ASEL,A,AREA,,75,80,5
ASEL,A,AREA,,54,59,5
ASEL,A,AREA,,12,17,5
ASEL,A,AREA,,33,38,5
ASEL,A,AREA,,53,58,5
ASEL,A,AREA,,11,16,5
ASEL,A,AREA,,32,37,5
ASEL,A,AREA,,74,79,5
ASEL,A,AREA,,10,31,21
ASEL,A,AREA,,52,73,21
AREVERSE,ALL
SAVE,LMD1,DB,,ALL !保存为LMD.DB
!约束
ASEL,S,,,40,82,42
ASEL,A,,,19,61,42
NSLA,S,1
D,ALL,ALL
!*****************************模态分析************************************
/SOLU !进入求解器
ANTYPE,MODAL !指定为模态分析
MODOPT,LANB,20,0,0,,OFF !选择模态分析方法
MXPAND,20, , ,YES !扩展振形
OUTPR,BASIC,ALL !控制求解屏幕输出
OUTRES,ALL,ALL !输出所有项，每一步都输出
ALLSEL !选择所有元素
SOLVE !求解
!********************************模态分析后处理*********************************************
/POST1
SET,LIST !结果列表
SET,1,1 !读入第一个载荷子步的结果
PLDISP,0 !显示一阶振型
SET,1,2 !读入第二个载荷子步的结果
PLDISP,0 !显示二阶振型
SET,1,3 !读入第三个载荷子步的结果
PLDISP,0 !显示三阶振型
SET,1,4 !读入第四个载荷子步的结果
PLDISP,0 !显示四阶振型
!******************************** 静力求解****************************************
/SOLU
ANTYPE,STATIC !指定为静力分析
ACEL,0,9.8 !施加重力加速度
SOLVE
PLDISP,0 !变形图
PLNSOL,U,Y,0,1 !Y向位移云图
ETABLE, ,S,EQV !定义单元表
PLETAB,SEQV,NOAV !绘等效应力云图
ETABLE,MX,SMISC,4
PLETAB,MX,NOAV
ETABLE,MY,SMISC,5
PLETAB,MY,NOAV
!移动载荷作用下
/SOLU !进入求解器
ANTYPE,TRANS !定义瞬态求解
TIM=0 !初始化
DELT=1 !时间增量
!TIMINT,ON
*DO,I,1,114,1.000 !进入循环
TIM=TIM+1 !循环控制
TIME,TIM !循环控制
FDELE,ALL,AL !删除所有载荷
!第一
ALLSEL !选择所有元素
NSEL,S,LOC,X,-61+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,-20 !由位置重选点
F,ALL,FY,-F !加集中载荷
!第二段
ALLSEL !选择所有元素
NSEL,S,LOC,X,-53+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,-20 !由位置重选点
F,ALL,FY,-F !加集中载荷
!第三段
ALLSEL !选择所有元素
NSEL,S,LOC,X,-61+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,20 !由位置重选点
F,ALL,FY,-F !加集中载荷
!第四段
ALLSEL !选择所有元素
NSEL,S,LOC,X,-53+(I-1) !由位置重选点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,20 !由位置重选点
F,ALL,FY,-F !加集中载荷
ALLSEL
NSUBST,1
OUTRES,ALL,ALL
SOLVE
*ENDDO
/POST26 !进入后处理模块
/AXLAB,Y,UY !制定Y轴名称
NSOL,2,22,U,Y,UY_2 !选择2号节点的Y向变形作为变量2
PLVAR,2 !显示时程关系曲线
/AXLAB,Y,UX !制定Y轴名称
NSOL,3,2,U,X,UX_2 !选择2号节点的X向变形作为变量3
PLVAR,3 !显示时程关系曲线
/AXLAB,Y,UZ !制定Y轴名称
NSOL,4,2,U,Z,UZ_2 !选择2号节点的Z向变形作为变量4
PLVAR,4 !显示时程关系曲线
/AXLAB,Y,UY !制定Y轴名称
NSOL,5,1628,U,Y,UY_1628 !选择1628号节点的Y向变形作为变量5
PLVAR,5 !显示时程关系曲线
/AXLAB,Y,UX !制定Y轴名称
NSOL,6,1628,U,X,UX_1628 !选择1628号节点的X向变形作为变量6
PLVAR,6 !显示时程关系曲线
!特殊位置处的变形和应力云图
set,1
PLDISP,0 !显示变形云图
PLNSOL,U,X,0,1 !小车在悬臂端时X向位移云图
PLNSOL,U,Y,0,1 !小车在悬臂端时Y向位移云图
PLNSOL,U,Z,0,1 !小车在悬臂端时Z向位移云图
ETABLE, ,S,EQV !定义单元表
PLETAB,SEQV,NOAV !绘等效应力云图
!小车在跨中附近
set,57
PLDISP,0 !显示变形云图
PLNSOL,U,X,0,1 !小车在跨中时X向位移云图
PLNSOL,U,Y,0,1 !小车在跨中时Y向位移云图
PLNSOL,U,Z,0,1 !小车在跨中时Z向位移云图
ETABLE, ,S,EQV !定义单元表
PLETAB,SEQV,NOAV !绘等效应力云图
!同时考虑重力和移动荷载
/SOLU !进入求解器
ANTYPE,TRANS !定义瞬态求解
TRNOPT,FULL !指定为完全瞬态分析
TIMINT,OFF !关闭时间积分开关
NLGEOM,OFF !关闭大变形开关
TIME,1E-8 !设置一个十分小的时间步
NSUBST,2 !设两个子步
KBC,1 !设置为加载方式为阶跃式
ACEL,0,-9.8 !施加重力加速度
SOLVE !求解
TIMINT,ON !打开时间积分开关
TIM=0 !初始化
DELT=1 !时间增量
*DO,I,1,114,1.000 !进入循环
TIM=TIM+1 !循环控制
TIME,TIM !循环控制
FDELE,ALL,ALL !删除所有载荷
ALLSEL !选择所有元素
NSEL,S,LOC,X,-61+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,-20 !由位置重选点
F,ALL,FY,-F !加集中载荷
ALLSEL !选择所有元素
NSEL,S,LOC,X,-53+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,-20 !由位置重选点
F,ALL,FY,-F !加集中载荷
ALLSEL !选择所有元素
NSEL,S,LOC,X,-61+(I-1) !由位置选择点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,20 !由位置重选点
F,ALL,FY,-F !加集中载荷
ALLSEL !选择所有元素
NSEL,S,LOC,X,-53+(I-1) !由位置重选点
NSEL,R,LOC,Y,17 !由位置重选点
NSEL,R,LOC,Z,20 !由位置重选点
F,ALL,FY,-F !加集中载荷
ALLSEL !选择所有元素
NSUBST,1 !设置子步数
OUTRES,ALL,ALL !输出所有结果
SOLVE !求解
*ENDDO !循环结束
!后处理
/POST26 !进入后处理模块
/AXLAB,Y,UY !制定Y轴名称
NSOL,2,22,U,Y,UY_2 !选择2号节点的Y向变形作为变量2
PLVAR,2 !显示时程关系曲线
/AXLAB,Y,UX !制定Y轴名称
NSOL,3,2,U,X,UX_2 !选择2号节点的X向变形作为变量3
PLVAR,3 !显示时程关系曲线
/AXLAB,Y,UZ !制定Y轴名称
NSOL,4,2,U,Z,UZ_2 !选择2号节点的Z向变形作为变量4
PLVAR,4 !显示时程关系曲线
/AXLAB,Y,UY !制定Y轴名称
NSOL,5,1628,U,Y,UY_1628 !选择1628号节点的Y向变形作为变量5
PLVAR,5 !显示时程关系曲线
/AXLAB,Y,UX !制定Y轴名称
NSOL,6,1628,U,X,UX_1628 !选择1628号节点的X向变形作为变量6
PLVAR,6 !显示时程关系曲线
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -