📄 bga力学行为模拟.txt
字号:
FINI
/CLE
/UNITS,SI !国际单位制
/FILNAME,CBGA !制定文件名为BGA
/TITLE,3D TEMPERATURE CIRCLE SIMULATION OF CBGA
!定义芯片的尺寸
*SET,CHIP_L,18.5E-3 !芯片长度
*SET,CHIP_W,18.5e-3 !芯片宽度
*SET,CHIP_H,1E-3 !芯片高度
!定义焊料球的尺寸
*SET,SB_R,0.445E-3 !焊球半径
*SET,SB_H,0.65E-3 !焊球高度
*SET,SB_JJ,SQRT((SB_R**2)-((SB_H/2)**2))
!定义PCB的尺寸
*SET,PCB_L,47E-3 !PCB板长度
*SET,PCB_W,47E-3 !PCB板宽度
*SET,PCB_H,1.2E-3 !PCB板高度
!************************
!*******前处理***********
!************************
/PREP7 !进入前处理
ET,1,VISCO107 !定义两种单元类型
ET,2,SOLID45
MP,ALPX,1,21E-6 !热膨胀系数
MPTEMP,1,-55,-35,-15,5,20,50 !定义焊点材料的弹性模量、泊松比
MPTEMP,7,75,100,125
MPDATA,EX,1,1,47.97E9,46.89E9,45.79E9,44.38E9,43.25E9,41.33E9
MPDATA,EX,1,7,39.45E9,36.85E9,34.59E9
MPDATA,PRXY,1,1,0.352,0.354,0.357,0.36,0.363,0.365
MPDATA,PRXY,1,7,0.37,0.377,0.38
TB,ANAN,1,,,0
TBDATA,1,56.33E6,10830,1.49E7,11,0.303,2640E6
TBDATA,7,80.415E6,0.0231,1.34
!定义芯片材料属性——陶瓷
MP,EX,2,26.5E9 !定义陶瓷的弹性模量
MP,PRXY,2,0.23 !定义陶瓷的泊松比
MP,ALPX,2,6.9E-6 !定义陶瓷的热膨胀系数
!定义PCB的材料属性——FR4板
MP,EX,3,22E9 !定义PCB的弹性模量
MP,PRXY,3,0.28 !定义PCB的泊松比
MP,ALPX,3,18E-6 !定义PCB的热膨胀系数
!建模
PCIRC,SB_R, ,-90,90 !建立一个半圆
LSEL,S,LOC,X,0,0 !根据坐标系选择线
LCOMB,ALL !合并选择的线为一条线
RECTNG,0,SB_JJ,SB_H/2,SB_H/2+CHIP_H !建立芯片矩形
RECTNG,0,SB_JJ,-SB_H/2,-SB_H/2-PCB_H !建立PCB板矩形
AOVLAP,ALL !重叠芯片、焊球和PCB模型
ASEL,S,LOC,Y,SB_H/2,SB_H/2+CHIP_H !选择PCB板
AADD,ALL !生成一个单一面
ASEL,S,LOC,Y,-SB_H/2,-SB_H-PCB_H !选择芯片
AADD,ALL !生成一个单一面
LSEL,S,LOC,X,0,0 !选择线
LSEL,R,LOC,Y,SB_H/2,SB_H/2+CHIP_H
LCOMB,ALL !合并生成一条单一的线
LSEL,S,LOC,X,0,0 !选择线
LSEL,R,LOC,Y,-SB_H/2,-SB_H/2-PCB_H
LCOMB,ALL !合并生成一条单一的线
ALLSEL,ALL !选择所有实体
NUMCMP,ALL !压缩编号
VROTAT,ALL,,,,,,4,1,90 !旋转面得到体
BLOCK,0,SB_DIST/2,SB_H/2,CHIP_H+SB_H/2,0,SB_DIST/2 !建立长方体
BLOCK,0,SB_DIST/2,-SB_H/2,-PCB_H-SB_H/2,0,SB_DIST/2
VOVLAP,ALL
NUMCMP,ALL !压缩编号
ALLSEL,ALL !选择所有实体
!定义材料属性
VSEL,S,LOC,Y,-SB_H/2,SB_H/2 !选择焊球
VATT,1,1,, !定义焊球材料属性
VSEL,S,LOC,Y,SB_H/2,SB_H/2+CHIP_H !选择芯片
VATT,2,2,, !定义芯片材料属性
VSEL,S,LOC,Y,-SB_H/2-PCB_H,-SB_H/2 !选择PCB板
VATT,3,2,, !定义PCB材料属性
!进行网格划分
ACCAT,14,15 !连接两个平面以便于映射网格划分
ACCAT,16,17
LSEL,S,LOC,Y,SB_H/2+1E-5,SB_H/2+CHIP_H-1E-5
LSEL,A,LOC,Y,-SB_H/2-1E-5,-SB_H/2-CHIP_H+1E-5
LESIZE,ALL,,,8,,1,,,1 !沿PCB板和芯片高度方向
LSEL,S,LOC,Y,-SB_H/2+1E-5,SB_H/2-1E-5
LESIZE,ALL,,,6,,1,,,1 !沿焊球高度方向
CSYS,5
LSEL,S,LOC,X,1E-5,SB_R
LESIZE,ALL,,,2,,0,,,1 !沿焊球水平方向
CSYS
LSEL,S,LOC,X,0,0
LESIZE,ALL,,,4,,0,,,1
LSEL,S,LOC,Z,0,0
LESIZE,ALL,,,4,,0,,,1
ALLSEL,ALL
MSHAPE,0,3D
MSHKEY,1
VMESH,ALL
NUMCMP,ALL !压缩编号
LSEL,S,LCCA !选择连接的线
LDELE,ALL
ASEL,S,ACCA !选择连接的面
ADELE,ALL
ALLSEL,ALL
VSYMM,X,ALL,,,,0,0 !通过镜像复制得到一个焊球的模型
VSYMM,Z,ALL,,,,0,0
NUMCMP,ALL !压缩编号
ALLSEL,ALL
NUMMRG,NODE,1E-6 !节点合并
NUMCMP,ALL !压缩编号
!施加约束条件
ASEL,S,LOC,Y,-SB_H/2-PCB_H,-SB_H/2-PCB_H
DA,ALL,ALL !在PCB板底面施加一个全约束
ALLSEL,ALL
!设置求解选项
!======================
!========加载求解======
!======================
/SOLU
ANTYPE,4 !设定为瞬态分析
TRNOPT,FULL !定义瞬态分析类型
NLGEOM,1 !设定为大变形分析
nropt,full !设定全N-R求解
TREF,25 !设定参考温度
TOFFST,273 !设定摄氏温度与开氏温度之间的差值
OUTRES,ALL,ALL !输出每个子步的所有值
!施加载荷并进行计算
TUNIF,25
TIME,1E-5
SOLVE
NSUBST,5 !设定载荷子步数为5
KBC,0 !定义载荷为斜坡载荷
*DO,N,0,4,1 !施加温度循环，循环圈数为5圈
TUNIF,125 !升温阶段
TIME,5*60+68*60*N
SOLVE
TIME,30*60+68*60*N !保温阶段
SOLVE
TUNIF,-55 !降温阶段
TIME,39*60+68*60*N
SOLVE
TIME,64*60+68*60*N !保温阶段
SOLVE
TUNIF,25 !升温阶段
TIME,68*60+68*60*N
SOLVE
*ENDDO
!======================
!======通用后处理======
!======================
/POST1
PLNSOL,S,EQV,0,1 !查看等效应力分布图
PLNSOL,EPPL,EQV,0,1 !查看等效应变分布图
FINISH
!======================
!====时间历程后处理====
!======================
ESOL,2,495,24,S,Y,Y_2 !保存后处理文件中危险点的Y向应力
XVAR,1 !定义X轴变量
PLVAR,2 !绘制Y向应力随时间变化图，见图7-17
ESOL,3,495,24,EPPL,Y,EPPLY_3 !保存后处理文件中危险点的Y向塑性应变
XVAR,1 !定义X轴变量
PLVAR,3 !绘制Y向塑性变形随时间变化图，见图7-18
ESOL,4,495,24,EPEL,Y,EPELY_4 !保存后处理文件中危险点的Y向弹性应变
XVAR,1 !定义X轴变量
PLVAR,4 !绘制Y向弹性应变随时间变化图，见图7-19
ADD,5,3,4,,T_STRAIN,,,1,1,1 !对数据进行加法处理
XVAR,1 !定义X轴变量
PLVAR,5 !绘制Y向总应变随时间变化图，见图7-20
XVAR,5 !定义X轴变量
PLVAR,2 !绘制危险点Y向应力应变环，见图7-21
/AXLAB,X,Y STRAIN !定义X轴标注
/AXLAB,Y,Y STRESS/Pa !定义Y轴标注⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -