double-arch tunnel fini.txt

来自「《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.」· 文本 代码 · 共 582 行 · 第 1/2 页

MSHAPE,0			!指定为四边形网格划分
AMESH,3				!划分3号面

MAT,3				!指定3号材料号
AMESH,6				!划分6号面

MAT,4				!指定4号材料号
MSHKEY,0			!指定为自由网格划分
AMESH,10			!划分10号面
!右隧道
MAT,5				!指定5号材料号
AMESH,11			!划分11号面
!左隧道
MAT,6				!指定6号材料号
AMESH,12			!划分12号面
!围岩
MAT,7				!指定7号材料号
CSYS				!激活总体笛卡尔坐标系
ASEL,S,LOC,X,-4*L1/5,4*L1/5	!选择隧道附近围岩面
ASEL,R,LOC,Y,-2.5*H2,H5/2
ASEL,U,MAT,,1,6,1
LSEL,S,LINE,,176,179,3		!选择线
LESIZE,ALL,,,30			!指定划分数
LSEL,S,LINE,,181,183,2		!选择线
LESIZE,ALL,,,22			!指定划分数
AMESH,ALL			!划分当前选择集中所有面
ALLS				!选择所有元素

LSEL,S,LOC,X,-W+1,-4*L1/5-1	!选择线
LSEL,A,LOC,X,4*L1/5+1,W-1	
LESIZE,ALL,,,6			!指定划分数
LSEL,S,LOC,Y,H5/2+1,H5-1	!选择线
LESIZE,ALL,,,4			!指定划分数
LSEL,S,LOC,Y,-2.5*H2-1,-H4+1	!选择线
LESIZE,ALL,,,6			!指定划分数

ASEL,S,LOC,X,-4*L1/5,4*L1/5	!选择围岩面
ASEL,R,LOC,Y,-2.5*H2,H5/2
ASEL,INVE
MSHKEY,1			!指定为映射网格划分
MSHAPE,0			!指定为四边形网格划分
AMESH,ALL			!划分当前选择集中所有面

!=====边界条件=====
NSEL,S,LOC,X,-W			!选择左右边界的节点
NSEL,A,LOC,X,W
D,ALL,UX			!约束当前所有选集中节点X方向位移

NSEL,S,LOC,Y,-H4		!选择下边界的节点
D,ALL,UY			!约束当前所有选集中节点Y方向位移

ALLS				!选择所有元素
NUMCMP,ALL			!压缩所有元素编号
!======================
!=======加载求解=======
!======================
FINI
/SOLU				!进入求解器
ANTYPE,STATIC			!指定为静力学求解类型
PRED,ON				!打开时间步长预测器
LNSRCH,ON			!打开线性搜索
NLGEOM,ON			!打开大变形求解
NROPT,FULL			!设定全N-R求解
OUTRES,ALL,ALL			!输出所有项，每一步都输出
NSUB,6,10			!设定子步数为6，最大不超过10

!载荷步1，求解自重应力场
TIME,1

ACEL,,9.8			!施加重力加速度9.8
ESEL,S,MAT,,8,13,1		!选择8到13材料号的单元
EKILL,ALL			!杀死单元

ESEL,ALL			!选择所有单元
ESEL,S,LIVE			!选择所有活的单元
NSLE,S				!选择当前单元中所有节点
NSEL,INVE			!反向选择
D,ALL,ALL			!约束当前选择集中所有节点所有自由度

ALLS				!选择所有元素
SOLVE				!求解
SAVE,S1,DB			!保存为S1.DB
!载荷步2，中导洞开挖
TIME,2

ESEL,S,MAT,,2,4,1		!选择2到4材料号的单元
EKILL,ALL			!杀死单元

ESEL,S,MAT,,8,9,1		!选择8到9材料号的单元
EALIVE,ALL			!激活单元
NSLE,S				!选择当前单元中所有节点
DDELE,ALL,ALL			!删除当前选择集中所有节点的约束

