简谐力移动载荷分析.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!在移动载荷作用下，桥梁将发生振动，产生的变形和应力都比静载荷作用大。移动载荷的这种动力效应是不可忽视的，若在载荷处于最不利的静力作用位置同时满足共振条件，那么将会发生较大的动态响应，从而导致桥梁破坏。本例将移动载荷作为匀速移动的常量力来模拟悬索桥在移动载荷下的动态响应。为了提高分析效率，我们在前节初始位置确定分析中已经创建了宏“MODEL.MAC”，在本节只需要直接调用该宏，并将缆索单元的初应变值改为0.0043，即可得到移动载荷作用分析的有限元模型。
!参数定义
FINI								!退出
/CLE
/FILNAME,CABLE_BRIDGE,1
/TITLE,YIDONG HEZAI OF CABLE_BRIDGE
!建立模型
!"MODEL"宏文件应放在工作目录下。
BW=10.8			!桥面宽度
TH=-1.88			!加劲桁架高度
X1=50				!左侧桥塔X向坐标
X2=174				!右侧桥塔X向坐标
Y1=18				!桥塔塔顶Y向坐标
Y2=-18.8			!桥塔塔基Y向坐标
D1=0.079			!主缆截面直径
D2=0.039			!吊索截面直径
B1=0.16			!纵向分配梁，纵向斜腹杆，横向内侧竖杆，横向内、外侧斜腹杆截面宽度
B2=0.3				!纵向上、下弦杆截面宽度
B3=0.2				!纵向竖杆，横向外侧竖杆截面宽度
B4=0.18			!横向上、下弦杆截面宽度
B5=0.12			!抗风桁架截面宽度
B6=2.0				!塔柱截面宽度
B7=4.0				!柱间连接件截面宽度
B8=0.14			!桥面板截面厚度
H1=0.28			!纵向分配梁截面厚度
H2=0.2				!纵向上、下弦杆，横向下弦杆截面厚度
H3=0.14			!纵向斜腹杆，横向外侧竖杆、内侧竖杆、外侧斜腹杆、内侧斜腹杆截面厚度
H4=0.18			!纵向竖杆截面厚度
H5=0.24			!横向上弦杆截面厚度
H6=0.12			!抗风桁架截面厚度
H7=4.0				!塔柱截面厚度
H8=2.0				!柱间连接件截面厚度
!材料参数设定
INSTR=0.0043			!缆索初应变
!定义单元类型
/PREP7
ET,1,LINK10				!主缆、吊索单元
KEYOPT,1,3,0				!只受拉不受压
ET,2,BEAM4				!加劲桁架、纵向分配梁、抗风桁架、桥塔单元
ET,3,SHELL63				!桥面板单元
!定义材料属性
MP,EX,1,21E10				!钢丝绳材料常数（悬索、吊索）
MP,NUXY,1,0.167
MP,DENS,1,7850	
MP,EX,2,3.0E10				!C30砼材料常数（加劲桁架、纵梁）
MP,NUXY,2,0.3
MP,DENS,2,2500
MP,EX,3,2.8E10				!C20砼材料常数（桥塔、桥面板）
MP,NUXY,3,0.3
MP,DENS,3,2500
!定义实常数
R,1,D1**2*3.1415926/4,INSTR	!主缆
R,2,D2**2*3.1415926/4			!吊索
R,3,B1*H1,,,B1,H1				!纵向分配梁
!纵向加劲桁架
R,4,B2*H2,B2*H2**3/12,B2**3*H2/12,B2,H2	!上、下弦杆
R,5,B1*H3,B1*H3**3/12,B1**3*H3/12,B1,H3	!纵向斜腹杆、内侧竖杆、外侧斜腹杆、内侧斜腹杆
R,6,B3*H4,B3*H4**3/12,B3**3*H4/12,B3,H4	!纵向竖杆
!横向加劲桁架实常数
R,7,B4*H5,B4*H5**3/12,B4**3*H5/12,B4,H5	!上弦杆
R,8,B4*H2,B4*H2**3/12,B4**3*H2/12,B4,H2	!下弦杆
R,9,B3*H3,B3*H3**3/12,B3**3*H3/12,B3,H3	!外侧竖杆
R,10,B5*H6,B5*H6**3/12,B5**3*H6/12,B5,H6	!抗风桁架实常数	
R,11,B6*H7,B6*H7**3/12,B6**3*H7/12,B6,H7	!桥塔塔柱实常数
R,12,B7*H8,B7*H8**3/12,B7**3*H8/12,B7,H8	!桥塔柱间连接件实常数
R,13,B8						!桥面板人行道板及车行道板实常数
!建模
!建立模型时，采用自下而上的方法建立除桥塔外的模型部分，然后通过对线划分单元建立桥塔模型。
!建立单侧主缆单元模型
*DO,I,1,12,1
N,I,4*(I-1),(4*(I-1)+12)**2/256+2		!创建节点
*ENDDO
N,13,50,18
*DO,I,1,29,1
N,I+13,4*I+52,(4*I-60)**2/256+2		!创建节点
*ENDDO
N,43,174,18
*DO,I,1,12,1
N,I+43,4*I+176,(4*I-60)**2/256+2		!创建节点
*ENDDO
TYPE,1								!指定单元类型
MAT,1								!指定材料类型
REAL,1								!指定实常数
*DO,I,1,54,1
E,I,I+1								!连接节点生成单元
*ENDDO
!建立单侧吊索单元模型
*DO,I,1,11,1
N,I+55,4*I							!创建节点
*ENDDO
*DO,I,1,29,1
N,I+66,4*I+52						!创建节点
*ENDDO
*DO,I,1,11,1
N,I+95,4*I+176						!创建节点
*ENDDO							!压缩节点编号
TYPE,1								!指定单元类型
MAT,1								!指定材料类型
REAL,2								!指定实常数
*DO,I,2,12,1
E,I,I+54								!连接节点生成单元
*ENDDO
*DO,I,14,42,1
E,I,I+53								!连接节点生成单元
*ENDDO
*DO,I,44,54,1
E,I,I+52								!连接节点生成单元
*ENDDO
!建立单侧塔柱模型
K,1,X1,Y1							!创建关键点
K,2,X1,Y2							!创建关键点
K,3,X2,Y1							!创建关键点
K,4,X2,Y2							!创建关键点
K,5,X1,TH							!创建关键点
K,6,X2,TH							!创建关键点
K,7,X1,0							!创建关键点
K,8,X2,0							!创建关键点
L,1,7								!连接关键点生成线
L,3,8								!连接关键点生成线
L,7,2								!连接关键点生成线
L,8,4								!连接关键点生成线
!将已建好的单侧模型，对称复制到另一侧
LSEL,ALL,ALL						!选择所有线
LGEN,2,ALL,,,,,BW					!将所有线复制到Z=BW平面
ESEL,ALL,ALL						!选择所有单元
EGEN,2,200,ALL,,,,,,,,,,BW			!将所有单元复制到Z=BW平面
KGEN,2,5,6,,,,BW,10					!将关键点5，6复制到Z=BW平面
L,5,15								!建立支撑横梁
L,6,16								!建立支撑横梁
L,1,9								!建立塔顶纵向梁
L,3,11								!建立塔顶纵向梁
NUMCMP,ALL						!压缩对象编号
!***********加劲桁架模型**********
!建立横向上弦杆单元模型
N,213,8,TH,BW						!创建节点
N,214,8,TH							!创建节点
N,215,8,,1.89						!创建节点
NGEN,7,1,215,,,,,1.17				!将所选节点沿X方向复制
N,222,8,TH,1.89						!创建节点
NGEN,4,1,222,,,,,2.34				!将所选节点沿X方向复制
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,7								!指定实常数
E,57,215							!连接节点生成单元
E,163,221							!连接节点生成单元
*DO,I,215,220,1
E,I,I+1								!连接节点生成单元
*ENDDO
!建立横向下弦杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,8								!指定实常数
E,214,222							!连接节点生成单元
E,213,225							!连接节点生成单元
*DO,I,222,224,1
E,I,I+1								!连接节点生成单元
*ENDDO
!建立横向外侧斜腹杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,5								!指定实常数
E,163,225							!连接节点生成单元
E,225,220
E,220,224
E,224,218
E,218,223
E,223,216
E,216,222
E,222,57
!建立横向外侧竖杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,9								!指定实常数
*DO,I,1,4,1
E,213+2*I,221+I					!连接节点生成单元
*ENDDO
!建立纵向竖杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,6								!指定实常数
E,163,213							!连接节点生成单元
E,57,214
ESEL,S,ELEM,,211,237,1			!选择单元
EGEN,2,200,ALL,,,,,,,,-4				!将已单元沿X方向复制
ALLS								!全选
NUMMRG,ALL						!合并所有重合对象
NUMCMP,ALL						!压缩对象编号
!建立纵向上、下弦杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,4								!指定实常数
NGEN,2,77,162,,,2					!复制节点
NGEN,2,1,239,,,,TH					!复制节点
E,162,239							!连接节点生成单元
E,239,163
E,226,240
E,240,213
!建立纵向斜腹杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,5								!指定实常数
E,226,239							!连接节点生成单元
E,239,213							!连接节点生成单元
ESEL,S,ELEM,,265,270,1			!选择单元
EGEN,2,100,ALL,,,,,,,,,,-BW			!将已单元沿X方向复制
!建立横向内侧竖杆，内侧斜腹杆单元模型
TYPE,2								!指定单元类型
MAT,2								!指定材料类型
REAL,5								!指定实常数
*DO,I,1,7,1
E,227+I,214+I						!连接节点生成单元
*ENDDO
NUMCMP,ALL						!压缩编号
E,56,163							!连接节点生成单元
E,162,57
NUMCMP,ALL			!压缩对象编号
!**************************************
!建立桥面单元模型
TYPE,3								!指定单元类型
MAT,3								!指定材料类型
REAL,13							!指定实常数
E,162,163,221,234
E,234,221,220,233
*DO,I,1,5,1
E,234-I,221-I,220-I,233-I
*ENDDO
E,228,215,57,56
!将桁架和桥面单元模型沿桥纵向复制
ESEL,S,ELEM,,211,293,1
EGEN,54,1000,ALL,,,,,,,,4
ALLS
NUMMRG,ALL						!合并所有对象
NUMCMP,ALL						!压缩对象编号
NSEL,ALL							!选择所有节点
NSEL,U,LOC,Y,Y1					!选择以＝Y1平面上的节点
CM,QIAO,NODE						!将所选节点归为QIAO一组
!划分桥塔塔柱单元模型
LSEL,S,LINE,,1,8,1					!选择线
LESIZE,ALL,1.88					!指定已选线上的单元份数
MSHKEY,1							!采用映射网格划分方式
MSHAPE,0,3D						!采用四边形、3D单元
TYPE,2								!指定单元类型
MAT,3								!指定材料类型
REAL,11							!指定实常数
LMESH,ALL							!对已选线进行网格划分
ALLS
!划分塔柱间连接件单元模型
LSEL,S,LINE,,9,12,1					!选择线
LESIZE,ALL,,,10						!指定已选线上的单元份数
REAL,12							!指定实常数
LMESH,ALL							!对已选线进行网格划分
ALLS								!全选
CMSEL,U,QIAO						!筛除属于QIAO组的节点
NUMMRG,NODE						!合并重合节点
NUMCMP,ALL						!压缩编号
!将桥塔塔柱单元与桥面单元重合的节点的自由度耦合
ALLS								!全选
CP,1,UY,431,1213					!耦合两节点Y方向自由度
CP,2,UZ,431,1213					!耦合两节点Z方向自由度
CP,3,ROTX,431,1213				!耦合两节点X方向的转动自由度
CP,4,UY,433,1173
CP,5,UZ,433,1173
CP,6,ROTX,433,1173
CP,7,UY,962,1223
CP,8,UZ,962,1223
CP,9,ROTX,962,1223
CP,10,UY,964,1183
CP,11,UZ,964,1183
CP,12,ROTX,964,1183
CP,13,UY,430,1192
CP,14,UZ,430,1192
CP,15,ROTX,430,1192
CP,16,UY,432,1152
CP,17,UZ,432,1152
CP,18,ROTX,432,1152
CP,19,UY,961,1202
CP,20,UZ,961,1202
CP,21,ROTX,961,1202
CP,22,UY,963,1162
CP,23,UZ,963,1162
CP,24,ROTX,963,1162
!施加边界条件
!约束主缆
NSEL,S,LOC,X,0						!选择节点
D,ALL,ALL							!约束主缆端部的所有自由度
NSEL,S,LOC,X,224					!选择节点
D,ALL,ALL							!约束主缆端部的所有自由度
!约束桥塔塔基
NSEL,S,LOC,Y,Y2					!选择节点
D,ALL,ALL							!约束桥塔塔基节点的所有自由度
!约束加劲桁架两端
NSEL,S,LOC,X,220					!选择节点
NSEL,U,LOC,Y,3
D,ALL,ALL							!约束加劲桁架端部的所有自由度
NSEL,S,LOC,X,4						!选择节点
NSEL,U,LOC,Y,3
D,ALL,ALL							!约束加劲桁架端部的所有自由度
*END								!运行宏生成模型
!加载及求解
!本例中的移动载荷视为匀速常量力载荷行分析。其中载荷MG＝2000N，简化成四个车轮上的相等集中载荷，车轮间距为8M，正好为两个桥面单元的长度，则简谐力F=500COS(10T)，载荷移动速度V＝120公里/小时。
!参数定义
!定义参数
DELTL=4							!桥面单元长度
V=120								!载荷移动速度
DELTT=DELTL/V*3.6				!荷载经过一个单元所用时间
F=1000								!常量力大小
W=10								!简谐力的圆频率
LF=8								!前后车轮间距
NUM=54							!桥面单元数
MM=NUM+1+LF/DELTL			!循环最大数目
!设置分析选项
FINI
/SOLU
ANTYPE,4							!指定分析类型为瞬态动力学分析
TRNOPT,FULL						!瞬态动力学分析采用FULL法
NLGEOM,ON
NROPT,FULL  
!计算重力的影响
TIMINT,OFF
TIME,1E-8
KBC,1
NSUBST,5
SSTIF,ON
ACEL,,9.8
ALLS
SOLVE                                 	!求解
!施加常量力移动载荷并求解
TIMINT,ON                             !打开时间积分开关
KBC,0
*DO,I,1,MM,1
OUTRES,ALL,ALL					!输出每一步的结果
TIME,I*DELTT
NSUBST,5
*IF,I,LT,LF/DELTL,THEN
	FDELE,ALL,ALL					!删除所有集中力载荷
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)		!施加简谐力载荷
	ALLS
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	SOLV
*ELSEIF,I,LT,(NUM+1)
	FDELE,ALL,ALL
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	SOLV
*ELSE
	FDELE,ALL,ALL
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加简谐力载荷
	ALLS
	SOLV
*ENDIF
*ENDDO 

FINI
/POST1						!进入通用后处理
SET,30,2					!查看30步第2子步即载荷移动到跨中附近的结果
PLNSOL, U,Y				!显示y方向位移云图
PLNSOL, S,EQV				!显示等效应力云图
/POST26					!进入时间历程后处理
NUMVAR,20				!指定允许的变量数
NSOL,2,677,U,Y, UY_CENT  !取出中间节点的Y向位移数据
DERIV,3,2,1,,VY_CENT		!对中间节点的Y向位移微分运算，得到Y向速度
PLVAR,2					!显示中间节点的Y向位移随时间变化曲线
PLVAR,3