ESEL,ALL			!选择所有单元
ESEL,S,LIVE			!选择所有活的单元
NSLE,S				!选择当前单元中所有节点
NSEL,INVE			!反向选择
D,ALL,ALL			!约束当前选择集中所有节点所有自由度

ESEL,S,MAT,,1			!选择1材料号的单元
MPCHG,14,ALL			!改变为14材料号

ALLS				!选择所有元素
SOLVE				!求解
SAVE,S2,DB			!保存为S2.DB
!载荷步3
TIME,3

ESEL,S,MAT,,5,8,3		!选择5、8材料号的单元
EKILL,ALL			!杀死单元

ESEL,S,MAT,,3,10,7		!选择3、10、12材料号的单元
ESEL,A,MAT,,12
EALIVE,ALL			!激活单元
NSLE,S				!选择当前单元中所有节点
DDELE,ALL,ALL			!删除当前选择集中所有节点的约束

ESEL,ALL			!选择所有单元
ESEL,S,LIVE			!选择所有活的单元
NSLE,S				!选择当前单元中所有节点
NSEL,INVE			!反向选择
D,ALL,ALL			!约束当前选择集中所有节点所有自由度

ALLS				!选择所有元素
SOLVE				!求解
SAVE,S3,DB			!保存为S3.DB
!载荷步4
TIME,4

ESEL,S,MAT,,3,9,3		!选择3、6、9材料号的单元
EKILL,ALL			!杀死单元

ESEL,S,MAT,,11,13,2		!选择11、13材料号的单元
EALIVE,ALL			!激活单元
NSLE,S				!选择当前单元中所有节点
DDELE,ALL,ALL			!删除当前选择集中所有节点的约束

ESEL,ALL			!选择所有单元
ESEL,S,LIVE			!选择所有活的单元
NSLE,S				!选择当前单元中所有节点
NSEL,INVE			!反向选择
D,ALL,ALL			!约束当前选择集中所有节点所有自由度

ALLS				!选择所有元素
SOLVE				!求解
SAVE,S4,DB			!保存为S4.DB

!======================
!======通用后处理======
!======================
FINI
/POST1
!==自重应力场==
RESUME,'S1','DB'		!打开名为S1的DB文件
FILE,'EX5-5','RST'		!指定结果文件  
SET,1,LAST	   		!读入第1个载荷步最后一个子步数据

ESEL,S,LIVE			!选择激活的单元
PLNSOL,U,SUM,0,1.0     		!显示合位移云图
PLNSOL,U,X		     	!显示X方向位移云图
PLNSOL,U,Y		     	!显示Y方向位移云图

PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!==载荷步2==
RESUME,'S2','DB'		!打开名为S2的DB文件

!围岩等效应力场
ESEL,S,LIVE			!选择激活的单元
ESEL,U,MAT,,14			!排除中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!中墙等效应力场
ESEL,S,MAT,,14			!选择中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!初期支护内力
ESEL,S,LIVE
ESEL,R,ENAME,,3			!选择单元类型为BEAM3的单元
ETABLE,FX_I,SMISC,1  		!轴力
ETABLE,FX_J,SMISC,7
ETABLE,FY_I,SMISC,2  		!剪力
ETABLE,FY_J,SMISC,8
ETABLE,MZ_I,SMISC,6  	!	弯矩
ETABLE,MZ_J,SMISC,12

PLLS,MZ_I,MZ_J,-0.05  		!显示弯矩
PLLS,FX_I,FX_J,0.05 		!显示轴力

!查看位移场（减去初始位移场）
FILE,'EX5-5','RST'		!指定结果文件  
SET,2,LAST	   		!读入第2个载荷步最后一个子步数据

LCDEF,1,1 			!定义第1个载荷步为工况1
LCOPER,SUB,1   			!当前载荷步的结果减去工况1的结果

ESEL,S,LIVE			!选择激活的单元
PLNSOL,U,SUM     		!显示合位移云图
PLNSOL,U,X	     		!显示X方向位移云图
PLNSOL,U,Y	     		!显示Y方向位移云图

!==载荷步3==
RESUME,'S3','DB'		!打开名为S3的DB文件

!围岩等效应力场
ESEL,S,LIVE			!选择激活的单元
ESEL,U,MAT,,14			!排除中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!中墙等效应力场
ESEL,S,MAT,,14			!选择中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!初期支护及右隧道衬砌内力
ESEL,S,LIVE
ESEL,R,ENAME,,3			!选择单元类型为BEAM3的单元
ETABLE,FX_I,SMISC,1  		!轴力
ETABLE,FX_J,SMISC,7
ETABLE,FY_I,SMISC,2  		!剪力
ETABLE,FY_J,SMISC,8
ETABLE,MZ_I,SMISC,6  	!	弯矩
ETABLE,MZ_J,SMISC,12

PLLS,MZ_I,MZ_J,-0.2  		!显示弯矩
PLLS,FX_I,FX_J,0.2 		!显示轴力

!查看锚杆轴力
ESEL,S,LIVE			!选择激活的单元
ESEL,R,ENAME,,1			!选择单元类型为LINK1的单元
ETABLE,FORX,SMISC,1  		!轴力

PLLS,FORX,FORX,0.05  		!显示轴力 

!查看位移场（减去初始位移场）
FILE,'EX5-5','RST'		!指定结果文件  
SET,3,LAST	   		!读入第3个载荷步最后一个子步数据

LCDEF,1,1 			!定义第1个载荷步为工况1
LCOPER,SUB,1   			!当前载荷步的结果减去工况1的结果

ESEL,S,LIVE			!选择激活的单元
ESEL,U,MAT,,3			!去除回填土的单元
PLNSOL,U,SUM     		!显示合位移云图
PLNSOL,U,X	     		!显示X方向位移云图
PLNSOL,U,Y	     		!显示Y方向位移云图

!==载荷步4==
RESUME,'S4','DB'		!打开名为S4的DB文件

!围岩等效应力场
ESEL,S,LIVE			!选择激活的单元
ESEL,U,MAT,,14			!排除中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!中墙等效应力场
ESEL,S,MAT,,14			!选择中墙的单元
PLNSOL,S,EQV    		!显示EQUIVALENT STRESS

!隧道衬砌内力
ESEL,S,LIVE
ESEL,R,ENAME,,3			!选择单元类型为BEAM3的单元
ETABLE,FX_I,SMISC,1  		!轴力
ETABLE,FX_J,SMISC,7
ETABLE,FY_I,SMISC,2  		!剪力
ETABLE,FY_J,SMISC,8
ETABLE,MZ_I,SMISC,6  	!	弯矩
ETABLE,MZ_J,SMISC,12

PLLS,MZ_I,MZ_J,-0.2  		!显示弯矩
PLLS,FX_I,FX_J,0.2 		!显示轴力

!查看锚杆轴力
ESEL,S,LIVE			!选择激活的单元
ESEL,R,ENAME,,1			!选择单元类型为LINK1的单元
ETABLE,FORX,SMISC,1  		!轴力

PLLS,FORX,FORX,0.05  		!显示轴力 

!查看位移场（减去初始位移场）
FILE,'EX5-5','RST'		!指定结果文件  
SET,4,LAST	   		!读入第4个载荷步最后一个子步数据

LCDEF,1,1 			!定义第1个载荷步为工况1
LCOPER,SUB,1   			!当前载荷步的结果减去工况1的结果

ESEL,S,LIVE			!选择激活的单元
PLNSOL,U,SUM     		!显示合位移云图
PLNSOL,U,X	     		!显示X方向位移云图
PLNSOL,U,Y	     		!显示Y方向位移云图